Автозаполнение шаблона

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)
    
    Дерево = РеквизитФормыВЗначение("ОбъектДеревоРеквизитов");
    
    РодительСтрок = ДобавитьСтрокуВДеревоЗначений(Дерево, "Клиент", Ложь);
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Фамилия");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Имя");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Отчество");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "ФИО");
    РодительСтрок = ДобавитьСтрокуВДеревоЗначений(Дерево, "Предварительная запись", Ложь);
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "День");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Время");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "День и время");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Сотрудник");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Услуга");
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Структурная единица");
    РодительСтрок = ДобавитьСтрокуВДеревоЗначений(Дерево, "Полис мед. страхования", Ложь);
    ДобавитьСтрокуВДеревоЗначений(РодительСтрок, "Дата окончания срока действия полиса"); 
            
    ЗначениеВРеквизитФормы(Дерево, "ОбъектДеревоРеквизитов"); 
    
КонецПроцедуры
 
&НаКлиентеНаСервереБезКонтекста
Функция ДобавитьСтрокуВДеревоЗначений(РодительСтроки, ПредставлениеПоля, РазрешитьВыбор = Истина)
    
    НоваяСтрока = РодительСтроки.Строки.Добавить();
    НоваяСтрока.Представление = ПредставлениеПоля;
    НоваяСтрока.РазрешитьВыбор = РазрешитьВыбор;
    
    Возврат НоваяСтрока;
    
КонецФункции
 
&НаКлиенте
Процедура ДеревоРеквизитовВыбор(Элемент, ВыбраннаяСтрока, Поле, СтандартнаяОбработка)
    
    СтандартнаяОбработка = Ложь;
    ДеревоРеквизитовВыборЗначения(Элемент, Неопределено, СтандартнаяОбработка);
    
КонецПроцедуры
 
&НаКлиенте
Процедура ДеревоРеквизитовВыборЗначения(Элемент, Значение, СтандартнаяОбработка)
    
    СтандартнаяОбработка = Ложь;
    
    Если Элемент.ТекущиеДанные = Неопределено ИЛИ Элемент.ТекущиеДанные.РазрешитьВыбор = Ложь Тогда
        Возврат;
    КонецЕсли;
    
    Объект.Содержание = Объект.Содержание + ?(ЗначениеЗаполнено(Объект.Содержание), " ", "") + "{" + Элемент.ТекущиеДанные.Представление + "}" + ?(ЗначениеЗаполнено(Объект.Содержание), " ", "");
    
КонецПроцедуры

// Процедура заполнения предопределенных шаблонов СМС
//
Процедура ЗаполнитьПредопределенныеШаблоныSMS(УстановитьОсновным = Истина) Экспорт
    
    ЭлементОбъект = Справочники.ШаблоныСообщений.НапоминаниеПредварительнойЗаписи.ПолучитьОбъект();
    Если ЭлементОбъект.Содержание = "" Тогда
        ЭлементОбъект.Содержание = "Уважаемая(ый) {Имя} {Отчество}, напоминаем вам, что вы записаны {День} в {Время} к врачу {Сотрудник}";
        ЭлементОбъект.Записать();
        Если УстановитьОсновным Тогда
            Константы.ИнформироватьОЗаписиШаблонСообщения.Установить(ЭлементОбъект.Ссылка);
        КонецЕсли;
    КонецЕсли;
    
    ЭлементОбъект = Справочники.ШаблоныСообщений.НапоминаниеОкончанияСтраховогоПолиса.ПолучитьОбъект();
    Если ЭлементОбъект.Содержание = "" Тогда
        ЭлементОбъект.Содержание = "Уважаемая(ый) {Имя} {Отчество}, напоминаем вам, что {Дата окончания срока действия полиса} у вас заканчивается срок действия полиса.";
        ЭлементОбъект.Записать();
        Если УстановитьОсновным Тогда
            Константы.ИнформироватьОбОкончанииСтраховогоПолисаШаблон.Установить(ЭлементОбъект.Ссылка);
        КонецЕсли;
    КонецЕсли;
    
    ЭлементОбъект = Справочники.ШаблоныСообщений.ИнформированиеОПодтвержденииОнЛайнЗаписи.ПолучитьОбъект();
    Если ЭлементОбъект.Содержание = "" Тогда
        ЭлементОбъект.Содержание = "Вы записаны на {День} в {Время} к стоматологу {Сотрудник}";
        ЭлементОбъект.Записать();      
        Если УстановитьОсновным Тогда
            Константы.ИнформированиеКлиентаПодтверждениеОнЛайнЗаписиШаблон.Установить(ЭлементОбъект.Ссылка);
        КонецЕсли;         
    КонецЕсли;
    
КонецПроцедуры

Функция ПреобразоватьСодержаниеСПараметрамиВТекст(Знач Содержание, Документ, ПолучательSMS) Экспорт
    
    // Получаем значение параметров
    МассивПараметров = ПолучитьМассивПараметровИзШаблона(Содержание, "{}");
    Для Каждого Параметр Из МассивПараметров Цикл
        Результат = Неопределено;
        Попытка
            Выполнить("Результат = " + ВернутьПутьКРеквизитуПоПредставлении(Параметр));
        Исключение
            Сообщить("Невозможно получить параметр (" + Параметр + ")" );
            Ошибка = Истина;
        КонецПопытки;
        Если Результат <> Неопределено Тогда
            Содержание = СтрЗаменить(Содержание, "{" + Параметр + "}", Результат);
        КонецЕсли;
    КонецЦикла;
    
    Возврат Содержание;
    
КонецФункции
 
Функция ПолучитьМассивПараметровИзШаблона(ФормулаШаблона, ЗнакиВыделения = "{}")
    
    МассивПараметров = Новый Массив;
    
    НачалоПараметра = 0;
    КонецПараметра = 0;   
    Для а = 1 По СтрДлина(ФормулаШаблона) Цикл
        Если Сред(ФормулаШаблона, а, 1) = Сред(ЗнакиВыделения, 1, 1) Тогда
            НачалоПараметра = а + 1;
        ИначеЕсли Сред(ФормулаШаблона, а, 1) = Сред(ЗнакиВыделения, 2, 1) Тогда
            КонецПараметра = а - 1;          
        КонецЕсли;
        Если НачалоПараметра <> 0 И КонецПараметра <> 0 И (КонецПараметра - НачалоПараметра + 1) > 0 Тогда
            МассивПараметров.Добавить(Сред(ФормулаШаблона, НачалоПараметра, КонецПараметра - НачалоПараметра + 1));
            НачалоПараметра = 0;
            КонецПараметра = 0;   
        КонецЕсли;
    КонецЦикла;
    
    Возврат МассивПараметров;
    
КонецФункции
 
Функция ВернутьПутьКРеквизитуПоПредставлении(Наименование)
    
    СписокПараметров = Новый СписокЗначений;
    СписокПараметров.Добавить("Фамилия", "ПолучательSMS.Фамилия");
    СписокПараметров.Добавить("Имя", "ПолучательSMS.Имя");
    СписокПараметров.Добавить("Отчество", "ПолучательSMS.Отчество");
    СписокПараметров.Добавить("ФИО", "ПолучательSMS.Наименование");
    СписокПараметров.Добавить("День", "Формат(Документ.ДокументОснование.Услуги[0].ДатаНачала, ""ДФ='dd MMMM'"")");
    СписокПараметров.Добавить("Время", "Формат(Документ.ДокументОснование.Услуги[0].ДатаНачала, ""ДФ=HH:mm"")");
    СписокПараметров.Добавить("День и время", "Формат(Документ.ДокументОснование.Услуги[0].ДатаНачала, ""ДФ='dd MMMM HH:mm'"")");
    СписокПараметров.Добавить("Сотрудник", "Документ.ДокументОснование.Услуги[0].Сотрудник");
    СписокПараметров.Добавить("Услуга", "Документ.ДокументОснование.Услуги[0].Номенклатура");
    СписокПараметров.Добавить("Структурная единица", "Документ.ДокументОснование.СтруктурнаяЕдиница");
    СписокПараметров.Добавить("Дата окончания срока действия полиса", "Формат(Документ.ДокументОснование.ДатаОкончания, ""ДФ='dd MMMM yyyy'"")");
            
    Результат = СписокПараметров.НайтиПоЗначению(Наименование);
    
    Если Результат <> Неопределено Тогда
        Возврат Результат.Представление;
    Иначе
        Возврат Наименование;
    КонецЕсли;
    
КонецФункции