Найти второе по величине четное число в линейном массиве

@Shura_deg · Регистрация: 01.02.2015

Author24 — интернет-сервис помощи студентам

Найти второе по величине четное число в линейном массиве
элементы массива - знаковые целые числа размером в слово (не менее 10) ) – должны вводиться с клавиатуры.
И ещё главное чтобы не менялись числа в массиве поэтому код немного странноват
Но иногда появляются ошибки например если все числа одинаковые
Пример правильной работы программы:
Исходный массив : 1 2 3 4 0 5
Ответ: 2
Вот что то наваял)

Assembler

data segment
req db  10,13,'ENTER ARRAY:$'
error db "INCORRECT NUMBER$"
inpbuf  db  30 
len db  0 
DBbuF db 30 dup (?)
dwArray dw 60 dup (?)
dimension dw 0  
FIND dw 0 
msg1 db 10,13,"THE SECOND LARGEST EVEN NUMBER:$"
ends
 
stack segment
    dw   128  dup(0)
ends
 
code segment
start:
; set segment registers:
    mov ax, data
    mov ds, ax
    mov es, ax
;================================================================
;==========================input array===========================
;================================================================
    XOR CX, CX
    XOR BX, BX 
    
    mov  ah, 09h
    lea  dx, req
    int  21h
    
    mov ah, 0Ah
    lea dx, inpbuf      
    int 21h
    
    LEA SI, DBbuF
    LEA DI, dwArray
    
    MOV BX, 10              ;notation
    XOR DX, DX
nachalo:
    PUSH DX    
    cmp byte ptr [si],"-" 
    jnz positive
    mov BP,1  
    inc si
positive:
    xor ax,ax
cycle:    
    mov CL,[SI]
    CMP CL,0dh   ;ne konec li stroki         
    JZ  proverka
    CMP CL,20h
    JZ  proverka ; konec chisla (probel)
    
    CMP CL,'0'
    JL er
    CMP CL,'9'
    JA er
    
    SUB CL,'0'
    MUL BX
    ADD AX, CX
    INC SI
    JMP cycle
    
proverka:
    POP DX
    INC DX
    CMP BP,1
    JNZ neminys
    NEG AX
neminys:
    XOR BP, BP
    MOV [DI], AX
    ADD DI, 2
    INC SI
    CMP CL, 0dh
    JZ  endin    
    JMP nachalo
    
er:
    MOV DX, offset error
    MOV AH, 09
    INT 21h    
endin:
    MOV dimension, DX   
;================================================================
;==========================main part=============================
;================================================================       
    LEA   SI, dwArray
    MOV   CX, dimension
    XOR   DX, DX
    PUSH  CX
    PUSH  SI  
Max1LooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   Skip1             ;if <>
    MOV   BP, AX            ;MAX -> BP
    INC   DX                ;the even number
Skip1:
    CMP   DX, 0             ;the even number (at least one)
    LOOPE Max1LooP
    JE    EXIT              ;no even numbers
;-----------------------------------------------------------------  
    POP  SI 
    POP  CX
    PUSH CX
    PUSH SI 
MaxLooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   ODD               ;if <> 
    CMP   AX, BP            ;AX[SI] - BP[MAX]
    JL    LessEven          ;IF AX<BX -> lesseven (AX<max)    
    MOV   BP, AX            ;BP <- max[AX]         
    JMP   ODD
LessEven:
    MOV   DX, AX            ;
    ODD:
    LOOP  MaxLooP
;------------------------------------------------------------------- 
    POP  SI 
    POP  CX
    PUSH SI
    PUSH CX 
SecondMaxLooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   OddNumber         ;if <> 
    CMP   AX, BP
    JE    OddNumber            
    MOV   DX, AX            ;MAX = AX  
    OddNumber:
    LOOP  SecondMaxLooP
    POP   CX
    POP   SI       
SecondMaxLooP2:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   OddNumber1         ;if <> 
    CMP   AX, BP
    JE    OddNumber1            
    CMP   AX, DX
    JL    oddNumber1
    MOV   DX, AX 
    OddNumber1:
    LOOP  SecondMaxLooP2  
    MOV FIND, DX
;================================================================
;==========================display a message on the screen=======
;================================================================
    LEA DX, msg1
    MOV AH, 9
    INT 21h
;================================================================
;==========================Result output=========================
;================================================================    
    MOV AX, FIND
    TEST AX, AX
    JNS oi1
    MOV CX, AX
    MOV AH, 02H
    MOV DL, '-'
    INT 21H
    MOV AX, CX
    NEG AX
oi1:
    XOR CX, CX
    MOV BX, 10
oi2:
    XOR DX, DX
    DIV BX
    PUSH DX
    INC  CX
    TEST AX,AX
    JNZ  oi2
    MOV AH, 02H
oi3:
    POP DX
    CMP DL, 9
    JBE oi4
    ADD DL, 7
oi4:
    ADD DL, '0'
    INT 21H
    LOOP oi3       
      
    EXIT:
    mov ax, 4c00h ; exit to operating system.
    int 21h    
ends
 
end start

Добавлено через 13 часов 8 минут

Assembler

; multi-segment executable file template.
 
data segment
req        db  10,13,'ENTER ARRAY:$'
error      db  10,13,"INPUT ERROR$"
pkey       db  10,13,"press any key...$"
msg1       db  10,13,"THE SECOND LARGEST EVEN NUMBER:$"
inpbuf     db  50 
len        db  0 
DBbuF      db  50 dup (?)
dwArray    dw  100 dup (?)
dimension  dw  0  
FIND       dw  0 
ends
 
stack segment
    dw   128  dup(0)
ends
 
code segment
start:
; set segment registers:
    mov ax, data
    mov ds, ax
    mov es, ax
;================================================================
;==========================input array===========================
;================================================================
    XOR CX, CX
    XOR BX, BX 
InputStart:    
    mov  ah, 09h
    lea  dx, req
    int  21h
    
    mov ah, 0Ah
    lea dx, inpbuf      
    int 21h
    
    CMP len, 0
    JE  er
    LEA SI, DBbuF
    LEA DI, dwArray
    
    MOV BX, 10              ;notation
    XOR DX, DX
nachalo:
    PUSH DX    
    cmp byte ptr [si],"-" 
    jnz positive
    mov BP,1  
    inc si
positive:
    xor ax,ax
cycle:    
    mov CL,[SI]
    CMP CL,0dh   ;ne konec li stroki         
    JZ  proverka
    CMP CL,20h
    JZ  proverka ; konec chisla (probel)
    
    CMP CL,'0'
    JL er
    CMP CL,'9'
    JA er
    
    SUB CL,'0'
    MUL BX
    ADD AX, CX
    INC SI
    JMP cycle
    
proverka:
    POP DX
    INC DX
    CMP BP,1
    JNZ neminys
    NEG AX
neminys:
    XOR BP, BP
    MOV [DI], AX
    ADD DI, 2
    INC SI
    CMP CL, 0dh
    JZ  endin    
    JMP nachalo    
er:
    MOV DX, offset error
    MOV AH, 09
    INT 21h
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h
    ;======================
    ;=====clear screen=====
    ;======================   
    MOV  AH, 00H
    MOV  AL, 03H  
    INT    10H  
    JMP InputStart 
           
endin:
    MOV dimension, DX   
;================================================================
;==========================main part=============================
;================================================================       
    LEA   SI, dwArray
    MOV   CX, dimension
    XOR   DX, DX
    PUSH  CX
    PUSH  SI  
checkARRAY:
    LODSW                   ;AX = DS:[SI], SI = SI + 2 
    MOV   BX, AX
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   wrong             ;if <> 
    MOV   BP, AX
    INC   DL                ;the even number
wrong:
    CMP   DL, 2h            ;the even number (at least one)
    LOOPNE checkARRAY       ;esli 2 nechetnix
    JC    er                ;if CF=1   -->menshe dvyh nechetnix  
    DEC  DL                 ;est yzhe odno chetnoe chislo
    POP  SI
    POP  CX
    PUSH CX
    PUSH SI
checkARRAY1:
    LODSW                   ;AX = DS:[SI], SI = SI + 2 
    MOV   BX, AX
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   wrong1            ;if <> 
    CMP   BP, AX
    JE    wrong1
    INC   DL                ;the even number
wrong1:
    CMP   DL, 2h            ;the even number (at least one)
    LOOPNE checkARRAY1      ;esli 2 nechetnix
    JC    er                ;if CF=1   -->menshe dvyh nechetnix
    POP  SI
    POP  CX
    PUSH CX
    PUSH SI
Max1LooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   Skip1             ;if <>
    MOV   BP, AX            ;MAX -> BP
    INC   DX                ;the even number
Skip1:
    CMP   DX, 0             ;the even number (at least one)
    LOOPE Max1LooP
    JE    er                 ;no even numbers
;-----------------------------------------------------------------  
    POP  SI 
    POP  CX
    PUSH CX
    PUSH SI 
MaxLooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   ODD               ;if <> 
    CMP   AX, BP            ;AX[SI] - BP[MAX]
    JL    ODD               ;IF AX<BP -> lesseven (AX<max)    
    MOV   BP, AX            ;BP <- max[AX]         
    ODD:
    LOOP  MaxLooP
;------------------------------------------------------------------- 
    POP  SI 
    POP  CX
    PUSH SI
    PUSH CX 
SecondMaxLooP:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   OddNumber         ;if <> 
    CMP   AX, BP
    JE    OddNumber            
    MOV   DX, AX            ;MAX = AX  
    OddNumber:
    LOOP  SecondMaxLooP
    POP   CX
    POP   SI       
SecondMaxLooP2:    
    LODSW                   ;AX = DS:[SI], SI = SI + 2
    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   OddNumber1        ;if <> 
    CMP   AX, BP            ;AX-[SI] BP-max1
    JE    OddNumber1        ;if = then exit    
    CMP   AX, DX            ;AX-[SI] DX-max2
    JL    oddNumber1        ;if max>AX then exit
    MOV   DX, AX            ;max=AX
    OddNumber1:
    LOOP  SecondMaxLooP2  
    MOV FIND, DX            ;ANSWER
;================================================================
;==========================display a message on the screen=======
;================================================================
    LEA DX, msg1
    MOV AH, 9
    INT 21h
;================================================================
;==========================Result output=========================
;================================================================    
    MOV AX, FIND
    TEST AX, AX
    JNS oi1
    MOV CX, AX
    MOV AH, 02H
    MOV DL, '-'
    INT 21H
    MOV AX, CX
    NEG AX
oi1:
    XOR CX, CX
    MOV BX, 10
oi2:
    XOR DX, DX
    DIV BX
    PUSH DX
    INC  CX
    TEST AX,AX
    JNZ  oi2
    MOV AH, 02H
oi3:
    POP DX
    CMP DL, 9
    JBE oi4
    ADD DL, 7
oi4:
    ADD DL, '0'
    INT 21H
    LOOP oi3       
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h      
    EXIT:
    mov ax, 4c00h ; exit to operating system.
    int 21h    
ends
 
end start ; set entry point and stop the assembler.

Апгрейт))) нет вроде ошибок если найдёте плз отпишите
попробуйте забагать если получится напишите какие числа пробовали
И отпишите как улучшить программу если у кого есть какие-нибудь соображения
И если у кого будет интерес просмотреть код МОЖНО ЛИ СДЕЛАТЬ ТАМ ГДЕ У МЕНЯ САМАЯ ОСНОВНАЯ ЧАСТЬ ЧТО БЫ ОБОЙТИСЬ БЕЗ РЕГИСТРОВ BP ибо говорят что BP используют только для стека

@Shura_deg · 09.05.2015, 12:20 **[ТС]**

exe.rar
ВОт откомпилированный файл

@Ethereal · 09.05.2015, 15:19

Сообщение от Shura_deg

ОБОЙТИСЬ БЕЗ РЕГИСТРОВ BP ибо говорят что BP используют только для стека

Часто используют для стека. Но это-же не значит, что его нельзя использовать иначе. Пока ты не адресуешься по BP косвенно - это регистр, как регистр. А вот косвенно - он, да, адресует по умолчанию в сегменте SS.

Добавлено через 6 минут

Assembler

nachalo:
    PUSH DX    
    cmp byte ptr [si],"-" 
    jnz positive
    mov BP,1  
    inc si
positive:

Итак, если символ минус, то BP=1. А в противном случае ? А в противном случае BP не определен. Может тоже 1.

Добавлено через 30 минут
Так некорректный у тебя алгоритм.

Первый цикл после метки endin.
Ты запихиваешь в BP второе по порядку четное число в массиве.
Если четных чисел меньше двух идешь на ошибку.

Второй цикл - ты ищещь четное, не равное найденному в первом
цикле. Если не найдешь, то идешь на ошибку.

Вывод - если все четные числа одинаковые и хоть сколько их,
у тебя обязательно уйдет на ошибку.

Добавлено через 20 минут
Мысли проще.
Массив будем просмотривать только ОДИН РАЗ !
У тебя два флага состояния :
Флаг_1 - нашли первое четное число.
Флаг 2 - нашли второе четное число.

Код

Флаг1 = ЛОЖЬ
Флаг2 = ЛОЖЬ
Цикл:
 ЧИСЛО = очередной_элемент_массива
 Если ЧИСЛО нечетно, то GOTO Конец_цикла
 Если Флаг 1 = ЛОЖЬ, то
       НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_1 = ПРАВДА
       GOTO Конец_цикла
 Если Флаг 2 = ЛОЖЬ, то
       Если ЧИСЛО <= НАИБОЛЬШЕЕ
            ИСКОМОЕ = ЧИСЛО
       в противном случае
            ИСКОМОЕ = НАИБОЛЬШЕЕ
            НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_2 = ПРАВДА
       GOTO Конец_цикла
 Если ЧИСЛО > НАИБОЛЬШЕЕ
      ИСКОМОЕ = НАИБОЛЬШЕЕ
      НАИБОЛЬШЕЕ = ЧИСЛО
      GOTO Конец_цикла
 Если ЧИСЛО > ИСКОМОЕ
      ИСКОМОЕ = ЧИСЛО
Конец_цикла:
LOOP Цикл
Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку
Печатаем ИСКОМОЕ

Добавлено через 7 минут
И еще :

Assembler

    MOV   BX, AX            ;Parity
    AND   BX, 01h           ;Parity        
    CMP   BX, 0             ;Parity
    JNE   OddNumber         ;if <>

Словом Parity называют нечто другое. И вообще это делается так :

Assembler

1 2	TEST AX, 01h ;А если TEST AL,01H , то еще и на байт короче JNZ OddNumber

Добавлено через 3 минуты
Короче, простые правила :
CMP - это то-же самое, что SUB, только результат не пишется никуда. Изменяются только флаги.
TEST - это то-же самое, что AND, только результат не пишется никуда. Изменяются только флаги.

Добавлено через 3 минуты
В свете этого :

Assembler

    CMP CL,'0'
    JL er
    CMP CL,'9'
    JA er
    SUB CL,'0'

смело пишем, как

Assembler

    SUB CL,'0'
    JL er
    CMP CL,9
    JA er

@Shura_deg · 09.05.2015, 15:42 **[ТС]**

Сообщение от Ethereal

Итак, если символ минус, то BP=1. А в противном случае ? А в противном случае BP не определен. Может тоже 1.

я имел ввиду что мне важно было единица там или что то иное
забыл наверое правда сперва указать xor bp, bp и это мне нужно было для этого фрагмента кода:

Assembler

proverka:
    POP DX
    INC DX
    CMP BP,1
    JNZ neminys
    NEG AX

Добавлено через 2 минуты

Сообщение от Ethereal

Если четных чисел меньше двух идешь на ошибку.

правильно ибо мне нужно найти второе по величине чётное число а следовательно если одно чётное то не будет результата

Добавлено через 33 секунды

Сообщение от Ethereal

Вывод - если все четные числа одинаковые и хоть сколько их,
у тебя обязательно уйдет на ошибку.

так да я это специально подгонял....

Добавлено через 23 секунды
тобишь пользователь некоорректо вводит массив

@Ethereal · 09.05.2015, 15:43

Сообщение от Shura_deg

правильно ибо мне нужно найти второе по величине чётное число а следовательно если одно чётное то не будет результата

К этому циклу претензий нет. Если в массиве два и более четных и все одинаковые, то ошибка будет на следующем цикле.

@Shura_deg · 09.05.2015, 15:44 **[ТС]**

Сообщение от Ethereal

Словом Parity называют нечто другое.

к слову https://translate.google.ru/#r... 1%82%D1%8C

@Ethereal · 09.05.2015, 15:44

Сообщение от Shura_deg

так да я это специально подгонял....

Если массив 2 2 2 2 2 2 , то второе по величине четное есть и оно 2

@Shura_deg · 09.05.2015, 15:47 **[ТС]**

Сообщение от Ethereal

К этому циклу претензий нет. Если в массиве два и более четных и все одинаковые, то ошибка будет на следующем цикле.

не додумал как в один уместить...

Добавлено через 2 минуты

Сообщение от Ethereal

Если массив 2 2 2 2 2 2 , то второе по величине четное есть и оно 2

так то да но это же не логично ....
2=2
а если второе по величине следовательно оно не <> друг другу....
но конечно можно так как и вы сделать чисто выйти сразу на ответ указав это чётное число в качестве ответа

@Ethereal · 09.05.2015, 16:03

Сообщение от Shura_deg

к слову https://translate.google.ru/#r... 1%82%D1%8C

К слову после исполнения каждой инструкции процессора в слове состояния процессора выставляется или нет флажок Parity. И у него совсем иной смысл. Так-что за словом Parity в мире ассемблера закреплен иной смысл. Смысл паритета, а не четности.
Это в русском языке четность - это четный или нечетный. А в английском - это even или odd. Чтобы не путать с Parity в смысле паритета пишут в комментариях "Even or Odd ?" "Is it even ?" и т.д.

Добавлено через 1 минуту

Сообщение от Shura_deg

так то да но это же не логично ....
2=2

Ну в математическом смысле у массива одинаковых чисел есть и наибольшее значение и наименьшее. Просто тот, кто давал тебе задание, наверняка мыслит именно так.

Добавлено через 8 минут
Ну доработай мой алгоритм так :

Assembler

...
LOOP Цикл
Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку
Если ИСКОМОЕ = НАИБОЛЬШЕЕ, то напечатать "А введи ка ты мне что-то другое, мил человек"
Печатаем ИСКОМОЕ

@Shura_deg · 09.05.2015, 19:29 **[ТС]**

Сообщение от Ethereal

Мысли проще.
Массив будем просмотривать только ОДИН РАЗ !
У тебя два флага состояния :
Флаг_1 - нашли первое четное число.
Флаг 2 - нашли второе четное число.

ЧТО означает в вашем псевдокоде ИСКОМОЕ?
ЧТО означает в вашем псевдокоде ЧИСЛО?

Добавлено через 48 минут
ПОХОДУ ПОНЯЛ ИСКОМОЕ ТО ЧТО СЛЕДУЕТ ОТЫСКАТЬ
А ЧИСЛО ЭТО ТЕКУЩЕЕ ЧИСЛО В МАССИВЕ

Добавлено через 36 минут
пытался разобраться с предложенным вами алгоритмом да недопонял....
гляньте может чё намудрил...

Assembler

1
2
3

DwArray     dw 4, 3, 2
len         dw 3  
find        dw 0

Assembler

    LEA SI, DwArray 
    MOV CX, len
    XOR BX, BX     
cycle:
LODSW
TEST  AX, 01h
JNZ   EndLoop
;-------------------
CMP   BL, 0
JE    @1
JMP   @22
@1:
MOV   DX, AX
MOV   BL, 1
;-------------------
@22:
CMP   BH, 0
JE    @2
JMP   @33
@2:
CMP   AX, DX
JLE   @3
MOV   BP, DX
MOV   DX, AX
MOV   BH, 1
JMP   EndLoop
@3:
MOV   BP, AX 
MOV   BH, 1
JMP   EndLoop
;-------------------
@33:
CMP   AX, DX
JL    @4
MOV   BP, DX
MOV   DX, AX
JMP   EndLoop
@4:
CMP   AX, BP
JL    EndLoop
MOV   BP, AX
EndLoop:
LOOP  cycle
CMP   BH, 0
JE    ER
MOV   FIND, BP
 
er:
 
            
 
    
    mov ax, 4c00h 
    int 21h

@Ethereal · 09.05.2015, 21:55

Сообщение от Shura_deg

ЧТО означает в вашем псевдокоде ИСКОМОЕ?

Сообщение от Shura_deg

Найти второе по величине четное число

Вот это и значит.

Добавлено через 57 секунд

Сообщение от Shura_deg

ЧТО означает в вашем псевдокоде ЧИСЛО?

Вот это :

Сообщение от Ethereal

ЧИСЛО = очередной_элемент_массива

Добавлено через 29 минут

Сообщение от Shura_deg

пытался разобраться с предложенным вами алгоритмом да недопонял....

Попробую объяснить доступно :

Сообщение от Ethereal

Код

Флаг1 = ЛОЖЬ ;Мы еще ни хрена не нашли
Флаг2 = ЛОЖЬ ;Мы еще ни хрена не нашли
Цикл:
  ЧИСЛО = очередной_элемент_массива
  Если ЧИСЛО нечетно, то GOTO Конец_цикла
  ;Врубаемся, что нашли четное число
  Если Флаг 1 = ЛОЖЬ, то
    ;Здесь втыкаем %ули будем делать, если нашли первое четное число
    НАИБОЛЬШЕЕ = ЧИСЛО
    Флаг_1 = ПРАВДА
    GOTO Конец_цикла
  Если Флаг 2 = ЛОЖЬ, то
    ;Здесь втыкаем %ули будем делать, если нашли второе четное число
    Если ЧИСЛО <= НАИБОЛЬШЕЕ
      ;Здесь втыкаем %ули будем делать, если второе <= первого
      ИСКОМОЕ = ЧИСЛО
    в противном случае
      ;Здесь втыкаем %ули будем делать, если второе > первого
      ИСКОМОЕ = НАИБОЛЬШЕЕ
      НАИБОЛЬШЕЕ = ЧИСЛО
    Флаг_2 = ПРАВДА
    GOTO Конец_цикла
  ;Здесь врубаемся, что два четных уже было и еще привалило
  Если ЧИСЛО > НАИБОЛЬШЕЕ
    ;Здесь втыкаем %ули будем делать, если привалило число > наибольшего
    ; из тех, что привалили раньше
    ИСКОМОЕ = НАИБОЛЬШЕЕ
    НАИБОЛЬШЕЕ = ЧИСЛО
    GOTO Конец_цикла
  ;Врубаемся, что привалило число <= наибольшего из тех, что привалили
  ; раньше. А значит НАИБОЛЬШЕЕ корректировать не надо.
  Если ЧИСЛО > ИСКОМОЕ
    ;Здесь втыкаем %ули будем делать, если привалило число > второго
    ; по величине из тех, что привалили раньше.
    ИСКОМОЕ = ЧИСЛО
    ;В противном случае (если привалило число <= второго по величине из
    ; приваливших раньше) не будем делать ни хрена. Второе по величине
    ; число (т.е. ИСКОМОЕ) корректировать не надо.
Конец_цикла:
LOOP Цикл
Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку
Если ИСКОМОЕ = НАИБОЛЬШЕЕ печатаем, что все четные одинаковы и юзер тормоз
Печатаем ИСКОМОЕ

Добавлено через 5 минут
У тебя одна ошибка :

Assembler

Если Флаг 1 = ЛОЖЬ, то
       НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_1 = ПРАВДА
       GOTO Конец_цикла <- Вот это !!!

Assembler

;-------------------
CMP   BL, 0
JE    @1
JMP   @22
@1:
MOV   DX, AX
MOV   BL, 1
JMP   EndLoop   <------------ Забыл !!!
;-------------------

@Shura_deg · 11.05.2015, 18:04 **[ТС]**

Assembler

; multi-segment executable file template.
 
data segment
req        db  10,13,'ENTER ARRAY:$'
error      db  10,13,"INPUT ERROR$"
pkey       db  10,13,"press any key...$"
msg1       db  10,13,"THE SECOND LARGEST EVEN NUMBER:$"  
msg2       db  10,13,"ALL EVEN IDENTICAL, RETYPE$"
inpbuf     db  50 
len        db  0 
DBbuF      db  50 dup (?)
dwArray    dw  100 dup (?)
dimension  dw  0   
FIND dw 0
ends
 
stack segment
    dw   128  dup(0)
ends
 
code segment
start:
; set segment registers:
    MOV AX, DATA
    MOV DS, AX
    MOV ES, AX 
;================================================================
;==========================input array===========================
;================================================================
InputRESTART:
    XOR CX, CX
    XOR BX, BX
    XOR BP, BP
    XOR AX, AX 
InputStart:    
    mov  ah, 09h
    lea  dx, req
    int  21h
    
    mov ah, 0Ah
    lea dx, inpbuf      
    int 21h
    
    CMP len, 0
    JE  er
    LEA SI, DBbuF
    LEA DI, dwArray
    
    MOV BX, 10              ;notation
    XOR DX, DX
nachalo:
    PUSH DX    
    cmp byte ptr [si],"-" 
    jnz positive
    mov BP,1  
    inc si
positive:
    xor ax,ax
Inputcycle:    
    mov CL,[SI]
    CMP CL,0dh   ;ne konec li stroki         
    JZ  proverka
    CMP CL,20h
    JZ  proverka ; konec chisla (probel)
    
    SUB CL,'0'
    JL er
    CMP CL,9
    JA er
    MUL BX
    ADD AX, CX
    INC SI
    JMP Inputcycle
    
proverka:
    POP DX
    INC DX
    CMP BP,1
    JNZ neminys
    NEG AX
neminys:
    XOR BP, BP
    MOV [DI], AX
    ADD DI, 2
    INC SI
    CMP CL, 0dh
    JZ  endin    
    JMP nachalo    
er:
    MOV DX, offset error
    MOV AH, 09
    INT 21h
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h
    ;======================
    ;=====clear screen=====
    ;======================   
    MOV  AH, 00H
    MOV  AL, 03H  
    INT    10H  
    JMP InputRESTART 
           
endin:
    MOV dimension, DX   
;================================================================
;==========================main part=============================
;================================================================             
    LEA SI, DwArray 
    MOV CX, DX
    XOR BX, BX     
cycle:
    LODSW
;proverka na chetnost    
    TEST  AX, 01h
    JNZ   EndLoop
;-------------------
    CMP   BL, 0
    JNE   @1
    MOV   DX, AX
    MOV   BL, 1  
    JMP   EndLoop
;-------------------
@1:
    CMP   BH, 1
    JE    @2
    CMP   AX, DX
    JLE   @3
    MOV   BP, DX
    MOV   DX, AX
    MOV   BH, 1
    JMP   EndLoop
@3:
    MOV   BP, AX 
    MOV   BH, 1
    JMP   EndLoop
;-------------------
@2:
    CMP   AX, DX
    JL    @4
    MOV   BP, DX
    MOV   DX, AX
    JMP   EndLoop
@4:
    CMP   AX, BP
    JL    EndLoop
    MOV   BP, AX 
EndLoop:
    LOOP  cycle 
    MOV   FIND, BP
    CMP   BH, 0
    JE    ER   
    CMP   BP, DX
    JE    tormoz  
;================================================================
;==========================display a message on the screen=======
;================================================================
    LEA DX, msg1
    MOV AH, 9
    INT 21h          
;================================================================
;==========================Result output=========================
;================================================================    
    MOV  AX, BP
    TEST AX, AX
    JNS  oi1
    MOV  CX, AX
    MOV  AH, 02H
    MOV  DL, '-'
    INT  21H
    MOV  AX, CX
    NEG  AX
oi1:
    XOR CX, CX
    MOV BX, 10
oi2:
    XOR DX, DX
    DIV BX
    PUSH DX
    INC  CX
    TEST AX,AX
    JNZ  oi2
    MOV AH, 02H
oi3:
    POP DX
    CMP DL, 9
    JBE oi4
    ADD DL, 7
oi4:
    ADD DL, '0'
    INT 21H
    LOOP oi3       
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h 
    JMP InputRESTART
;================================================================
;==========================Tormoz================================
;================================================================         
tormoz:         
    lea dx, msg2
    mov ah, 9
    int 21h
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h  
    JMP InputRESTART   
Exit:    
    mov ax, 4c00h ; exit to operating system.
    int 21h    
ends
 
end start ; set entry point and stop the assembler.

Добавлено через 1 минуту
работает казалось бы на ура! но в ходе долгих проверок штук 20 я обнаружил ЧТО
при задаче такого массива 2, 2, -2, -2 считает что числа одинаковые и не выдаёт соответственно результата

@Ethereal · 11.05.2015, 20:34

Сообщение от Ethereal

Если ИСКОМОЕ = НАИБОЛЬШЕЕ печатаем, что все четные одинаковы и юзер тормоз

Это я затупил. Если ИСКОМОЕ = НАИБОЛЬШЕЕ, то два наибольших целых одинаковы, а не все они. Убрать эту строчку из алгоритма.

Получается, что это я - тормоз.

Добавлено через 16 минут

Код

Флаг1 = ЛОЖЬ
Флаг2 = ЛОЖЬ
Флаг_РАЗЛИЧНЫ = ЛОЖЬ <- добавление
Цикл:
 ЧИСЛО = очередной_элемент_массива
 Если ЧИСЛО нечетно, то GOTO Конец_цикла
 Если Флаг 1 = ЛОЖЬ, то
       НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_1 = ПРАВДА
       GOTO Конец_цикла
 Если ЧИСЛО != НАИБОЛЬШЕЕ, то Флаг_РАЗЛИЧНЫ = ПРАВДА <- добавление
 Если Флаг 2 = ЛОЖЬ, то
       Если ЧИСЛО <= НАИБОЛЬШЕЕ
            ИСКОМОЕ = ЧИСЛО
       в противном случае
            ИСКОМОЕ = НАИБОЛЬШЕЕ
            НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_2 = ПРАВДА
       GOTO Конец_цикла
 Если ЧИСЛО > НАИБОЛЬШЕЕ
      ИСКОМОЕ = НАИБОЛЬШЕЕ
      НАИБОЛЬШЕЕ = ЧИСЛО
      GOTO Конец_цикла
 Если ЧИСЛО > ИСКОМОЕ
      ИСКОМОЕ = ЧИСЛО
Конец_цикла:
LOOP Цикл
Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку
Если Флаг_РАЗЛИЧНЫ = ЛОЖЬ, то напечатать "Все четные одинаковы" <- добавление
Печатаем ИСКОМОЕ

Добавлено через 57 минут
Кстати, метафизический вопрос. Даны три числа : 2 2 -2.
Какое из них второе по величине ? По моему алгоритму 2.
Но ведь можно считать, что и -2. Тогда алго надо переделать.

@Shura_deg · 11.05.2015, 21:07 **[ТС]**

Сообщение от Ethereal

Какое из них второе по величине ? По моему алгоритму 2.

должно по идее быть -2
ксать тот алгоритм который я кидал рабочий в этом плане

Добавлено через 2 минуты
вот этот новый код который с

Сообщение от Ethereal

Флаг_РАЗЛИЧНЫ = ЛОЖЬ <- добавление

он работает в этом плане?
или всё же придётся алгоритм менять?

@Ethereal · 11.05.2015, 21:40

Придется менять. Щас поменяю. Я написал математически корректный алгоритм. А ты хочешь построенный на бытовой логике. Впрочем, хозяин-барин.

Добавлено через 9 минут
А там можно только одну строчку вставить (отталкиваясь от того, что ты уже написал) и все будет чики-пики

Код

Флаг1 = ЛОЖЬ
Флаг2 = ЛОЖЬ
Цикл:
 ЧИСЛО = очередной_элемент_массива
 Если ЧИСЛО нечетно, то GOTO Конец_цикла
 Если Флаг 1 = ЛОЖЬ, то
       НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_1 = ПРАВДА
       GOTO Конец_цикла
 Если ЧИСЛО = НАИБОЛЬШЕЕ, то GOTO Конец_цикла <- вставить
 Если Флаг 2 = ЛОЖЬ, то
       Если ЧИСЛО <= НАИБОЛЬШЕЕ
            ИСКОМОЕ = ЧИСЛО
       в противном случае
            ИСКОМОЕ = НАИБОЛЬШЕЕ
            НАИБОЛЬШЕЕ = ЧИСЛО
       Флаг_2 = ПРАВДА
       GOTO Конец_цикла
 Если ЧИСЛО > НАИБОЛЬШЕЕ
      ИСКОМОЕ = НАИБОЛЬШЕЕ
      НАИБОЛЬШЕЕ = ЧИСЛО
      GOTO Конец_цикла
 Если ЧИСЛО > ИСКОМОЕ
      ИСКОМОЕ = ЧИСЛО
Конец_цикла:
LOOP Цикл
Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку
Печатаем ИСКОМОЕ

Добавлено через 7 минут
Тут ошибка будет означать, что нету минимум двух разных четных.

Добавлено через 9 минут
Т.е. тут я только одну строчку вставил, помеченную "<- вставить" и после цикла условие ухода на ошибку оставил единственное. Более ничего не трогал.

Добавлено через 4 минуты
Вот эта строчка, которую я вставил, будет гарантировать, что ИСКОМОЕ не будет равно НАИБОЛЬШЕМУ. Числа уже равные текущему НАИБОЛЬШЕМУ будут отбрасываться, а значит текущее ИСКОМОЕ будет наибольшим из всех меньших его по величине чисел.

@Shura_deg · 11.05.2015, 22:14 **[ТС]**

всё работает на ура (тестил раз 30)
вот код (а можно было бы его ещё как то усовершенствовать в плане быстродействия
наверное это уже глупости но чисто ради "спортивного интереса"

Assembler

; multi-segment executable file template.
 
data segment
req        db  10,13,'ENTER ARRAY:$'
error      db  10,13,"INPUT ERROR$"
pkey       db  10,13,"press any key...$"
msg1       db  10,13,"THE SECOND LARGEST EVEN NUMBER:$"  
msg2       db  10,13,"ALL EVEN IDENTICAL, RETYPE$"
inpbuf     db  50 
len        db  0 
DBbuF      db  50 dup (?)
dwArray    dw  100 dup (?)
dimension  dw  0   
FIND dw 0
ends
 
stack segment
    dw   128  dup(0)
ends
 
code segment
start:
; set segment registers:
    MOV AX, DATA
    MOV DS, AX
    MOV ES, AX 
;================================================================
;==========================input array===========================
;================================================================
InputRESTART:
    XOR CX, CX
    XOR BX, BX
    XOR BP, BP
    XOR AX, AX 
InputStart:    
    mov  ah, 09h
    lea  dx, req
    int  21h
    
    mov ah, 0Ah
    lea dx, inpbuf      
    int 21h
    
    CMP len, 0
    JE  er
    LEA SI, DBbuF
    LEA DI, dwArray
    
    MOV BX, 10              ;notation
    XOR DX, DX
nachalo:
    PUSH DX    
    cmp byte ptr [si],"-" 
    jnz positive
    mov BP,1  
    inc si
positive:
    xor ax,ax
Inputcycle:    
    mov CL,[SI]
    CMP CL,0dh   ;ne konec li stroki         
    JZ  proverka
    CMP CL,20h
    JZ  proverka ; konec chisla (probel)
    
    SUB CL,'0'
    JL er
    CMP CL,9
    JA er
    MUL BX
    ADD AX, CX
    INC SI
    JMP Inputcycle
    
proverka:
    POP DX
    INC DX
    CMP BP,1
    JNZ neminys
    NEG AX
neminys:
    XOR BP, BP
    MOV [DI], AX
    ADD DI, 2
    INC SI
    CMP CL, 0dh
    JZ  endin    
    JMP nachalo    
er:
    MOV DX, offset error
    MOV AH, 09
    INT 21h
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h
    ;======================
    ;=====clear screen=====
    ;======================   
    MOV  AH, 00H
    MOV  AL, 03H  
    INT    10H  
    JMP InputRESTART 
           
endin:
    MOV dimension, DX   
;================================================================
;==========================main part=============================
;================================================================             
    LEA SI, DwArray 
    MOV CX, DX
    XOR BX, BX     
cycle:
    LODSW
;proverka na chetnost    
    TEST  AX, 01h
    JNZ   EndLoop
;-------------------
    CMP   BL, 0
    JNE   @1
    MOV   DX, AX
    MOV   BL, 1  
    JMP   EndLoop
;-------------------
@1: 
    CMP   AX, DX
    JE    EndLoop
    CMP   BH, 1
    JE    @2
    CMP   AX, DX
    JLE   @3
    MOV   BP, DX
    MOV   DX, AX
    MOV   BH, 1
    JMP   EndLoop
@3:
    MOV   BP, AX 
    MOV   BH, 1
    JMP   EndLoop
;-------------------
@2:
    CMP   AX, DX
    JL    @4
    MOV   BP, DX
    MOV   DX, AX
    JMP   EndLoop
@4:
    CMP   AX, BP
    JL    EndLoop
    MOV   BP, AX 
EndLoop:
    LOOP  cycle 
    MOV   FIND, BP
    CMP   BH, 0
    JE    tormoz   
    CMP   BP, DX
    JE    tormoz  
;================================================================
;==========================display a message on the screen=======
;================================================================
    LEA DX, msg1
    MOV AH, 9
    INT 21h          
;================================================================
;==========================Result output=========================
;================================================================    
    MOV  AX, BP
    TEST AX, AX
    JNS  oi1
    MOV  CX, AX
    MOV  AH, 02H
    MOV  DL, '-'
    INT  21H
    MOV  AX, CX
    NEG  AX
oi1:
    XOR CX, CX
    MOV BX, 10
oi2:
    XOR DX, DX
    DIV BX
    PUSH DX
    INC  CX
    TEST AX,AX
    JNZ  oi2
    MOV AH, 02H
oi3:
    POP DX
    CMP DL, 9
    JBE oi4
    ADD DL, 7
oi4:
    ADD DL, '0'
    INT 21H
    LOOP oi3       
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h 
    JMP InputRESTART
;================================================================
;==========================Tormoz================================
;================================================================         
tormoz:         
    lea dx, msg2
    mov ah, 9
    int 21h
    ;======================
    ;=wait for any key....=
    ;======================      
    lea dx, pkey
    mov ah, 9
    int 21h
    ;=====================   
    ;=====================  
    mov ah, 1
    int 21h  
    JMP InputRESTART   
Exit:    
    mov ax, 4c00h ; exit to operating system.
    int 21h    
ends
 
end start ; set entry point and stop the assembler.

@Shura_deg 83 / 19 / 5 Регистрация: 01.02.2015 Сообщений: 655
	09.05.2015, 12:20 [ТС]	2
	exe.rar ВОт откомпилированный файл 0

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,047
	09.05.2015, 15:43	5
	Сообщение от Shura_deg правильно ибо мне нужно найти второе по величине чётное число а следовательно если одно чётное то не будет результата К этому циклу претензий нет. Если в массиве два и более четных и все одинаковые, то ошибка будет на следующем цикле. 1

@Shura_deg 83 / 19 / 5 Регистрация: 01.02.2015 Сообщений: 655
	09.05.2015, 15:44 [ТС]	6
	Сообщение от Ethereal Словом Parity называют нечто другое. к слову https://translate.google.ru/#r... 1%82%D1%8C 0

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,047
	09.05.2015, 15:44	7
	Сообщение от Shura_deg так да я это специально подгонял.... Если массив 2 2 2 2 2 2 , то второе по величине четное есть и оно 2 1

@Shura_deg 83 / 19 / 5 Регистрация: 01.02.2015 Сообщений: 655
	09.05.2015, 15:47 [ТС]	8
	Сообщение от Ethereal К этому циклу претензий нет. Если в массиве два и более четных и все одинаковые, то ошибка будет на следующем цикле. не додумал как в один уместить... Добавлено через 2 минуты Сообщение от Ethereal Если массив 2 2 2 2 2 2 , то второе по величине четное есть и оно 2 так то да но это же не логично .... 2=2 а если второе по величине следовательно оно не <> друг другу.... но конечно можно так как и вы сделать чисто выйти сразу на ответ указав это чётное число в качестве ответа 0

@Shura_deg 83 / 19 / 5 Регистрация: 01.02.2015 Сообщений: 655
	11.05.2015, 21:07 [ТС]	14
	Сообщение от Ethereal Какое из них второе по величине ? По моему алгоритму 2. должно по идее быть -2 ксать тот алгоритм который я кидал рабочий в этом плане Добавлено через 2 минуты вот этот новый код который с Сообщение от Ethereal Флаг_РАЗЛИЧНЫ = ЛОЖЬ <- добавление он работает в этом плане? или всё же придётся алгоритм менять? 0

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,047
	11.05.2015, 21:40	15
	Придется менять. Щас поменяю. Я написал математически корректный алгоритм. А ты хочешь построенный на бытовой логике. Впрочем, хозяин-барин. Добавлено через 9 минут А там можно только одну строчку вставить (отталкиваясь от того, что ты уже написал) и все будет чики-пики Код Флаг1 = ЛОЖЬ Флаг2 = ЛОЖЬ Цикл: ЧИСЛО = очередной_элемент_массива Если ЧИСЛО нечетно, то GOTO Конец_цикла Если Флаг 1 = ЛОЖЬ, то НАИБОЛЬШЕЕ = ЧИСЛО Флаг_1 = ПРАВДА GOTO Конец_цикла Если ЧИСЛО = НАИБОЛЬШЕЕ, то GOTO Конец_цикла <- вставить Если Флаг 2 = ЛОЖЬ, то Если ЧИСЛО <= НАИБОЛЬШЕЕ ИСКОМОЕ = ЧИСЛО в противном случае ИСКОМОЕ = НАИБОЛЬШЕЕ НАИБОЛЬШЕЕ = ЧИСЛО Флаг_2 = ПРАВДА GOTO Конец_цикла Если ЧИСЛО > НАИБОЛЬШЕЕ ИСКОМОЕ = НАИБОЛЬШЕЕ НАИБОЛЬШЕЕ = ЧИСЛО GOTO Конец_цикла Если ЧИСЛО > ИСКОМОЕ ИСКОМОЕ = ЧИСЛО Конец_цикла: LOOP Цикл Если Флаг_2 = ЛОЖЬ, то GOTO на ошибку Печатаем ИСКОМОЕ Добавлено через 7 минут Тут ошибка будет означать, что нету минимум двух разных четных. Добавлено через 9 минут Т.е. тут я только одну строчку вставил, помеченную "<- вставить" и после цикла условие ухода на ошибку оставил единственное. Более ничего не трогал. Добавлено через 4 минуты Вот эта строчка, которую я вставил, будет гарантировать, что ИСКОМОЕ не будет равно НАИБОЛЬШЕМУ. Числа уже равные текущему НАИБОЛЬШЕМУ будут отбрасываться, а значит текущее ИСКОМОЕ будет наибольшим из всех меньших его по величине чисел. 1