Ошибка в программе - вывести введенное имя пользователя

@zer0ed · Регистрация: 07.06.2015

Author24 — интернет-сервис помощи студентам

В программе ошибка. Я не могу ее найти.
Пользователь должен ввести свое имя. Потом нужно очистить экран и в левом верхнем углу вывести это имя.
Но оно не выводится!
Помогите найти ошибку.

Assembler

stacksg segment para stack 'stack'
    DW      32 dup ('*')
stacksg ends
 
datasg  segment para 'data'
    namepar     label   BYTE
    maxLen      DB      20
    nameLen     DB      0
    userName    DB      20 dup(' '), '$'
    
    prompt      DB      "Enter your name ", '$'
datasg  ends
 
codesg  segment para 'code'
    begin    proc    far
        assume  cs:codesg, ds:datasg, ss:stacksg, es:datasg
        push    ds
        sub     ax, ax
        push    ax
        mov     ax, datasg
        mov     ds, ax
        mov     es, ax
        
        call    ClearScreen     ; Очистить экран
        call    ShowPrompt      ; Выдать текст запроса
        call    InputName       ; Ввести имя
        call    ClearScreen     ; Очистить экран
        call    SetCursor       ; Установить курсор
        call    ShowName        ; Вывести имя
        ret
    begin    endp
    
    ; Выдать текст запроса
    ShowPrompt   proc    near
        mov     ah, 09
        lea     dx, prompt
        int     21h
        ret
    ShowPrompt   endp
    
    ; Ввести имя
    InputName    proc    near
        mov     ah, 0Ah
        lea     dx, namepar
        int     21h
        ret
    InputName    endp
    
    ; Вывести имя
    ShowName     proc    near
        mov     ah, 09
        lea     dx, userName
        int     21h
        ret
    ShowName     endp
    
    ; Очистка экрана
    ClearScreen proc    near
        mov     ax, 0600h
        mov     bh, 30
        mov     cx, 0000
        mov     dx, 184Fh   ; 24,79
        int     10h
        ret
    ClearScreen endp
    
    ; Установка курсора
    SetCursor   proc    near
        mov     ah, 02
        mov     bh, 00
        mov     dx, 0000
        int     10h
        ret
    SetCursor   endp
codesg  ends
    end begin

@Ethereal · 08.06.2015, 07:11

У тебя буфер ввода изначально заполнен пробелами, а потом $
Предположим, что ты вводишь имя Ethereal
Тогда в буфере получится
'Ethereal' 0Dh <куча пробелов> $
Сначала выведется 'Ethereal'
потом 0Dh - возврат каретки, который вернет каретку (курсор) в начало строки
потом <куча пробелов> которые затрут поверх имя 'Ethereal'
и наконец встретившийся $ завершит вывод.

Итого, имя у тебя выводится, да только тут-же затирается пробелами.

Добавлено через 5 минут
Поставь в своей программе вместо mov dx,0000 в функции установки позиции курсора mov dx,40 и больше ничего не меняй. Т.е. поставь курсор не в левый верхний угол, а в середину верхней строки. И ты увидишь введенное имя. Т.е. оно действительно выводится ... только тут-же затирается

@zer0ed · 08.06.2015, 14:13 **[ТС]**

Вот что значит невнимательность

Действительно, после ввода возврат каретки остается в строке. Я совсем забыл про это.
Спасибо

Переписал функцию ввода имени

Assembler

    ; Ввести имя
    InputName   proc    near
        mov     ah, 0Ah
        lea     dx, namepar
        int     21h
        
        ; Заменить оставшийся Return на '$'
        mov     bh, 00
        mov     bl, nameLen
        mov     userName[bx], '$'
        ret
    InputName   endp

Теперь работает как надо.

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,047
	08.06.2015, 07:11	2
	Сообщение было отмечено zer0ed как решение Решение У тебя буфер ввода изначально заполнен пробелами, а потом $ Предположим, что ты вводишь имя Ethereal Тогда в буфере получится 'Ethereal' 0Dh <куча пробелов> $ Сначала выведется 'Ethereal' потом 0Dh - возврат каретки, который вернет каретку (курсор) в начало строки потом <куча пробелов> которые затрут поверх имя 'Ethereal' и наконец встретившийся $ завершит вывод. Итого, имя у тебя выводится, да только тут-же затирается пробелами. Добавлено через 5 минут Поставь в своей программе вместо mov dx,0000 в функции установки позиции курсора mov dx,40 и больше ничего не меняй. Т.е. поставь курсор не в левый верхний угол, а в середину верхней строки. И ты увидишь введенное имя. Т.е. оно действительно выводится ... только тут-же затирается 2

	08.06.2015, 14:13

Ошибка в программе - вывести введенное имя пользователя

Решение