Создание папки

@Andrey040601 · Регистрация: 13.07.2014

Author24 — интернет-сервис помощи студентам

Как сделать создание папки с названием, которое вводит пользователь? Нашел вот такое:

Assembler

CSEG segment
org 100h
 
start:
mov ah, 9
mov dx, offset msg
int 21h
 
mov ah, 0ah
mov dx, offset nam1
int 21h
 
mov ah, 39h
mov dx, offset nam1
int 21h
 
int 20h
 
msg db 'Enter dir: $', 0
nam1 db 40, 0, 40 dup(?)
 
CSEG ends
end start

Но оно не работает. Как правильно? И что вообще значит эта строка

Assembler

1	nam1 db 40, 0, 40 dup(?)

?

Charles Kludge · 26.09.2015, 20:15

Сообщение от Andrey040601

Как правильно?

Assembler

; MASM
    dos_inp macro lbl, sz
    _ib_    struc
    max db sz           ; наибольшая длина строки
    len db ?            ; сюда вернется настоящая длина
    bf  db sz dup(?)        ; тут будет то, что ввели
    _ib_    ends
    lbl _ib_ <>
    endm
 
    .model  tiny
    .code
    org 100h
 
start:
    mov ah, 9
    lea dx, msg
    int 21h
 
    mov ah, 0ah
    lea dx, nam1
    int 21h
 
    lea dx, nam1.bf
    xor bx, bx
    mov bl, nam1.len
    add bx, dx
    mov byte ptr [bx],0
 
    mov ah, 39h
    int 21h
 
    int 20h
 
    msg db 'Enter dir: $', 0
dos_inp nam1,40
 
    end start

Сообщение от Andrey040601

И что вообще значит эта строка

См. в тексте проги. Читайте Ральфа.

@proc3nt · 26.09.2015, 20:48

Сообщение от Andrey040601

mov ah, 0ah
mov dx, offset nam1
int 21h

чтобы создать папку с заданным именем, имя должно заканчиваться нулем. а при вводе имени папки с помощью функции 0ah последним символом будет "воврат каретки". вот его то и нужно заменить.

Assembler

xor ah,ah           ;обнуление регистра
mov al,[nam1+1]     ;количество символов во введенном имени
mov bx,offset nam1+2;адрес начала имени
add bx,ax           ;адрес символа "возврат каретки"
mov byte ptr [bx],0 ;замена символа "возврат каретки" на ноль

Добавлено через 5 минут

Сообщение от Andrey040601

mov ah, 39h
mov dx, offset nam1
int 21h

и тогда нужно указывать адрес начала имени папки, а не максимально возможного количества символов в имени папки

Assembler

1
2
3

mov ah,39h
mov dx,offset nam1+2
int 21h

	26.09.2015, 20:48