Из записи натурального числа N выбросить все цифры, кратные заданной

@Милена1 · Регистрация: 07.09.2015

Author24 — интернет-сервис помощи студентам

Вот такая вот задача. Из записи натурального числа N выбросить все цифры, кратные
заданной, оставив прежним порядок остальных цифр. С языком еще не очень знакома, можете подсказать хотя бы принцип и последовательность действий, при помощи которых можно решить эту задачу. А то совсем никаких идей нет. Заранее благодарна.

@Mikl___ · 23.04.2016, 03:43

Милена1,
а другие языки программирования ты знаешь? Попробуй эту задачу выполнить на Паскале, Си или Бейсике... Результаты выложишь здесь, а дальше поможем

@Милена1 · 23.04.2016, 15:17 **[ТС]**

но вот на с++

C++

int main()
{
    int a, s=0, i=1 , n, k;
    cin >> a >> n;
    while (a)
    {
        if ((k = a % 10)%n!=0)
        {
            s += k*i;
            i *= 10;
        }
        a /= 10;
    }
    cout << s;
}

@R71MT · 23.04.2016, 21:09

Милена1, пример с 16-тиричным числом 8F5Ch размером в 2 байта (16 бит).
Разбиваем его на 4 тетрады, в каждой из которых можно закодировать числа 00..0Fh (00..15d):

Assembler

1 2	hex = 8 F 5 C bin = 1000 1111 0101 1100

Из этого следует, что тебе нужно выталкивать из твоего числа по 4 бита, и проверять их на кратность заданной константе. Как-нельзя-лучше подходит для этого команда SHLD. У неё 3 операнда:

Assembler

1	SHLD приёмник, источник, счетчик

SHLD сдвигает влево биты приёмника на количество бит, указанных в третьем операнде(счётчике). Освободившееся место приёмника занимают старшие биты источника. При этом значение источника не меняется. Для следующей тетрады источник нужно сдвигать вручную. Вот что можно из этого наваять..

Assembler

org 100h
jmp start
 
mes0   db  13,10,'Default digit: F9A3h'
       db  13,10,'Binary codes : 1111 1001 1010 0011b'
       db  13,10,'Type constant: $'
ress   db  13,10,'       Result: $'
digit  dw  0F9A3h
const  db  0
 
start:
    mov   dx,mes0         ;
    call  message         ;
    mov   ah,8            ; вводим константу
@@: int   21h             ;
    cmp   al,'0'          ; игнорируем всё,
    jb    @b              ;     ..кроме цифр 0..9
    cmp   al,'9'          ;
    ja    @b              ;
    int   29h             ;
    and   ax,0Fh          ; переводим символ в цифру,
    push  ax              ;     ..и запоминаем её
    mov   dx,ress         ;
    call  message         ;
 
    pop   bx              ; ВХ = константа (делитель)
    xor   ax,ax           ; АХ будет результат (пока очищаем)
    mov   si,[digit]      ; натуральное число
    mov   cx,4            ; кол-во цифр в числе
@@: shld  ax,si,4         ; см.описание выше!
    push  ax              ; запомним АХ
    and   ax,0Fh          ; оставляем только мл.тетраду числа
    cwd                   ; очищаем место под остаток (DX=0)
    div   bx              ; разделить АХ на ВХ
    pop   ax              ; восстановим число
    or    dx,dx           ; в DX есть остаток?
    jnz   ok              ; есть - пропускаем тетраду в приёмник
    shr   ax,4            ; иначе: удаляем её от туда
ok: rol   si,4            ; сдвинем на 4 влево источник (сл.тетрада для проверки)
    loop  @b              ; проверяем оставшиеся цифры..
                          ; в АХ у нас результат! ==============================
    call  hexOut          ;      ..выводим его на экран
    mov   al,'h'          ; вставляем в конец литер "hex"
    int   29h             ;
 
exit:                     ;
    xor   ax,ax           ;
    int   16h             ;
    int   20h             ; выход!
 
;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
message:                  ;
   mov   ah,9             ;
   int   21h              ;
ret                       ;
;-----------------------------------------------------------------------
; процедура выводит EАХ на экран в HEX
hexOut:                   ;
   pusha                  ;
   xchg  dx,ax            ; DX = число
   mov   cx,4             ; кол-во цифр для вывода
@@:                       ;
   shld  ax,dx,4          ; получить в AL очередную цифру
   rol   dx,4             ; удалить ее из DX
   and   al,0Fh           ; оставить в AL только эту цифру
   cmp   al,0Ah           ; три команды, переводящие
   sbb   al,69h           ;    ..шестнадцатеричную цифру из AL
   das                    ;         ..в соответствующий ASCII-код
   int   29h              ; вывод на экран
   loop  @b               ; повторить для всех цифр
   popa                   ;
ret                       ;

@Милена1 0 / 0 / 0 Регистрация: 07.09.2015 Сообщений: 12
		1
	Из записи натурального числа N выбросить все цифры, кратные заданной 22.04.2016, 20:14. Показов 1179. Ответов 3 Метки нет (Все метки) Вот такая вот задача. Из записи натурального числа N выбросить все цифры, кратные заданной, оставив прежним порядок остальных цифр. С языком еще не очень знакома, можете подсказать хотя бы принцип и последовательность действий, при помощи которых можно решить эту задачу. А то совсем никаких идей нет. Заранее благодарна. 0

@Mikl___ Ушел с форума 16279 / 7604 / 1065 Регистрация: 11.11.2010 Сообщений: 13,617
	23.04.2016, 03:43	2
	Милена1, а другие языки программирования ты знаешь? Попробуй эту задачу выполнить на Паскале, Си или Бейсике... Результаты выложишь здесь, а дальше поможем 1

	23.04.2016, 21:09