Примитивный калькулятор (два операнда и операции сложения, вычитания, умножения и деления)

@Fenixsenok · Регистрация: 13.12.2016

Author24 — интернет-сервис помощи студентам

Здравствуйте.
Вот пытался написать примитивный калькулятор, которые будет +, -, * и / два значения, введенные пользователём, только есть одно условие, пользователь должен одним вводом ввести уравнение, например,
3 + 5
6 – 3
2 * 2
или
6 / 2
Мне нужно чтобы программа считывала какой знак был введен между цыфрами и на его основе производить вычесления.

Была идея, чтобы сохранять введенную пользователем строку в одной переменной, например, userInput DW '3 + 5', а затем разбить данную строку на три значения, firstNumber DW '3', operator DW '+' и secondNumber DW '5'.

При создании я не должен использовать библиотечные функции и код должен быть написан на Masm32.

К сожалению, моих знаний и практики не достаточно чтобы выполнить подобную задачу.
Буду благодарен за любой пример.

@R71MT · 06.04.2018, 12:14

Сообщение от Fenixsenok

Вот пытался написать примитивный калькулятор

где он???

Добавлено через 1 минуту
если числа от 0 до 9, то проблем нет, а если больше, то уже нужно сохранять ввод в буфер

@Fenixsenok · 06.04.2018, 12:50 **[ТС]**

примерно вот так...

Assembler

.586                                                                    ; Recognise 80x86 instructions that use 32-bit
.MODEL FLAT, STDCALL                                                    ; Generate code for a flat memory model
option casemap :none
.STACK 4096                                                             ; Reserve 4096 bytes for stack operations
 
ExitProcess proto dwExitCode:dword
GetStdHandle proto :dword
WriteConsoleA proto :dword, :dword, :dword, :dword, :dword
ReadConsoleA  proto :dword, :dword, :dword, :dword, :dword
 
 
STD_OUTPUT_HANDLE equ -11                                               ; The standard output device
STD_INPUT_HANDLE equ -10                                                ; The standard output device
 
    
.DATA
 
    
    promptUserInput         DB 10, 13, 'Please enter your equation: ', 0
 
    outputHandle    DWORD ?
    bytes_written   DD ?
    inputHandle DWORD ?
    bytes_read  DWORD ?
 
    buffer_size = 100
 
    bufferUserInput         DB buffer_size dup(?)
 
    bufferForSign           DB buffer_size dup(?)
    bufferFirstNumber       DB buffer_size dup(?)
    bufferSecondNumber      DB buffer_size dup(?)
    result                  DB buffer_size dup(?)
 
 
 
.CODE
    main PROC
        invoke GetStdHandle, STD_OUTPUT_HANDLE
        mov outputHandle, eax
        mov eax, LENGTHOF promptUserInput
        invoke WriteConsoleA, outputHandle, addr promptUserInput, eax, addr bytes_written, 0
        mov eax, 0
        mov eax, bytes_written
        mov eax, 0
    
        invoke GetStdHandle, STD_INPUT_HANDLE
        mov inputHandle, eax
        invoke ReadConsoleA, inputHandle, addr bufferUserInput, buffer_size, addr bytes_read, 0
 
 
        cmp bufferForSign, '+'
        je addition
 
        jne finish_program
 
 
        addition:
            mov ax, 0
            mov ax, bufferFirstNumber       
            add ax, bufferSecondNumber
            mov result, eax
        
            invoke WriteConsoleA, outputHandle, addr result, eax, addr bytes_written, 0
 
    main ENDP
    
    finish_program PROC     
        invoke ExitProcess, 0
    finish_program ENDP
END main

Вот только как разделит переменную на три я понятия не имею...

ФедосеевПавел · 06.04.2018, 13:03

Зачем делить? Обрабатывайте в потоке.
У вас 3 переменные: операнд1, операнд2, операция.

При инициализации операнд1=0, операция=сложение (чтобы не повлиять).
Начинаете обрабатывать строку посимвольно
1. if Buffer[esi]='0'...'9' then Op2:=Op2*10+(Buffer[esi]-'0'); к следующему символу строки

2.1. Если не цифра, то выполнить вычисление Op1:= Op1 (Operation) Op2; Op2:=0;
2.2. Уточнить операцию для следующего вычисления
2.2.1. if Buffer[esi]='+' then Operation:=сложение
2.2.2. if Buffer[esi]='-' then Operation:=вычитание
...
2.2.7. if Buffer[esi]=Enter then выйти
3. esi:=esi+1
4. перейти к п.1

5. вывод результата (Op1)

Так я и делал в Написать программу, позволяющую выполнять арифметические действия над двоичными или шестнадцатеричными числами

ФедосеевПавел · 07.04.2018, 23:04

Assembler

.686
.model flat, stdcall
option casemap :none
 
        include \masm32\include\windows.inc
 
        include \masm32\include\user32.inc
        include \masm32\include\kernel32.inc
        include \masm32\include\masm32.inc
 
        includelib \masm32\lib\user32.lib
        includelib \masm32\lib\kernel32.lib
        includelib \masm32\lib\masm32.lib
.data
        aszPrompt       db      'Expression: ', 0Dh, 0Ah, 0
        aszPressEnter   db      0Dh, 0Ah, 0Dh, 0Ah, "Press ENTER to exit", 0
        aszResult       db      10, 13, "Result of your equation is %d", 0
 
        OpAdd           equ     '+'
        OpSub           equ     '-'
        OpMul           equ     '*'
        OpDiv           equ     '/'
 
        AllowedChars    db      '=+-*/0123456789'
        LenAllowedChars equ     $-AllowedChars
        OpChars         db      '=+-*/'
        LenOpChars      equ     $-OpChars
.data?
        hConsoleOutput  HANDLE  ?
        hConsoleInput   HANDLE  ?
        Buffer          db      1024 dup(?)
        BufLen          dd      ?
        Result          dd      ?
        Op1             dd      ?
        Op2             dd      ?
        Operation       db      ?
.code
 
PrevOperation   proc
                mov     eax,    [Op1]
                cdq
                mov     ebx,    [Op2]
                cmp     [Operation],    OpAdd
                jne     @@Sub
                add     eax,    ebx
                jmp     @@Calc
        @@Sub:
                cmp     [Operation],    OpSub
                jne     @@Mul
                sub     eax,    ebx
                jmp     @@Calc
        @@Mul:
                cmp     [Operation],    OpMul
                jne     @@Div
                mul     ebx
        @@Div:
                cmp     [Operation],    OpDiv
                jne     @@Calc
                idiv    ebx
        @@Calc:
                mov     [Op1],  eax
                mov     [Op2],  0
                mov     al,     [esi-1]
                mov     [Operation],    al
        ret
PrevOperation   endp
 
main    proc
 
        ; получение описателей ввода и вывода консоли
        invoke  GetStdHandle,   STD_INPUT_HANDLE
        mov     hConsoleInput,  eax
 
        invoke  GetStdHandle,   STD_OUTPUT_HANDLE
        mov     hConsoleOutput, eax
 
        invoke  ClearScreen
 
        ;ввод выражения
        invoke  WriteConsole, hConsoleOutput, ADDR aszPrompt,\
                LENGTHOF aszPrompt-1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
        lea     esi,    [Buffer]        ;удаление из буфера
        add     esi,    [BufLen]        ;символов перевода строки
        mov     [esi-2],word ptr 0
        sub     [BufLen],       2
 
        ;обработка выражения во введённой строке
        mov     eax,    0
        mov     [Op1],  0
        mov     [Op2],  0
        mov     [Operation],    OpAdd
 
        lea     esi,    [Buffer]
        mov     ecx,    [BufLen]
        @@GetCmd:
                push    ecx
                lodsb
                ;проверка корректности введённых символов
                lea     edi,    [AllowedChars]
                mov     ecx,    [LenAllowedChars]
                repne   scasb
                jnz     @@Next
        @@ProcessChar:
                lea     edi,    [OpChars]
                mov     ecx,    [LenOpChars]
                repne   scasb
                jz      @@DoOperation
        @@TestDigits:
                ;введена цифра
                and     eax,    0FFh
                sub     al,     '0'
                mov     ebx,    [Op2]
                lea     eax,    [eax+8*ebx]
                lea     eax,    [eax+2*ebx]
                mov     [Op2],  eax
 
                pop     ecx
                push    ecx
                cmp     ecx,    1
                jne     @@Next
 
        @@DoOperation:
                ;сначала завершается предыдущая операция
                call    PrevOperation
                cmp     al,     '='
                jne     @@Next
                pop     ecx
                jmp     @@Break
        @@Next:
                pop     ecx
        loop    @@GetCmd
@@Break:
ResultShow:
        ;вывод результата
        mov     eax,    [Op1]
        invoke  wsprintf, ADDR Buffer, ADDR aszResult, eax
        mov     [BufLen],       eax
        invoke  WriteConsole, hConsoleOutput, ADDR Buffer,\
                BufLen, ADDR BufLen, NULL
 
        ;ожидание нажатия ENTER
        invoke  WriteConsole, hConsoleOutput, ADDR aszPressEnter,\
                LENGTHOF aszPressEnter - 1, ADDR BufLen, NULL
        invoke  ReadConsole, hConsoleInput, ADDR Buffer,\
                LENGTHOF Buffer, ADDR BufLen, NULL
 
        invoke  ExitProcess, 0
main    endp
 
end     main

ФедосеевПавел · 07.01.2020, 10:51

Нужно изменить строки

Assembler

102	mov ecx, LenAllowedChars

Assembler

107	mov ecx, LenOpChars

Т.к. и LenAllowedChars и LenOpChars - константы и лишь безразличие masm к квадратным скобкам позволяет избежать ошибки обращения к недоступным адресам при заполнении регистра ecx.

@Fenixsenok 0 / 0 / 0 Регистрация: 13.12.2016 Сообщений: 8
		1
	MASM32 Примитивный калькулятор (два операнда и операции сложения, вычитания, умножения и деления) 06.04.2018, 12:00. Показов 4719. Ответов 5 Метки 2, assembly, c, calculate, masm32, splitstring (Все метки) Здравствуйте. Вот пытался написать примитивный калькулятор, которые будет +, -, * и / два значения, введенные пользователём, только есть одно условие, пользователь должен одним вводом ввести уравнение, например, 3 + 5 6 – 3 2 * 2 или 6 / 2 Мне нужно чтобы программа считывала какой знак был введен между цыфрами и на его основе производить вычесления. Была идея, чтобы сохранять введенную пользователем строку в одной переменной, например, userInput DW '3 + 5', а затем разбить данную строку на три значения, firstNumber DW '3', operator DW '+' и secondNumber DW '5'. При создании я не должен использовать библиотечные функции и код должен быть написан на Masm32. К сожалению, моих знаний и практики не достаточно чтобы выполнить подобную задачу. Буду благодарен за любой пример. 0

@R71MT Эксперт Hardware 6103 / 2347 / 390 Регистрация: 29.07.2014 Сообщений: 3,108 Записей в блоге: 4
	06.04.2018, 12:14	2
	Сообщение от Fenixsenok Вот пытался написать примитивный калькулятор где он??? Добавлено через 1 минуту если числа от 0 до 9, то проблем нет, а если больше, то уже нужно сохранять ввод в буфер 0

ФедосеевПавел Модератор 8476 / 4335 / 1642 Регистрация: 01.02.2015 Сообщений: 13,461 Записей в блоге: 8
	06.04.2018, 13:03	4
	Зачем делить? Обрабатывайте в потоке. У вас 3 переменные: операнд1, операнд2, операция. При инициализации операнд1=0, операция=сложение (чтобы не повлиять). Начинаете обрабатывать строку посимвольно 1. if Buffer[esi]='0'...'9' then Op2:=Op2*10+(Buffer[esi]-'0'); к следующему символу строки 2.1. Если не цифра, то выполнить вычисление Op1:= Op1 (Operation) Op2; Op2:=0; 2.2. Уточнить операцию для следующего вычисления 2.2.1. if Buffer[esi]='+' then Operation:=сложение 2.2.2. if Buffer[esi]='-' then Operation:=вычитание ... 2.2.7. if Buffer[esi]=Enter then выйти 3. esi:=esi+1 4. перейти к п.1 5. вывод результата (Op1) Так я и делал в Написать программу, позволяющую выполнять арифметические действия над двоичными или шестнадцатеричными числами 0

	07.01.2020, 10:51