Ввести строку С, определить чего в строке больше цифр, букв или знаков пунктуации

@boikosad · Регистрация: 11.06.2018

Author24 — интернет-сервис помощи студентам

Сделать программу на ассемблере.
Задание:
Ввести строку С,определить чего в строке больше цифр,букв или знаков пунктуации.

@~~masha777~~ · 11.06.2018, 21:37

Ребят, нужно написать программу на ассемблере.Задание Ввести строку С,определить чего в строке больше цифр,букв или знаков пунктуации.Заранее спасибо.

@boikosad · 14.06.2018, 10:56 **[ТС]**

Есть код который подсчитивает количество букв и цифр в строке,хочу добавить чтобы считало еще и знаки пунктуации,но хз как

Assembler

.model small
 
.code
org 100h
start:
 
    mov ah,0Ah
    lea dx,buf
    mov si,dx
    int 21h
 
    mov ah,9
    lea dx,digital
    int 21h
 
    inc si
    xor ax,ax
    xor cx,cx
    mov cl,[si]
push cx
    inc si
    mov dx,si
m1:
    lodsb
push cx
    mov cl,10
    lea di,tab
    repne scasb
    jnz short m2
 
    inc ah
m2:
pop cx
    loop m1
    xor al,al
    xchg ah,al
push ax
    call OutInt
 
    mov ah,9
    lea dx,undigital
    int 21h
pop ax
pop cx
    xchg ax,cx
    sub ax,cx
    call OutInt
 
    mov ah,0
    int 16h
 
    ret
OutInt  proc near
    xor cx,cx
    mov bx,10
oi2:
    xor dx,dx
    div bx
    push dx
    inc cx
    test ax,ax
    jnz short oi2
    mov ah,02h
oi3:
    pop dx
    add dl,'0'
    int 21h
    loop oi3
    ret
OutInt  endp
digital   db 10,13,'Cifrovyh simvolov:    $'
undigital db 10,13,'Ne cifrovyh simvolov: $'
 
tab db  '0123456789'
 
buf db 254
    end start

?

@R71MT · 14.06.2018, 11:26

Сообщение от masha777

определить чего в строке больше цифр,букв или знаков пунктуации

..а чем они отличаются знаешь?
можешь скачать справочник ASCII-символов и посмотреть, тогда и помощь не потребуется.

@Jin X · 14.06.2018, 18:15

Я тут, кстати, недавно придумал способ проверки символа на букву (причём, неважно: русскую или английскую, заглавную или строчную), правда, под Windows.
Но всё равно напишу, может, кому пригодится.

Вызываем CharLower и CharUpper. Если результат разный, значит буква:

Assembler

; al = буква
movzx ebx,al
invoke CharUpper, ebx
xchg eax,ebx
invoke CharLower, eax
cmp eax,ebx
je NotLetter  ; не буква
; al = буква в нижнем регистре

(предполагается, что ebx уже сохранён).

ФедосеевПавел · 15.06.2018, 12:55

Assembler

LOCALS
 
.model small
 
.stack 100h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgPrompt       db      'Enter a string:', 0Dh, 0Ah, '$'
        msgResult       db      'Result:'
        msgChars        db      0Dh, 0Ah, ' - chars:  ', '$'
        msgDigits       db      0Dh, 0Ah, ' - digits: ', '$'
        msgPuncts       db      0Dh, 0Ah, ' - puncts: ', '$'
 
        msgCharsG       db      0Dh, 0Ah, 'The line has more letters.', '$'
        msgDigitsG      db      0Dh, 0Ah, 'The line has more digits.', '$'
        msgPunctsG      db      0Dh, 0Ah, 'The line has more puncts.', '$'
 
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
 
        Chars           label   byte
        Latin           db      'ABCDEFGHJKLMNOPQRSTUVWXYZ'
                        db      'abcdefghjklmnopqrstuvwxyz'
        Cyrillic        db      'АБВГДЕЁЖЗИЙКЛМНОПРСТУФХЦЧШЩЬЫЪЭЮЯ'
                        db      'абвгдеёжзийклмнопрстуфхцчшщьыъэюя'
        CharsAmount     dw      $-Chars
 
        Digits          db      '0123456789'
        DigitsAmount    dw      $-Digits
 
        Puncts          db      '!()-[]{};:', "'", '"', ',.?'
        PunctsAmount    dw      $-Puncts
 
        KeyBuffer       label   byte
        MaxLen          db      80
        Len             db      ?
        String          db      81 dup(?)
 
        CountChars      dw      ?
        CountDigits     dw      ?
        CountPuncts     dw      ?
 
        pStr            label   word
                        dw      offset  msgCharsG
                        dw      offset  msgDigitsG
                        dw      offset  msgPunctsG
.code
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        ;ввод строки
        mov     ah,     09h
        lea     dx,     [msgPrompt]
        int     21h
        mov     ah,     0Ah
        lea     dx,     [KeyBuffer]
        int     21h
        mov     ah,     09h
        lea     dx,     [CrLf]
        int     21h
        ;обработка строки
        xor     cx,     cx
        mov     [CountChars],   cx
        mov     [CountDigits],  cx
        mov     [CountPuncts],  cx
        mov     cl,     [Len]
        lea     si,     [String]
        cld
        @@for:
                lodsb
                call    IsChar
                adc     [CountChars],   0
                call    IsDigit
                adc     [CountDigits],  0
                call    IsPunct
                adc     [CountPuncts],  0
        loop    @@for
 
        ;вывод результата
        ; - статистика
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        mov     ax,     [CountChars]
        call    ShowUInt16
        mov     ah,     09h
        lea     dx,     [msgDigits]
        int     21h
        mov     ax,     [CountDigits]
        call    ShowUInt16
        mov     ah,     09h
        lea     dx,     [msgPuncts]
        int     21h
        mov     ax,     [CountPuncts]
        call    ShowUInt16
        ; -
        mov     si,     0
        mov     ax,     [CountChars]
        cmp     ax,     [CountDigits]
        jae     @@3
        mov     si,     1
        mov     ax,     [CountDigits]
@@3:
        cmp     ax,     [CountPuncts]
        jae     @@4
        mov     si,     2
        mov     ax,     [CountPuncts]
@@4:
        mov     ah,     09h
        lea     bx,     [pStr]
        add     bx,     si
        add     bx,     si
        mov     dx,     [bx]
        int     21h
 
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
;Определяет, принадлежит ли символ в al буквам
;на входе
; al - символ
;на выходе
; CF -  0 (не буква), CF - 1 (буква)
IsChar  proc
        push    ax
        push    cx
        push    es
 
        mov     ah,     1
        push    ds
        pop     es
        lea     di,     [Chars]
        mov     cx,     [CharsAmount]
        cld
        repne   scasb
        jnz     @@icSkip
        mov     ah,     0
@@icSkip:
        cmp     ah,     1
        pop     es
        pop     cx
        pop     ax
        ret
IsChar  endp
 
 
;Определяет, принадлежит ли символ в al цифрам
;на входе
; al - символ
;на выходе
; CF -  0 (не цифра), CF - 1 (цифра)
IsDigit proc
        push    ax
        push    cx
        push    es
 
        mov     ah,     1
        push    ds
        pop     es
        lea     di,     [Digits]
        mov     cx,     [DigitsAmount]
        cld
        repne   scasb
        jnz     @@idSkip
        mov     ah,     0
@@idSkip:
        cmp     ah,     1
        pop     es
        pop     cx
        pop     ax
        ret
IsDigit endp
 
;Определяет, принадлежит ли символ в al знакам пунктуации
;на входе
; al - символ
;на выходе
; CF -  0 (не знак пунктуации), CF - 1 (знак пунктуации)
IsPunct proc
        push    ax
        push    cx
        push    es
 
        mov     ah,     1
        push    ds
        pop     es
        lea     di,     [Puncts]
        mov     cx,     [PunctsAmount]
        cld
        repne   scasb
        jnz     @@ipSkip
        mov     ah,     0
@@ipSkip:
        cmp     ah,     1
        pop     es
        pop     cx
        pop     ax
        ret
IsPunct endp
 
ShowUInt16       proc
        push    bx
        mov     bx,     10
        xor     cx,     cx      ;символов в модуле числа
        @@div:
                xor     dx,     dx
                div     bx
                push    dx
                inc     cx      ;количество цифр в числе
                or      ax,     ax
        jnz     @@div
        mov     ah,     02h
        @@store:
                pop     dx
                add     dl,     '0'
                int     21h
        loop    @@store
        pop     bx
        ret
ShowUInt16       endp
 
end     main

@Ethereal · 16.06.2018, 20:21

Вот примерно так индусы и пишут. Глаза бы мои не видели. Особенно IsDigit через scasb.

Assembler

;Определяет, принадлежит ли символ в al цифрам
;на входе
; al - символ
;на выходе
; CF - 0 (не цифра), CF - 1 (цифра)
IsDigit proc
        cmp al, '0'
        cmc
        jnc @@0
        cmp al, '9'+1
@@0:    ret
IsDigit endp

С попутным преобразованием цифры '0'..'9' в ее значение 0..9 будет еще короче :

Assembler

;Определяет, принадлежит ли символ в al цифрам
;на входе
; al - символ
;на выходе
; CF - 0 (не цифра), CF - 1 (цифра)
; al - значение цифры 0..9, если была цифра
IsDigit proc
        add al, -'0'
        jnc @@0
        cmp al, 10
@@0:    ret
IsDigit endp

ФедосеевПавел · 16.06.2018, 20:49

Ethereal, спасибо за критику.
Но в своё оправдание скажу - варюсь в собственном соку и от других форумчан гениальных примеров не вижу - только дружеские "обнимашки" и плюсики за эти "обнимашки".

И добавлю царапающий глаз пример

Assembler

8	add al, -'0'

Что это было?

@Jin X · 16.06.2018, 20:54

Это чтобы флаг CF не выставился при al<'0', потому как sub al,'0' выдаст противоположное значение CF.

ФедосеевПавел · 16.06.2018, 21:05

А так негламурно?

Assembler

        sub al, '0'
        jc  @@0  ; оно же jb @@0
        cmp al, 10
@@0:    ret

Добавлено через 6 минут
Понял - это же функция с двумя результатами CF и число.
Спасибо, запомню.

@Jin X · 16.06.2018, 21:15

Так будет CF=1 при любом значении al<='9'.
Тогда уж так:

Assembler

        sub al, '0'
        cmc
        jnc  @@0  ; оно же jnb @@0
        cmp al, 10
@@0:    ret

Добавлено через 1 минуту
Но смысл? Когда sub+cmc можно заменить на один add...

Добавлено через 2 минуты
Только call IsDigit должен быть последним, т.к. он «портит» al.

ФедосеевПавел · 16.06.2018, 21:19

Но это не обязательно к данной программе - можно же использовать в другом месте для фильтрации ввода. И как пример применения не обязательно применительно к цифрам.

@Ethereal · 17.06.2018, 13:53

Сообщение от ФедосеевПавел

И добавлю царапающий глаз пример
add al, -'0'
Что это было?

Отрицательных чисел никогда не видел что-ли ?
-'0' это код символа 0 со знаком минус. Вот что это.

Добавлено через 5 минут

Сообщение от ФедосеевПавел

Спасибо, запомню.

Надо не запоминать. А дойти до состояния придумывания такого на ходу. Ведь практикуешься же постоянно. Пора бы. Ассемблер, он для того и ассемблер, чтобы использовать то, что он позволяет на всю катушку. А иначе будет не лучше, чем gcc -O3

Добавлено через 15 минут
Мысль такая. Надо воспринимать cmp не как часть готового заклинания CMP Jcond , а уяснить, что она делает. Представлять себе, что cmp вычитает (только результат теряет) и когда вычитает из меньшего большее, то выставляет флаг C. Потому-что был заем. Можно образно представлять себе заем. Можно представлять себе как при сложении add перенос пинком вылетает за пределы байта/слова. И когда появится такое образное представление, написание такого даже трюкачеством казаться перестанет. Нормальным, естественным писанием на ассемблере казаться будет.

@Jin X · 17.06.2018, 18:55

Ещё один вариант:

Assembler

.MODEL Tiny
LOCALS
 
$No             =       -1
$Dig            =       0
$Let            =       1
$Pun            =       2
 
.DATA
 
MsgEnter        DB      'Enter a string:',13,10,'$'
MsgDigits       DB      13,10,10,'Digits: $'
MsgLetters      DB      13,10,'Letters: $'
MsgPuncts       DB      13,10,'Punctuations: $'
MsgMax          DB      ' (maximum value)$'
MsgPressAKey    DB      13,10,10,'Press a key to quit...',13,10,'$'
 
CheckType       DB      $No,'!',$Pun,'0',$Dig,'9'+1,$Pun,'A',$Let,'Z'+1,$Pun,'a',$Let,'z'+1,$Pun,127,$No,'А',$Let,'п'+1,$No,'р',$Let,'ё'+1
lCheckType      =       ($-CheckType)/2
 
Counters        LABEL   WORD
CntDigits       DW      0
CntLetters      DW      0
CntPuncts       DW      0
CntMax          DW      0
 
Buffer          DB      79,?
String          DB      79 DUP (?)
 
.CODE
 
.STARTUP
 
                cld
 
                ; Ввод строки
                mov     ah,9
                lea     dx,MsgEnter
                int     21h
 
                mov     ah,0Ah
                lea     dx,Buffer
                int     21h
 
                ; Анализ строки
                lea     si,String
                jmp     @@start
        @@nextchar:
                lea     di,CheckType
                mov     cx,lCheckType
        @@checknext:
                mov     bx,[di]
                sub     al,bh
                jc      @@found
                add     al,bh
                add     di,2
                loop    @@checknext
                jmp     @@start
        @@found:
                shl     bl,1
                js      @@start
                xor     bh,bh
                inc     Counters[bx]
        @@start:
                lodsb
                cmp     al,' '
                jnb     @@nextchar
 
                ; Максимум
                lea     si,Counters
                mov     cx,3
        @@nextmax:
                lodsw
                cmp     ax,CntMax
                jna     @@notmax
                mov     CntMax,ax
        @@notmax:
                loop    @@nextmax
 
                ; Результаты
                mov     cx,CntDigits
                lea     dx,MsgDigits
                call    ShowResults
                mov     cx,CntLetters
                lea     dx,MsgLetters
                call    ShowResults
                mov     cx,CntPuncts
                lea     dx,MsgPuncts
                call    ShowResults
 
                ; Завершение
                mov     ah,9
                lea     dx,MsgPressAKey
                int     21h
 
                xor     ah,ah
                int     16h
 
                int     20h
 
; Вывод строки по адресу DX, числа CX и информации о максимальном значении
ShowResults     PROC
                mov     ah,9
                int     21h
                mov     ax,cx
                push    ax
                call    OutInt
                pop     ax
                cmp     ax,CntMax
                jb      @@notmax
                mov     ah,9
                lea     dx,MsgMax
                int     21h
        @@notmax:
                ret
ShowResults     ENDP
 
; Вывод целого БЕЗзнакового десятичного числа AX на экран
OutInt          proc
                xor     cx,cx           ; кол-во цифр (пока 0)
                mov     bx,10           ; система счисления (десятичная)
        nextdigit:
                xor     dx,dx           ; DX = 0 (нужно для деления)
                div     bx              ; AX = DX:AX/систему_счисления, DX = остаток
                push    dx              ; сохраняем цифру в стеке
                inc     cx              ; увеличиваем кол-во цифр
                test    ax,ax           ; проверяем AX (число)
                jnz     nextdigit       ; переход, если частное ещё не равно 0
                mov     ah,2            ; номер функции DOS вывода символа на экран
        outdigit:
                pop     dx              ; извлекаем цифру из стека
                add     dl,'0'          ; преобразуем её в символ
                int     21h             ; вывод цифры
                loop    outdigit        ; повторяем цикл вывода символов
                ret                     ; выходим из процедуры
OutInt          endp
 
END

@boikosad 0 / 0 / 0 Регистрация: 11.06.2018 Сообщений: 4
		1
	Ввести строку С, определить чего в строке больше цифр, букв или знаков пунктуации 11.06.2018, 11:24. Показов 1933. Ответов 13 Метки нет (Все метки) Сделать программу на ассемблере. Задание: Ввести строку С,определить чего в строке больше цифр,букв или знаков пунктуации. 0

@~~masha777~~ Заблокирован
	11.06.2018, 21:37	2
	Ребят, нужно написать программу на ассемблере.Задание Ввести строку С,определить чего в строке больше цифр,букв или знаков пунктуации.Заранее спасибо. 0

@R71MT Эксперт Hardware 6103 / 2347 / 390 Регистрация: 29.07.2014 Сообщений: 3,108 Записей в блоге: 4
	14.06.2018, 11:26	4
	Сообщение от masha777 определить чего в строке больше цифр,букв или знаков пунктуации ..а чем они отличаются знаешь? можешь скачать справочник ASCII-символов и посмотреть, тогда и помощь не потребуется. 1

@Jin X Asm/C++/Delphi/Py/PHP/VBA 6528 / 1973 / 228 Регистрация: 14.12.2014 Сообщений: 4,125 Записей в блоге: 12
	16.06.2018, 20:54	9
	Это чтобы флаг CF не выставился при al<'0', потому как sub al,'0' выдаст противоположное значение CF. 1

ФедосеевПавел Модератор 8476 / 4335 / 1642 Регистрация: 01.02.2015 Сообщений: 13,461 Записей в блоге: 8
	16.06.2018, 21:19	12
	Но это не обязательно к данной программе - можно же использовать в другом месте для фильтрации ввода. И как пример применения не обязательно применительно к цифрам. 0

@Ethereal 6770 / 2739 / 384 Регистрация: 17.02.2013 Сообщений: 4,047
	17.06.2018, 13:53	13
	Сообщение от ФедосеевПавел И добавлю царапающий глаз пример add al, -'0' Что это было? Отрицательных чисел никогда не видел что-ли ? -'0' это код символа 0 со знаком минус. Вот что это. Добавлено через 5 минут Сообщение от ФедосеевПавел Спасибо, запомню. Надо не запоминать. А дойти до состояния придумывания такого на ходу. Ведь практикуешься же постоянно. Пора бы. Ассемблер, он для того и ассемблер, чтобы использовать то, что он позволяет на всю катушку. А иначе будет не лучше, чем gcc -O3 Добавлено через 15 минут Мысль такая. Надо воспринимать cmp не как часть готового заклинания CMP Jcond , а уяснить, что она делает. Представлять себе, что cmp вычитает (только результат теряет) и когда вычитает из меньшего большее, то выставляет флаг C. Потому-что был заем. Можно образно представлять себе заем. Можно представлять себе как при сложении add перенос пинком вылетает за пределы байта/слова. И когда появится такое образное представление, написание такого даже трюкачеством казаться перестанет. Нормальным, естественным писанием на ассемблере казаться будет. 1

Ввести строку С, определить чего в строке больше цифр, букв или знаков пунктуации

Решение