Пересчитать в массиве количество элементов, кратных 5

.Data 
Mas db 10 dup (0)

.model small
 
.stack 100h
 
.data
        CrLf            db      0Dh, 0Ah, '$'
        msgResult       db      'Result: ', '$'
        msgPressAnyKey  db      0Dh, 0Ah, 'Press any key to exit...', '$'
        Mas             db      10 dup (0)
        Count           dw      ?
.code
 
main    proc
        ;инициализация сегментного регистра ds адресом сегмента данных
        mov     ax,     @data
        mov     ds,     ax
 
        lea     si,     [Mas]
        mov     cx,     10
        mov     bl,     5
        xor     dx,     dx
        @@for:
                lodsb
                cbw
                idiv    bl
                cmp     ah,     1
                adc     dx,     0
        loop    @@for
 
        mov     [Count],        dx
        ;вывод результата
        mov     ah,     09h
        lea     dx,     [msgResult]
        int     21h
        mov     ax,     [Count]
        call    ShowInt16
        ;ожидание нажатия любой клавиши
        mov     ah,     09h
        lea     dx,     [msgPressAnyKey]
        int     21h
 
        mov     ah,     00h
        int     16h
 
        mov     ax,     4C00h
        int     21h
main    endp
 
ShowInt16       proc
        push    bx
        mov     bx,     10
        xor     cx,     cx      ;символов в модуле числа
        or      ax,     ax
        jns     @@div
                neg     ax
                push    ax
                mov     ah,     02h
                mov     dl,     '-'
                int     21h
                pop     ax
        @@div:
                xor     dx,     dx
                div     bx
                push    dx
                inc     cx      ;количество цифр в числе
                or      ax,     ax
        jnz     @@div
        mov     ah,     02h
        @@store:
                pop     dx
                add     dl,     '0'
                int     21h
        loop    @@store
        pop     bx
        ret
ShowInt16       endp
 
end     main