А что находится внутри функции MessageBox или как еще можно создать MessageBox?

@Mikl___ · Регистрация: 11.11.2010

Author24 — интернет-сервис помощи студентам

Помните сказку о лягушке-царевне? Что необходимо было сделать, чтобы убить Кащея-бессмертного? ― нужно было сперва с кучей приключений попасть на некий остров, на острове найти дуб, с дуба снять ларец,

«в ларце ― заяц, в зайце ― утка, в утке ― яйцо, в яйце ― игла, а на кончике иглы ― смерть Кащеева...»

Казалось бы, что может быть проще функции MessageBox? Но кто-нибудь задавал себе вопрос ― «а что находится внутри MessageBox?» Может быть это поможет сделать наши программы еще меньше.

Запускаем программу выводящую MessageBox на экран в дебаггере Ollydbg и в тот момент, когда курсор доходит до строки call MessageBoxA нажимаем не на F8 (Step over), а на клавишу F7 (Step into) и оказываемся внутри функции MessageBoxA ― оказывается здесь происходит перекодировка ASCII-строк заголовка и текста сообщений в UNICODE и вызов функции MessageBoxW, снова жмем на F7 ― оказывается внутри MessageBoxW функция MessageBoxExA, которая имеет на один параметр больше, чем MessageBoxA и MessageBoxW и этот параметр (dwLanguageId) равен 0 (LANG_NEUTRAL), остальные же параметры совпадают полностью. Внутри MessageBoxExA находится функция MessageBoxExW. Внутри MessageBoxExW ― функция MessageBoxTimeoutA, у которой на один параметр больше, чем у MessageBoxExW и этот параметр (Timeout) равен -1. Внутри MessageBoxTimeoutA, как можно было догадаться MessageBoxTimeoutW. Внутри MessageBoxTimeoutW - MessageBoxIndirectA эта функция позволяет поменять иконку у MessageBox и может вызвать Справку, но мы оставляем эти параметры с нулевым значением. Внутри MessageBoxIndirectA находится точно такая же но с UNICODE строками функция MessageBoxIndirectW SoftModalMessageBox. У Indy/Clerk я нашел ссылку на NtRaiseHardError ― вызов MessageBox на уровне ядра.

Традиционный способ определения Unicode-строки:

Код

usz dw 'U', 'n', 'i', 'c', 'o', 'd', 'e', ' ', 's', 't', 'r', 'i', 'n', 'g', 0

Меня этот способ не устраивал, поэтому, я написал для этой цели макрос du (define unicode string), чтобы без проблем переводить ASCII-строки в UNICODE-строки

Код

du	macro string
local bslash
bslash = 0
irpc c,<string>
if bslash eq 0
	if '&c' eq "\";;управляющая последовательность символов
	bslash = 1
	elseif '&c' eq "ё"
	db 51h,4
	elseif '&c' eq "Ё"
	db 1,4
	elseif '&c' gt 127
	db ('&c'- 0B0h),4;;кириллица
	else
	dw '&c'          ;;латиница
	endif
else
bslash = 0
	if '&c' eq "n"    ;;  \n = новая строка
        DW 0Dh,0Ah
        elseif '&c' eq "\";;  \\ = обратная косая черта (\)
        dw '\'
        elseif '&c' eq "r";;  \r = возврат каретки
        dw 0Dh
        elseif '&c' eq "l";;  \l = LF
        dw 0Ah
        elseif '&c' eq "s"
        dw 20h
        elseif '&c' eq "c"
        dw 3Bh
        elseif '&c' eq "t";;  \t = табуляция 
        dw 9
	endif
endif
endm
dw 0
endm

этот макрос превращает ASCII-символы латиницы в UNICODE-символы добавлением после кода символа нуля, а для кириллицы заменяет 0 на 4 и сдвигает код символа на 176, в конце UNICODE-строки ставится ноль, терминирующий строку. Всё, что требуется от пользователя ― после du написать строку в угловых скобках. То есть представить Unicode-строку так:

Код

usz: du <Unicode string>

обратите внимание, что после названия строки стоит двоеточие.

Assembler

; masm windows gui #
.686P
.model flat
;include windows.inc
include native.inc
include ntstatus.inc
includelib user32.lib
includelib ntdll.lib
extern _imp__MessageBoxA@16:dword
extern _imp__MessageBoxW@16:dword
extern _imp__MessageBoxExA@20:dword
extern _imp__MessageBoxExW@20:dword
extern _imp__MessageBoxTimeoutA@24:dword
extern _imp__MessageBoxTimeoutW@24:dword
extern _imp__SoftModalMessageBox@4:dword
extern _imp__MessageBoxIndirectA@4:dword
extern _imp__MessageBoxIndirectW@4:dword
extern _imp__NtRaiseHardError@24:dword
;extern _imp__KiFastSystemCall@0:dword
MB_ICONASTERISK     equ 40h 
MB_OK           equ 0
; structures
MSGBOXPARAMSA STRUCT
  cbSize                DWORD      ?
  hwndOwner             DWORD      ?
  hInstance             DWORD      ?
  lpszText              DWORD      ?
  lpszCaption           DWORD      ?
  dwStyle               DWORD      ?
  lpszIcon              DWORD      ?
  dwContextHelpId       DWORD      ?
  lpfnMsgBoxCallback    DWORD      ?
  dwLanguageId          DWORD      ?
MSGBOXPARAMSA ENDS
 
MSGBOXDATA struct       
     params              MSGBOXPARAMSA <>
     pwndOwner           DWORD ?
     wLanguageId         DWORD ?
     pidButton           DWORD ?         ; // Array of button IDs
     ppszButtonText      DWORD ?         ; // Array of button text strings
     cButtons            DWORD ?
     DefButton           DWORD ?
     CancelId            DWORD ?
     Timeout             DWORD ?
MSGBOXDATA ends
; macros
du  macro string
    irpc c,<string>
    db '&c',0
    endm
    dw 0
    endm
.code
start:  xor ebx,ebx
    mov esi,ebx
    push MB_ICONASTERISK or MB_OK
    push offset MsgCaption
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxA@16
;---------------------------------------
    inc esi
    push MB_ICONASTERISK or MB_OK
    push offset TitleText
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxW@16
;----------------------------------------
    inc esi
    push ebx
    push MB_ICONASTERISK or MB_OK
    push offset MsgCaption
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxExA@20
;-----------------------------------------
    inc esi
    push ebx
    push MB_ICONASTERISK or MB_OK
    push offset TitleText
    push [Msg+esi*4]
    push ebx
    call _imp__MessageBoxExW@20
;-----------------------------------------
    inc esi
        push -1
        push ebx
        push MB_ICONASTERISK or MB_OK
        push offset MsgCaption
        push [Msg+esi*4]
        push ebx
        call _imp__MessageBoxTimeoutA@24
;------------------------------------------
    inc esi
        push -1
        push ebx
        push MB_ICONASTERISK or MB_OK
        push offset TitleText
        push [Msg+esi*4]
        push ebx
        call _imp__MessageBoxTimeoutW@24
;------------------------------------------
        sub esp,sizeof(MSGBOXPARAMSA);40
    mov edi,esp
    assume edi:ptr MSGBOXPARAMSA
    mov dword ptr [edi].cbSize,sizeof(MSGBOXPARAMSA)
    mov dword ptr [edi].hwndOwner,ebx
    mov dword ptr [edi].hInstance,400000h
    mov dword ptr [edi].lpszText,offset Msg8
    mov dword ptr [edi].lpszCaption,offset MsgCaption
    mov dword ptr [edi].dwStyle,MB_ICONASTERISK or MB_OK;:= MB_USERICON;
    mov dword ptr [edi].lpszIcon,ebx;:= PCHAR('MYICO');
    mov dword ptr [edi].dwContextHelpId,ebx;:= 0;
    mov dword ptr [edi].lpfnMsgBoxCallback,ebx;:= nil;
    mov dword ptr [edi].dwLanguageId,ebx;:= LANG_NEUTRAL;   
    push edi
        call _imp__MessageBoxIndirectA@4
;--------------------------------------------------------
    mov dword ptr [edi].cbSize,sizeof(MSGBOXPARAMSA)
    mov dword ptr [edi].hwndOwner,ebx
    mov dword ptr [edi].hInstance,400000h
    mov dword ptr [edi].lpszText,offset Msg9
    mov dword ptr [edi].lpszCaption,offset TitleText
    mov dword ptr [edi].dwStyle,MB_ICONASTERISK or MB_OK
    mov dword ptr [edi].lpszIcon,ebx;:= PCHAR('MYICO');
    mov dword ptr [edi].dwContextHelpId,ebx;:= 0;
    mov dword ptr [edi].lpfnMsgBoxCallback,ebx;:= nil;
    mov dword ptr [edi].dwLanguageId,ebx;:= LANG_NEUTRAL;   
    push edi
        call _imp__MessageBoxIndirectW@4
    add esp,sizeof(MSGBOXPARAMSA)
;-------------------------------------------------------------------------
        sub esp,sizeof MSGBOXDATA+8
;  local mbd:MSGBOXDATA
;  local bufid[1]:DWORD
;  local bufstr[1]:DWORD
    lea eax,[esp+4];bufid
    mov dword ptr[eax],1
    mov [esp],offset _OK
        lea edi,[esp+8]
    mov [edi].cbSize,sizeof MSGBOXPARAMSA
    mov [edi].hwndOwner,ebx
    mov [edi].lpszText,offset Msg7
    mov [edi].lpszCaption,offset TitleText
    mov [edi].dwStyle,MB_ICONASTERISK or MB_OK
        assume edi:ptr MSGBOXDATA
    mov [edi].pwndOwner,ebx;0
    mov [edi].wLanguageId,ebx;0
    mov [edi].pidButton,eax
    mov [edi].ppszButtonText,esp;offset bufstr
    mov [edi].cButtons,1
    mov [edi].DefButton,ebx;0
    mov [edi].CancelId,1
    mov [edi].Timeout,-1
    push edi
    call _imp__SoftModalMessageBox@4
    assume edi:nothing
    add esp,sizeof MSGBOXDATA+8
;------------------------------------------------------------------
ShowMessage proc
Local MessageBuffer[38h]:WCHAR;в Num+Num1 в вордах
Local Message[2]:UNICODE_STRING
Local HardErrorPointer[3]:PVOID
;первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText
    mov ecx,Num+Num1
    rep movsb
;второй параметр
    lea edi,MessageBuffer+Num
    mov Message.Buffer+sizeof(UNICODE_STRING)*1,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*1,Num1
    mov Message._Length+sizeof(UNICODE_STRING)*1,Num1-2
    lea edx,Message+sizeof(UNICODE_STRING)*1
    mov HardErrorPointer+sizeof(PVOID)*1,edx;pwCaption
;третий параметр
        mov HardErrorPointer+sizeof(PVOID)*2,MB_ICONASTERISK+MB_OK;uType
        lea edx,HardErrorPointer
    push offset x;куда функция запишет выбранный юзером ответ (если тип, 
;переданный в следующем параметре, предполагает выбор ответа пользователем)
    push ebx;0 варианты ответов
    push edx;указатель на массив параметров
    push 3;общее число параметров
    push 00000011b;маска, еденичные биты которой соответствуют тем 
;параметрам, которые имеют тип PUNICODE_STRING, а нули -- остальным параметрам
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    call _imp__NtRaiseHardError@24
;--------------------------------------------------
;меняем первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num3
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num3-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText2
    mov ecx,Num3
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    push offset @f
    mov edx,7FFE0300h
    call dword ptr ds:[edx]
@@:
;--------------------------------------------------
;меняем первый параметр
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num4
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num4-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText3
    mov ecx,Num4
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    push offset @f
    push offset @f
    mov edx,esp
    db 0Fh,34h;sysenter
@@:
;--------------------------------------------------------
    lea edi,MessageBuffer
    mov Message.Buffer+sizeof(UNICODE_STRING)*0,edi
    mov Message.MaximumLength+sizeof(UNICODE_STRING)*0,Num2
    mov Message._Length+sizeof(UNICODE_STRING)*0,Num2-2
    lea edx,Message+sizeof(UNICODE_STRING)*0
    mov HardErrorPointer+sizeof(PVOID)*0,edx;pwText
    mov esi,offset MessageText1
    mov ecx,Num2
    rep movsb
        lea edx,HardErrorPointer
    mov eax,0B6h;ID NtRaiseHardError для WinXP
    push offset x
    push ebx
    push edx
    push 3
    push 00000011b
    push STATUS_SERVICE_NOTIFICATION;статус ошибки
    mov edx,esp
    int 2Eh
    add esp,18h
    leave
    retn
ShowMessage endp
 
MessageText: du <NtRaiseHardError>
Num = $-MessageText
TitleText: du <Iczelion Tutorial #2:MessageBox>
Num1 = $-TitleText
MessageText1: du <int 2Eh>
Num2 equ $-MessageText1
MessageText2: du <KiFastSystemCall>
Num3 equ $-MessageText2
MessageText3: du <sysenter>
Num4 equ $-MessageText3
x dd 0
Msg dd Msg1,Msg2,Msg3,Msg4,Msg5,Msg6,Msg7,Msg8,Msg9
Msg1    db 'MessageBoxA',0
Msg2:   du <MessageBoxW>
Msg3    db 'MessageBoxExA',0
Msg4:   du <MessageBoxExW>
Msg5    db 'MessageBoxTimeoutA',0
Msg6:   du <MessageBoxTimeoutW>
Msg7:   du <SoftModalMessageBox>
Msg8    db 'MessageBoxIndirectA',0
Msg9:   du <MessageBoxIndirectW>
MsgCaption db "Iczelion Tutorial #2:MessageBox",0
_OK:    du <OK>
end start

Charles Kludge · 11.08.2014, 18:52

Не по теме:

murderer, можно ещё глянуть в Wine source.

Сообщение от murderer

Да хотелось бы прочитать оригинальный мануал

Возьми сырцы виндавса 1.0 - вряд ли там что-то изменилось с годами.:jokingly:

Charles Kludge
	11.08.2014, 18:52 А что находится внутри функции MessageBox или как еще можно создать MessageBox? #21
	Не по теме: murderer, можно ещё глянуть в Wine source. Сообщение от murderer Да хотелось бы прочитать оригинальный мануал Возьми сырцы виндавса 1.0 - вряд ли там что-то изменилось с годами.:jokingly: 0