Форум программистов, компьютерный форум, киберфорум
Наши страницы
Assembler: DOS/Real Mode/16-bits
Войти
Регистрация
Восстановить пароль
 
Рейтинг 4.67/3: Рейтинг темы: голосов - 3, средняя оценка - 4.67
sam5213
0 / 0 / 0
Регистрация: 13.07.2010
Сообщений: 46
1

Не запускается приложение

18.12.2012, 20:38. Просмотров 512. Ответов 4
Метки нет (Все метки)

вот я хочу запустить игру, но мне не удается, кто может помочь с подробной инструкцией запуска игры http://www.pouet.net/prod.php?which=29286&howmanycomments=50 скачиваю, есть asm файл, и еще др. необходимо сделать, пробывал создать батник и через досбокс запускать, ничего не получается..(tasm)
0
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
18.12.2012, 20:38
Ответы с готовыми решениями:

Приложение запускается из play, но не запускается с рабочего стола
Добрый день всем! В чем может быть проблема, если приложение отлично запускается с google play, но...

Не запускается приложение, ни из Debug ни из Release, но запускается из VS
Пишу программу, и местами её дополняю. Где то пару дней назад запускал её, прямо из .exe, без VS...

Не запускается приложение
Здравствуйте, запускаю свое первое приложение и не получается. 1. Создал эмулятор 2. Хочу...

Не запускается приложение
Привет! Пишу калькулятор. Но не смотря на то что ошибок в коде нет, приложение не запускаются......

Приложение не запускается
При запуске приложения появляется сообщение "приложение gameunp.exe связано с отсутствующим...

4
Troll_Face
603 / 403 / 8
Регистрация: 26.04.2012
Сообщений: 2,069
18.12.2012, 21:10 2
и какой батник вы делали?
0
Charles Kludge
Клюг
7648 / 3163 / 383
Регистрация: 03.05.2011
Сообщений: 8,381
18.12.2012, 21:33 3
Это FASM, скомпилилось и работает. Под тасм переделал, но запускаться не хочет, что не удивительно.
0
Troll_Face
603 / 403 / 8
Регистрация: 26.04.2012
Сообщений: 2,069
18.12.2012, 21:34 4
Цитата Сообщение от Charles Kludge Посмотреть сообщение
что не удивительно.
почему?
0
Charles Kludge
Клюг
7648 / 3163 / 383
Регистрация: 03.05.2011
Сообщений: 8,381
18.12.2012, 23:06 5
Цитата Сообщение от Fatal Error
почему?
Дык, сам попробуй[FASM]:
Assembler
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
; *         **  %%% ### 4is256
; * %  @@@@  ** %   #   a 256-byte brick game
; **%%      #    ==  @@ by Rrrola
;   %  ==== ### ==   @@ <rrrola@gmail.com>
 
; STORY
;  confused bricks fall down the pit of sorrow
;  show them the rightful way of flawless rows
;  make them complete
;  make them disappear in joy
;  and get awarded for their redemption
 
; CONTROLS AND SHIFTS
;  left shift ......... move left
;  right shift ....... move right
;  ctrl .............. rotate ccw
;  alt .............. fall faster
 
; SCORING
;  fast falling ........... 1/row
;  deleted rows ... 32/96/160/224
;  don't delete too fast ... -256 (punishment for the greedy ;-))
 
; LEVEL (FALLING SPEED)
;  increases every (1<<level) deletions
 
; note: needs vertical retrace for timing (fullscreen or pure DOS)
; greets to everyone who JUST WOULDN'T GET THE STRAIGHT ONE OMGWTF
 
 
HEIGHT  equ 24          ; must be a multiple of 4
_WIDTH  equ 10          ; 4..23
PIT_CHAR    equ 'є'
BRICK_CHAR  equ 'Ы'
 
    org 100h            ; assume ax=0 bl=0 sp=0FFFEh
 
    inc ax
    int 10h
    mov ah,5            ; textmode 40x25, page 1 (offset 800h)
    int 10h         ; filled with gray spaces on black (0720h)
    push    word 0B800h
    pop es
    push    es
    pop ds
 
 
; Draw the pit and erase complete rows
 
P:
    mov di,2178+(HEIGHT-1)*80
    mov si,di           ;-) si = source row, di = destination row
    mov cx,HEIGHT+4
E:
    sub di, 80
N:
    add bl,64           ; score += {0,64,128,192}[erased rows mod 4]
    sub si, 80+_WIDTH*2
 
    mov ax,800h+PIT_CHAR
    stosw
    sub di, _WIDTH*2+4
    stosw
 
    mov dx,_WIDTH
A:
    or  [di+(HEIGHT+4)*80+1],ah
    and al,[si+1]
    movsw               ; white score at the bottom of the pit, shift rows
    dec dx
    jnz A
 
    and al,8            ; brightness all the way?
    jnz N
    loop    E
 
    cmp si,di           ; if any rows were deleted, adjust score to +32/96/160/224
    je  G
    sub bl,32
    dec sp          ; sp = 0FFFEh-total deletions
 
 
; Generate a new brick
 
G:         ; di=6F2h cx=0
    in  al,40h          ; could be "rdtsc" for hardcore randomness
    mov ah,5Ah
    mul di          ; dx:ax=2711400h..277FF0Eh
    mov bp,dx
    mov cl,[bp-271h+S]
    mov di,800h-160+48-(_WIDTH or 1)
    mov si,es           ;-) the highest bits of si need to be "10"
 
; bp = brick index + 271h
; cx = rotated brick layout (4 bits per row)
; di = brick position
; most significant zero bit in sp = number of frames before dropping
; (si is used for checking that)
 
 
; Increase the displayed score by 1
 
M:
    or  bl,bl
    jz  V
    push    di          ; di = behind the last zero
    mov di,800h+HEIGHT*80+50
    dec bx
D:
    dec di          ; next digit
    dec di
    mov al,'0'          ; assume overflow
    xchg    al,[di]
    or  al,10h
    cmp al,'9'
    je  D
    inc ax
    stosb               ; if the digit wasn't '9', raise it
    pop di
 
 
; Wait for vertical retrace start (70/sec) and erase the brick
 
V:
    mov dx,3DAh
    in  al,dx
    and al,8
    jz  V
W:
in   al,dx
    and al,8
    jnz W           ; al=0
    call    B           ; if not erasable (= has no space to appear), GAME OVER
    jnc near 0
 
 
; Keyboard handler
 
    mov ah,2
    int 16h
    and bh,al           ; bh = previous shift state
    xchg    al,bh
    not bh          ; if a shift was just pressed, set a bit in al
 
    pusha
 
    shr al,1            ; RSHIFT: X++
    jnc X
    scasw               ; di+=2
X:
 
    shr al,1            ; LSHIFT: X--
    jnc Y
    dec di
    dec di
Y:
 
    shl ax,15
 
    jnc F           ; ALT: Y++, score++
    inc bx
    mov bh,8            ; can be held until landing
H:
    mov si,sp
    add si, 16
    add di, 80
F:
 
    jns C           ; CTRL: rotation
R:         ; ax=8000h, CF=0
    rcl cx,13           ; ax = cx rotated 90 degress ccw around [1;1]
    rcr ax,1
    jnc R
    cmp ah,[bp-271h+S]
    je  I           ; if we reach the original shape, reload (for O,S,Z)
    ror ax,12
I:
    xchg    ah,al
    xchg    ax,cx
C:         ; al=0
 
 
; Test whether changes were OK, drop if it's time
 
    call    B
    jnc Q
    add sp, 16
    pusha
Q:
    popa                ; use [bp-7*16] for black background instead of gray
    lea ax,[bp+0]
    rol si,1            ; OF = (CF!=sign(si))
    jnc L           ; you can't land with alt only (less mistakes)
 
    push    word M
    jno B           ; doesn't have to fall: draw the brick
 
    pop ax          ; has to fall: clean the stack
    xor ax,ax
    pusha
    jmp short H
 
L:
    or  al,8            ; draw the fallen brick bright and generate next brick
    push    word P
 
 
; Brick drawing (al=color cx=shape di=address)
 
B:
    push    bx
    xor bx,bx
T:
    ror cx,1
    jnc skip            ; brightness prevents drawing
    test    byte[bx+di],8       ; CF=0
    jnz O
    mov [bx+di],al
    mov byte[bx+di-1],BRICK_CHAR
skip:
    inc bx
    inc bx          ; bl:00 02 04 06  08
    test    bl,8            ;    50 52 54 56  58
    jz  T           ;    A0 A2 A4 A6  A8
    add bl,72           ;    F0 F2 F4 F6  F8 40+CF
    jnc T
O:
    pop bx          ; if the brick could be drawn, CF=1
    ret
 
    ; .... ##.. ..#. #... .##. .#.. ##..
    ; #### .##. ###. ###. ##.. ###. ##..
S: db 0F0h, 63h, 74h, 71h, 36h, 72h, 33h
0
18.12.2012, 23:06
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
18.12.2012, 23:06

Не запускается приложение
у меня есть готовая программа в Visual Studio, пытаюсь открыть .exe файл и сразу идет вылет...

Не запускается приложение
Здравствуйте, вот такой вопрос, создал в Eclipse новый проект (с нуля, а не как раньше на готовую...

Не запускается приложение
Добры день! При запуске приложения (игры) warface выходит следующая надпись: &quot;Это приложение не...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
5
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2019, vBulletin Solutions, Inc.
Рейтинг@Mail.ru