Screensaver

.model tiny
.code
.startup
 
    mov ax,3
    int 10h
 
    mov dh,15   ; dh = y coord
    mov dl,5    ; dl = x coord
    mov si,1    ; si = direction flag for y
    mov di,si   ; di = direction flag for x
 
    ; main loop
draw_m:
    push dx     ; save current coords
 
    mov ax,1300h
    xor bh,bh   ; zero vid page
    mov bl,0ah  ; color
    mov cx,textsize ; string size
    mov bp,offset text
    int 10h     ; draw string at dh:dl
 
    ; do small delay
delay:
    xor ah,ah
    int 1Ah
    add dx,4    ; 4 * 18.2
    mov bx,dx
d_loop:     
    int 28h     ; NTVDM idle
    int 1Ah
    cmp dx,bx
    jne d_loop  
 
    pop dx          ; restore coords
 
    mov ah,1    ; get keyboard state
    int 16h
    jz clear_str    ; if no key do clear current string
    xor ah,ah   ; get key from buf
    int 16h
    cmp al,27   ; if ESC presed
    je done_prog
 
clear_str:
    push dx     ; save coords
    mov ax,1300h
    xor bh,bh
    mov bl,0ah
    mov cx,textsize
    mov bp,offset clear
    int 10h     ; draw clear string at current XY
    pop dx
 
    test si,si      ; if si = 0
    jz dec_y    ; then  dec y
    inc dh      ; inc y
    cmp dh,24   ; if y > 24
    jb test_x   
    xor si,si   ; si direction flag = 0
    jmp test_x
dec_y:
    dec dh      ; dec y
    cmp dh,0    ; if y > 0
    ja test_x   
    mov si,1    ; si direction flag = 1
test_x:
    test di,di  ; if di = 0
    jz dec_x    ; then dec x
    inc dl      ; inc x
    cmp dl,80-textsize ; if x > 80-text length
    jb test_done    
    xor di,di   ; di direction flag = 0
    jmp test_done
dec_x:
    dec dl      ; dec x
    cmp dl,0    ; if x > 0
    ja test_done
    mov di,1    ; di derection flag = 1
test_done:
    jmp draw_m  ; go to main loop
 
done_prog:
    int 20h     ; terminate
 
text    db 'Hello world (c) Tronix'
textend EQU $
textsize EQU textend-text
clear   db textsize DUP(32)
end

stk segment stack
db 2 dup(?)
stk ends
 
data segment 
text    db 'Hello world (c) Tronix'
textend EQU $
textsize EQU textend-text
clear   db textsize DUP(32)
data ends
 
code segment
assume cs:code, ds:data, ss:stk
 
start:
    push data
    pop es
 
    mov ax,3
    int 10h
 
    mov dh,15   ; dh = y coord
    mov dl,5    ; dl = x coord
    mov si,1    ; si = direction flag for y
    mov di,si   ; di = direction flag for x
 
    ; main loop
draw_m:
    push dx     ; save current coords
 
    mov ax,1300h
    xor bh,bh   ; zero vid page
    mov bl,0ah  ; color
    mov cx,textsize ; string size
    mov bp,offset text
    int 10h     ; draw string at dh:dl
 
    ; do small delay
delay:
    xor ah,ah
    int 1Ah     ; get timer ticks
    add dx,4    ; 4 * 18.2
    mov bx,dx
d_loop:     
    int 28h     ; NTVDM idle
    int 1Ah     
    cmp dx,bx       ; compare current ticks with BX
    jne d_loop  
 
    pop dx          ; restore coords
 
    mov ah,1    ; get keyboard state
    int 16h
    jz clear_str    ; if no key do clear current string
    xor ah,ah   ; get key from buf
    int 16h
    cmp al,27   ; if ESC presed
    je done_prog
 
clear_str:
    push dx     ; save coords
    mov ax,1300h
    xor bh,bh
    mov bl,0ah
    mov cx,textsize
    mov bp,offset clear
    int 10h     ; draw clear string at current XY
    pop dx
 
    test si,si      ; if si = 0
    jz dec_y    ; then  dec y
    inc dh      ; inc y
    cmp dh,24   ; if y > 24
    jb test_x   
    xor si,si   ; si direction flag = 0
    jmp test_x
dec_y:
    dec dh      ; dec y
    cmp dh,0    ; if y > 0
    ja test_x   
    mov si,1    ; si direction flag = 1
test_x:
    test di,di  ; if di = 0
    jz dec_x    ; then dec x
    inc dl      ; inc x
    cmp dl,80-textsize ; if x > 80-text length
    jb test_done    
    xor di,di   ; di direction flag = 0
    jmp test_done
dec_x:
    dec dl      ; dec x
    cmp dl,0    ; if x > 0
    ja test_done
    mov di,1    ; di derection flag = 1
test_done:
    jmp draw_m  ; go to main loop
 
done_prog:
        mov ah,4ch  ; terminate
        int 21h
 
code ends
end start