Сравнить два текстовых файла

;file1 - старый файл
;file2 - новый файл (содержит все строки старого файла)
;size2 - размер нового файла
;file3 - файл куда записывается разница
proc compare uses esi edi ebx,file1,file2,size2,file3
     mov ecx,[size2]
     mov esi,[file1]
     mov edi,[file2]
     cld
     mov eax,0Ah ;ASCII CR
search_not_equal:
     mov edx,ecx ;сохраняем кол-во байт до конца файла
     repne scasb ;ищем CR
     jne exit ;конец, если не нашли
 
     sub edx,ecx ;находим разницу между текущая кол-во байт до конца файла и началом строки
     xchg edx,ecx ;в edx сохраняется текущее кол-во байт до конца, в ecx длина строки
     mov ebx,ecx ;длина строки еще понадобится
 
     sub edi,ecx ;отматываем на начало строки нового файла
     repe cmpsb ;сравниваем одну строку старого и нового файлов
     xchg ecx,edx ;возвращаем в ecx длину строки
     je search_not_equal ;прыгаем, если строки совпали
 
     ;если строки не совпали
     sub edx,ebx 
     neg edx ;в edx получился размер от начала строки
     sub esi,edx ;возвращаемся на начало строки старого
     sub edi,edx ;и нового файлов
     xchg ebx,ecx ;сохраняем кол-во байт до конца строки в ebx, а в ecx отправляем длину строки
     mov edx,esi ;сохраняем esi
     mov esi,edi ;отправляем в esi адрес строки нового файла
     mov edi,[file3] ;а в edi адрес 3его файла
     rep movsb ;копируем строку
     mov [file3],edi ;сохраняем текущий адрес, чтобы позже писать в продолжении
     mov edi,esi ;возвращаем на свои места edi
     mov esi,edx ;esi
     mov ecx,ebx ;ecx
     jmp search_not_equal
exit:
     ret
endp

format PE GUI 4.0
 
include 'win32a.inc'
 
section '.text' code readable executable
entry start
start:
     invoke  CreateFile,old_file.name,GENERIC_READ,FILE_SHARE_READ,NULL,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,NULL
     mov     esi,eax
     invoke  GetFileSize,eax,NULL
     mov     edi,eax
     invoke  GetProcessHeap
     mov     [hHeap],eax
     mov     ebx,eax
     invoke  HeapAlloc,eax,NULL,edi
     mov     [old_file.address],eax
     invoke  ReadFile,esi,eax,edi,temp,NULL
     invoke  CloseHandle,esi
 
     invoke  CreateFile,new_file.name,GENERIC_READ,FILE_SHARE_READ,NULL,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,NULL
     mov     esi,eax
     invoke  GetFileSize,eax,NULL
     mov     edi,eax
     invoke  HeapAlloc,ebx,NULL,edi
     mov     [new_file.address],eax
     mov     ebx,eax
     invoke  ReadFile,esi,eax,edi,temp,NULL
     invoke  CloseHandle,esi
 
     invoke  HeapAlloc,[hHeap],NULL,edi
     mov     [result_file.address],eax
 
     stdcall compare,[old_file.address],ebx,edi,eax
 
     mov     ebx,[result_file.address]
     sub     eax,ebx
     mov     edi,eax
 
     invoke  CreateFile,result_file.name,GENERIC_WRITE,NULL,NULL,CREATE_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
     mov     esi,eax
     invoke  WriteFile,eax,ebx,edi,temp,NULL
     invoke  CloseHandle,esi
     mov     edi,[hHeap]
     xor     esi,esi
     invoke  HeapFree,edi,esi,[old_file.address]
     invoke  HeapFree,edi,esi,[new_file.address]
     invoke  HeapFree,edi,esi,ebx
 
     invoke  ExitProcess,0
 
proc compare uses esi edi ebx,file1,file2,size2,file3
     mov ecx,[size2]
     mov esi,[file1]
     mov edi,[file2]
     cld
     mov eax,0Ah
search_not_equal:
     mov edx,ecx
     repne scasb        ;search Carriage Return byte
     jne exit
 
     sub edx,ecx
     xchg edx,ecx       ;edx saves previous ecx, ecx = length of string
     mov ebx,ecx
 
     sub edi,ecx
     repe cmpsb
     xchg ecx,edx
     je search_not_equal
 
     ;if strings not equal
     sub edx,ebx
     neg edx
     sub esi,edx
     sub edi,edx
     xchg ebx,ecx
     mov edx,esi
     mov esi,edi
     mov edi,[file3]
     rep movsb
     mov [file3],edi
     mov edi,esi
     mov esi,edx
     mov ecx,ebx
     jmp search_not_equal
exit:
     mov eax,[file3]
     ret
endp
 
section '.data' data readable writeable
struc FILE name
{
   .name db name,0
   .address dd ?
}
 
hHeap dd ?
temp dd ?
old_file FILE 'old_file.txt'
new_file FILE 'new_file.txt'
result_file FILE 'result_file.txt'
 
section '.idata' import data readable writeable
library kernel32,'KERNEL32.DLL',\
        user32,'USER32.DLL'
 
include 'api\kernel32.inc'
include 'api\user32.inc'

format PE CONSOLE
 
include 'win32a.inc'
 
section '.text' code readable executable
entry start
start:
     invoke  CreateFile,old_file.name,GENERIC_READ,FILE_SHARE_READ,NULL,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,NULL
     mov     esi,eax
     invoke  GetFileSize,eax,NULL
     mov     edi,eax
     invoke  GetProcessHeap
     mov     [hHeap],eax
     mov     ebx,eax
     invoke  HeapAlloc,eax,NULL,edi
     mov     [old_file.address],eax
     invoke  ReadFile,esi,eax,edi,temp,NULL
     invoke  CloseHandle,esi
 
     invoke  CreateFile,new_file.name,GENERIC_READ,FILE_SHARE_READ,NULL,OPEN_EXISTING,FILE_ATTRIBUTE_NORMAL,NULL
     mov     esi,eax
     invoke  GetFileSize,eax,NULL
     mov     edi,eax
     invoke  HeapAlloc,ebx,NULL,edi
     mov     [new_file.address],eax
     mov     ebx,eax
     invoke  ReadFile,esi,eax,edi,temp,NULL
     invoke  CloseHandle,esi
 
     invoke  HeapAlloc,[hHeap],NULL,edi
     mov     [result_file.address],eax
 
     invoke  GetCurrentThread
     invoke  SetThreadPriority,eax,THREAD_PRIORITY_TIME_CRITICAL
     rdtsc
     mov     esi,eax
 
     stdcall compare,[old_file.address],ebx,edi,[result_file.address]
     mov     ebx,eax
     rdtsc
     mov     edi,eax
 
     invoke  GetCurrentThread
     invoke  SetThreadPriority,eax,THREAD_PRIORITY_NORMAL
 
     sub     edi,esi
     cinvoke printf,cycles,edi
 
     mov     esi,[result_file.address]
     sub     ebx,esi
 
     invoke  CreateFile,result_file.name,GENERIC_WRITE,NULL,NULL,CREATE_ALWAYS,FILE_ATTRIBUTE_NORMAL,NULL
     mov     edi,eax
     invoke  WriteFile,eax,esi,ebx,temp,NULL
     invoke  CloseHandle,edi
     mov     edi,[hHeap]
     xor     ebx,ebx
     invoke  HeapFree,edi,ebx,[old_file.address]
     invoke  HeapFree,edi,ebx,[new_file.address]
     invoke  HeapFree,edi,ebx,esi
     invoke  Sleep,2000
 
     invoke  ExitProcess,0
 
proc compare uses esi edi ebx,file1,file2,size2,file3
     mov ecx,[size2]
     mov esi,[file1]
     mov edi,[file2]
     cld
     mov eax,0Ah
search_not_equal:
     mov edx,ecx
     repne scasb        ;search Carriage Return byte
     jne exit
 
     sub edx,ecx
     xchg edx,ecx       ;edx saves previous ecx, ecx = length of string
     mov ebx,ecx
 
     sub edi,ecx
     repe cmpsb
     xchg ecx,edx
     je search_not_equal
 
     ;if strings not equal
     sub edx,ebx
     neg edx
     sub esi,edx
     sub edi,edx
     xchg ebx,ecx
     mov edx,esi
     mov esi,edi
     mov edi,[file3]
     rep movsb
     mov [file3],edi
     mov edi,esi
     mov esi,edx
     mov ecx,ebx
     jmp search_not_equal
exit:
     mov eax,[file3]
     ret
endp
 
section '.data' data readable writeable
struc FILE name
{
   .name db name,0
   .address dd ?
}
 
hHeap dd ?
temp dd ?
cycle_count dd ?
old_file FILE 'old_file.txt'
new_file FILE 'new_file.txt'
result_file FILE 'result_file.txt'
 
cycles db 'Cycles %d',13,10,0
 
section '.idata' import data readable writeable
library kernel32,'KERNEL32.DLL',\
        user32,'USER32.DLL',\
        msvcrt,'msvcrt.dll'
 
include 'api\kernel32.inc'
include 'api\user32.inc'
import msvcrt,\
       printf,'printf'