Не выполняется условие

@experces · Регистрация: 23.02.2014

Добрый вечер форумчане.
Очень нуждаюсь в вашей помощи.

Суть такая: есть ватник который должен проверять в файле совпадение символов и в зависимости от результата давал разные значения.

Bash

:s1
set /p s="Please specify path to file: "
if exist "%s%" (goto n1) else (echo File Not Found & echo. & goto s1)
 
:n1
set /p n="Please enter text for searching: "
for /f %%e in ('findstr /i "%n%" %s%') do if "%%e"=="%n%" (echo good) else (echo bad)

В первом условии все работает:

Bash

1	if exist "%s%" (goto n1) else (echo File Not Found & echo. & goto s1)

В случае успеха, переход ко второму условию и в случае неудачи, переход к началу и требование повторить попытку.

Во втором условии:

Bash

1	for /f %%e in ('findstr /i "%n%" %s%') do if "%%e"=="%n%" (echo good) else (echo bad)

В случае успеха, возвращается сообщение good, в случае неудачи условие else попросту не срабатывает.

@sov44 · 26.02.2014, 20:01

experces, проверяйте присвоение переменной через defined. Примерно так (не проверял)

Bash

:s1
set /p s="Please specify path to file: "
if defined s (goto n1) else (echo File Not Found &echo. &goto s1)
 
:n1
set /p n="Please enter text for searching: "
if defined n (
if exist %s% (
find /i "%n%" "%s%" && (echo good) || (echo bad)
))

Dragokas · 27.02.2014, 03:16

Я бы так написал:

Bash

@echo off
SetLocal EnableExtensions
 
:s1
set s=
set /p "s=Please specify path to file: "
if not defined s goto s1
if exist "%s%" (goto n1) else (echo File Not Found &echo. &goto s1)
 
:n1
set n=
set /p "n=Please enter text for searching: "
if not defined n goto n1
>NUL find /i "%n%" < "%s%" && (echo good) || (echo bad)
echo.
goto s1

@@Root · 27.02.2014, 09:40

Dragokas,
строки 12 и 13 можно сократить:

Bash

1
2
3

:n1
set n=
set /p "n=Please enter text for searching: " || goto n1

Не выполняется условие

Решение

Решение

Опции темы