Возврат даты модификации файла в CMD

@Bazaroff · Регистрация: 29.05.2011

Author24 — интернет-сервис помощи студентам

В CMD хочу замутить такую штуку.
1. Вытянуть из конкретного файла *.* дату последней модификации.
2. Назначить для нее переменную "Х".
3. Сравнить месяц и год %X% с %DATE%.
4. При различии выполнить конкретную команду.
Поможете побаловаться?)))

@ComSpec · 25.05.2015, 11:23

Сообщение от Bazaroff

Поможете побаловаться?)))

Ддя этого переменная "X" собственно не нужна. Всё делается в одну строку.

Код командной строки:

Windows Batch file

1	for %i in ("конкретный файл") do @for /f "tokens=2,3,5,6 delims=.-/ " %j in ("%date% %~ti") do @if %j%k neq %l%m конкретная команда

.

Код пакетного файла:

Windows Batch file

1	@for %%i in ("конкретный файл") do @for /f "tokens=2,3,5,6 delims=.-/ " %%j in ("%date% %%~ti") do @if %%j%%k neq %%l%%m конкретная команда

.

@Bazaroff · 25.05.2015, 18:01 **[ТС]**

ComSpec, большущее спасибо.
Я пытаюсь кое-как осваивать CMD и т.п. Ограничен в понимальных возможностях, к сожалению(, но пытаюсь! Пытаюсь!
Будьте добры, растолкуйте детально ваш скрипт.
И, если не затруднит, каков был бы скрипт с использованием переменных? Или с переменными нерешаемо?

Добавлено через 14 минут
Почитал о команде FOR. Понятного не много (для меня). Когда искал решение наткнулся на команду FORFILES, но как оказалось она внешняя и к тому же оперирует только батниками. (По крайней мере так было сказано в описании).

@ComSpec · 26.05.2015, 12:55

Сообщение от Bazaroff

Будьте добры, растолкуйте детально ваш скрипт.

С помощью первого "for" получаем дату и время модификации файла ("%~ti"), которую передаём на разбор с помощью второго "for". Для разбора во втором цикле создаём строку "%date% %~ti", которая при раскрытии переменных будет иметь примерный вид "26.05.2015 26.11.2014 14:42". Поскольку нам надо сравнить месяц и год, то выделяем соответсвующие токены (2, 3, 5, 6), а разделителями будут точка и пробел (также в перечень разделителей добавлены дефис и слеш на случай другого формата даты). Далее сравниваются две пары (2-ой и 3-ий токены с 5-ым и 6-ым токенами), и по результату проверки истинности условия выполняется или не выполняется команда.

Сообщение от Bazaroff

И, если не затруднит, каков был бы скрипт с использованием переменных? Или с переменными нерешаемо?

Решаемо.

Варианты кода для пакетного файла:

1)

Windows Batch file

@echo off
setlocal
 
call :sub "конкретный файл"
 
:: Используем лексикографическое сравнение.
if defined X if %X:~3,7% neq %date:~3,7% конкретная команда
 
endlocal
exit/b 0
 
:sub
 set X=%~t1
 goto :eof

;

2)

Windows Batch file

@echo off
setlocal
 
for %%i in ("конкретный файл") do set X=%%~ti
 
:: Используем лексикографическое сравнение.
if defined X if %X:~3,7% neq %date:~3,7% конкретная команда
 
endlocal
exit/b 0

.

Вариант для командной строки (также с лексикографическим сравнением):

Windows Batch file

1	for %i in ("конкретный файл") do @set X=%~ti& cmd /v:on /c if defined X if !X:~3,7! neq %date:~3,7% конкретная команда

.

Сообщение от Bazaroff

Когда искал решение наткнулся на команду FORFILES, но как оказалось она внешняя...

Множество команд, постоянно используемых в пакетных файлах и командной строке, -- внешние, и это практически ни на что не влияет. Другое дело, что эта команда входит в комплектацию ОС, начиная с Windows Vista. Предназначена эта команда только для работы с файлами и папками, и разбирать строки она не может. Вот как с помощью этой команды можно получить дату и время модификации файла:

Windows Batch file

1	forfiles /m "конкретный файл" /c "cmd /c echo @fdate @ftime"

.
Обратите внимание, что дата и время модификации в команде "FORFILES" -- две самостоятельные переменные. Сочетание модификаторов же "~t" для переменных цикла при использовании "FOR" расширяет переменную до даты и времени модификации вместе.

Сообщение от Bazaroff

...и к тому же оперирует только батниками.

Не верьте.

@gepard13 · 06.03.2019, 16:03

Сообщение от ComSpec

forfiles /m "конкретный файл" /c "cmd /c echo @fdate @ftime"

не пойму как сделать так, чтобы результат этой команды записывался в переменную?

@alpap · 07.03.2019, 21:10

Сообщение от gepard13

результат этой команды записывался в переменную

Windows Batch file

@echo off
for /f "tokens=1*" %%a in ('forfiles /m "file.txt" /c "cmd /c echo @fdate @ftime"') do set "fdate=%%a"& set "ftime=%%b"
echo %fdate% %ftime%
pause

@Vadim89897575 · 13.11.2021, 01:26

alpap, ComSpec, ребят. а мне нужен код такой:

если дата создания ( или дата изменения - всё-равно в принципе) файла : C:\Temp\Pogloc\1.txt

более чем 40 часов, тогда выполняем код дальше , а если меньше 40 часов - exit

p.s. то есть этот код должен стоять в самом начале cmd файла, и проверять дату файла.

@Karen87 · 13.11.2021, 15:26

Vadim89897575, пробуйте:

Windows Batch file

@echo off
set "file=C:\Temp\Pogloc\1.txt"
for /f "tokens=* delims=" %%a in ('powershell -executionpolicy bypass -command "if (((get-date) - (Get-ChildItem '%file%').CreationTime).totalHours -gt 40) {'yes'} else {'no'}"') do (
    if "%%a"=="yes" (
        echo Process
    ) else (
        exit
    )
)
pause
exit

Примечание.
В 5-ой строчке вместо echo Process указываете код, который должен отработать при выполнении условия даты создания файла более 40 часов по отношению к текущей либо можете реализовать в виде вызова call

Возврат даты модификации файла в CMD

Решение

Решение

@Bazaroff 288 / 93 / 11 Регистрация: 29.05.2011 Сообщений: 2,399
		1
	Возврат даты модификации файла в CMD 24.05.2015, 23:30. Показов 21294. Ответов 7 Метки нет (Все метки) В CMD хочу замутить такую штуку. 1. Вытянуть из конкретного файла . дату последней модификации. 2. Назначить для нее переменную "Х". 3. Сравнить месяц и год %X% с %DATE%. 4. При различии выполнить конкретную команду. Поможете побаловаться?))) 0

@Bazaroff 288 / 93 / 11 Регистрация: 29.05.2011 Сообщений: 2,399
	25.05.2015, 18:01 [ТС]	3
	ComSpec, большущее спасибо. Я пытаюсь кое-как осваивать CMD и т.п. Ограничен в понимальных возможностях, к сожалению(, но пытаюсь! Пытаюсь! Будьте добры, растолкуйте детально ваш скрипт. И, если не затруднит, каков был бы скрипт с использованием переменных? Или с переменными нерешаемо? Добавлено через 14 минут Почитал о команде FOR. Понятного не много (для меня). Когда искал решение наткнулся на команду FORFILES, но как оказалось она внешняя и к тому же оперирует только батниками. (По крайней мере так было сказано в описании). 0

@gepard13 0 / 0 / 0 Регистрация: 05.02.2019 Сообщений: 9
	06.03.2019, 16:03	5
	Сообщение от ComSpec forfiles /m "конкретный файл" /c "cmd /c echo @fdate @ftime" не пойму как сделать так, чтобы результат этой команды записывался в переменную? 0

@Vadim89897575 5 / 5 / 0 Регистрация: 17.03.2021 Сообщений: 161
	13.11.2021, 01:26	7
	alpap, ComSpec, ребят. а мне нужен код такой: если дата создания ( или дата изменения - всё-равно в принципе) файла : C:\Temp\Pogloc\1.txt более чем 40 часов, тогда выполняем код дальше , а если меньше 40 часов - exit p.s. то есть этот код должен стоять в самом начале cmd файла, и проверять дату файла. 0

	13.11.2021, 15:26