Картинки в подпапках с одинаковыми именами

@echo off
 
set "source=C:\Test 1"
set "destination=C:\Test 2"
set "filename=1"
 
2>nul md "%destination%"
for /d %%i in ("%source%\*") do (
 set/a n+=1
 for %%j in ("%%i\%filename%.*") do (
  call move "%%j" "%destination%\%%~nj(%%n%%)%%~xj"
 )
)
 
exit/b

@echo off
:: универсальный вариант для перемещения файлов в новое расположение без дублей имен
:: переименование идет по принципу добавления постфикса: _(номер)
:: то есть test.txt переименуется в test_(1).txt, test_(2).txt и т.д
:: у каждого файла будет своя нумерация начиная с 1
 
:: стартовая директория
set "input=d:\dir1"
:: директория перемещения файлов
set "output=d:\dir2"
if not exist "%output%" md "%output%"
for /r "%input%" %%i in (*.*) do (call :movefile "%%i")
echo End operation
pause
exit /b
 
:movefile
setlocal
if not defined inputpath (set "inputpath=%~1")
if not defined name (set "name=%~n1")
if not defined ext (set "ext=%~x1")
if not defined postfix (set "postfix=")
if not defined count (set count=1)
 
if exist "%output%\%name%%postfix%%ext%" (
 set /a count+=1
   set "postfix=_(%count%)"
    call :movefile
     goto :eof
)
 
rem echo "%inputpath%" "%output%\%name%%postfix%%ext%">>c:\log.txt
move "%inputpath%" "%output%\%name%%postfix%%ext%" >nul
endlocal
goto :eof