Почему скрипт входит в бесконечный цикл на Win XP ?

@vavun · Регистрация: 07.04.2013

Author24 — интернет-сервис помощи студентам

Приветствую.
Собственно сабж

Windows Batch file

@echo off
SetLocal EnableExtensions EnableDelayedExpansion
 
 
:FILENAME
if not defined postfix (set "postfix=")
if not defined count (set count=1)
set "FILE=%~dp0empty%postfix%.txt"
if exist %FILE% (
                    set /a count+=1
                    set "postfix=_(%count%)"
                    call :FILENAME
                    )
echo.>%FILE%
exit

Начиная с висты работает, а на Win XP уходит в бесконечный цикл, а потом завершает скрипт.
Почему ?
Чую, что решение простое, но сам додуматься не могу.

Заранее спасибо

Добавлено через 8 минут
Сам спросил ,сам ответил

Windows Batch file

8	set FILE="%~dp0empty%postfix%.txt"

Теперь работает

@ComSpec · 18.11.2015, 03:37

vavun, вот так всё-таки надёжнее и логичнее:

Windows Batch file

@echo off
setlocal enableextensions
 
set count=1
set "postfix="
 
:FILENAME
set "FILE=%~dp0empty%postfix%.txt"
if exist "%FILE%" (
                    set "postfix=_(%count%)"
                    set /a count+=1
                    call :FILENAME
                   )
rem:>"%FILE%"
 
endlocal
exit /b

.

@vavun · 18.11.2015, 03:55 **[ТС]**

Согласен, спасибо )

Dragokas · 20.11.2015, 11:36

вместо call :FILENAME лучше goto FILENAME,
быстрее, и никогда не уйдет в переполнение стека.

@vavun · 20.11.2015, 20:47 **[ТС]**

О боги ! Почему оно не работает ?

Windows Batch file

@echo off
setlocal enableextensions
 
 
if "%1"=="" (
      set count=1
      set "postfix="
 
      :FILENAME
      set "FILE=%~dp0empty%postfix%.txt"
      if exist "%FILE%" (
                    set "postfix=_(%count%)"
                    set /a count+=1
                    call :FILENAME
                   )
      echo "%FILE%"
      pause
)

Господа, что я делаю не так ?

Где эта элементарная загвоздка ?
Почему она не назначается ?

Добавлено через 12 минут
А так работает

Windows Batch file

5	if "%1"=="" call (

Добавлено через 3 минуты
А нет, не работает ...

Dragokas · 20.11.2015, 20:54

Попытка вызова метки из под скобочной конструкции...

Вообще оформи этот функционал нормально, как отдельную подпрограмму, и вызывай ее через call

Windows Batch file

1	if "%~1"=="" call :FILENAME

и т.д.

@vavun · 20.11.2015, 21:01 **[ТС]**

Сообщение от Dragokas

оформи этот функционал нормально, как отдельную подпрограмму

А я как раз пытался от этого отказаться

Если разбить на отдельные составляющие и вызывать через call, то работает

Сообщение от Dragokas

Попытка вызова метки из под скобочной конструкции..

А можно поподробнее с этого места ?

Dragokas · 20.11.2015, 21:23

Сообщение от vavun

А я как раз пытался от этого отказаться

Не ты ли в соседней теме рекомендовал юзеру не использовать слишком "пирамидальную" конструкцию кода?

Сообщение от vavun

А можно поподробнее с этого места ?

А, нет, работает. Что-то подзабыл, в каких случаях так нельзя.

В твоем случае, попытка раскрыть переменную из под того же блока скобок, где и происходило присвоение значения.

@vavun · 20.11.2015, 22:20 **[ТС]**

Ругаться матом скоро буду

Windows Batch file

@echo off
setlocal enableextensions
 
 
if "%~1"=="" (call :EMPTY & exit /b)
if "%~1" neq "" (call :FULL & exit /b)
 
:EMPTY
echo There is no arg. Look "%1"
exit /b
 
:FULL
echo Here is the arg "%1"
exit /b

Наличие первого аргумента определяется верно

Но выводить его он не хочет ни в какую

Добавлено через 38 секунд

Не по теме:

Сообщение от Dragokas

Не ты ли в соседней теме

Вроде бы не я :pardon:

Добавлено через 16 минут
Думал по-быстрому сделаю, но не вышло.
В общем ТЗ:

При запуске скрипта без параметров

Код

batfile.bat

создать файл empty.txt, если такой есть, то empty_(1).txt и тд, примерно как тут

Windows Batch file

set count=1
set "postfix="
 
:FILENAME
set "FILE=%~dp0empty%postfix%.txt"
if exist "%FILE%" (
                    set "postfix=_(%count%)"
                    set /a count+=1
                    call :FILENAME
                   )
rem:>"%FILE%"
 
endlocal
exit /b

Если скрипту был передан аргумент

Код

batfile.bat arg

То передать этот аргумент программе

Windows Batch file

@echo off
prog.exe "%1"

Думал ничего сложного

Dragokas · 20.11.2015, 22:21

vavun, разумеется не выводит. %1 в подпрограмме обозначает аргумент подпрограммы, а не пакетного файла.

@vavun · 20.11.2015, 22:22 **[ТС]**

Сообщение от Dragokas

%1 в подпрограмме обозначает аргумент подпрограммы

А так прокатит ? )

Windows Batch file

call :PROG "%1" & exit /b

Dragokas · 20.11.2015, 22:24

Воткнуть 3-й строкой кода ComSpec:

Windows Batch file

1	if "%~1" neq "" (prog.exe "%~1"& exit /B)

и все ТЗ решено.

Добавлено через 1 минуту

Сообщение от vavun

А так прокатит ? )

Только тильду не забывай. Она лишние кавычки удаляет.

@vavun · 20.11.2015, 22:24 **[ТС]**

Прокатило вроде

Добавлено через 28 секунд

Сообщение от Dragokas

Воткнуть 3-й строкой кода ComSpec:

Сейчас проверим, благодарю

@b0gus · 20.11.2015, 22:25

может быть так:

Windows Batch file

@echo off
setlocal enableextensions
        
if "%~1"=="" (call :EMPTY %* & exit /b)
if "%~1" neq "" (call :FULL %* & exit /b)
 
:EMPTY
echo There is no arg. Look "%1"
exit /b
 
:FULL
echo Here is the arg "%1"
exit /b

@vavun · 20.11.2015, 22:33 **[ТС]**

Ну да, логично

Добавлено через 17 секунд
Dragokas, благодарю

Добавлено через 26 секунд

Сообщение от b0gus

может быть так:

В принципе можно и так

Добавлено через 5 минут
Dragokas, сработало как нужно

Dragokas · 21.11.2015, 23:14

Потребовалось сегодня чисто на cmd реализовать максимально быстрый код для поиска свободного имени, подобно как у vavun.
Сделал через кеш переименований.
По условию, кол-во файлов с одинаковым именем будет превышать 50, при этом известно что папка заранее пуста (ну или по крайней мере не содержит огромного кол-ва файлов с одинаковыми именами).

Windows Batch file

@echo off
SetLocal EnableExtensions
 
call :GetEmptyName "%~dp0" test.txt file
rem:>"%file%"
 
call :GetEmptyName "%~dp0" test.txt file
rem:>"%file%"
 
call :GetEmptyName "%~dp0" test.txt file
rem:>"%file%"
 
:: и.т.д.
 
pause
goto :eof
 
:GetEmptyName %1-Folder %2-FileName %3-Var.Return
  if exist "%~1\%~2" (
    if defined Empty[%~2] (
      call call :CheckKnownName "%~1" "%~2" "%~3" "%%Empty[%~2]%%" || (
        set SystemNum=0
        call :GetEmptyNameFast "%~1" "%~2" "%~3"
      )
    ) else (
      set SystemNum=0
      call :GetEmptyNameFast "%~1" "%~2" "%~3"
    )
  ) else (
    set "%~3=%~2"
  )
exit /B
 
:CheckKnownName %1-Folder %2-FileName %3-Var.Return %4-index
  set idx=%~4
  set /a idx+=1
  set "NewFileName=%~n2 (%idx%)%~x2"
  if exist "%~1\%NewFileName%" exit /B 1
  set "%~3=%NewFileName%"
  set "Empty[%~2]=%idx%"
exit /B 0
 
:GetEmptyNameFast %1-Folder %2-FileName %3-Var.Return
  set /a SystemNum+=1
  Set "NewFileName=%~n2 (%SystemNum%)%~x2"
  if exist "%~1\%NewFileName%" (
    goto GetEmptyNameFast
  ) else (
    set "%~3=%NewFileName%"
    set "Empty[%~2]=%SystemNum%"
  )
exit /B

Dragokas 17996 / 7697 / 892 Регистрация: 25.12.2011 Сообщений: 11,470 Записей в блоге: 16
	20.11.2015, 22:21	10
	vavun, разумеется не выводит. %1 в подпрограмме обозначает аргумент подпрограммы, а не пакетного файла. 1

Почему скрипт входит в бесконечный цикл на Win XP ?

Решение

Решение

Решение

@vavun 10582 / 5545 / 864 Регистрация: 07.04.2013 Сообщений: 15,660
	18.11.2015, 03:55 [ТС]	3
	Согласен, спасибо ) 0

Dragokas 17996 / 7697 / 892 Регистрация: 25.12.2011 Сообщений: 11,470 Записей в блоге: 16
	20.11.2015, 11:36	4
	Сообщение было отмечено vavun как решение Решение вместо call :FILENAME лучше goto FILENAME, быстрее, и никогда не уйдет в переполнение стека. 2

@vavun 10582 / 5545 / 864 Регистрация: 07.04.2013 Сообщений: 15,660
	20.11.2015, 21:01 [ТС]	7
	Сообщение от Dragokas оформи этот функционал нормально, как отдельную подпрограмму А я как раз пытался от этого отказаться Если разбить на отдельные составляющие и вызывать через call, то работает Сообщение от Dragokas Попытка вызова метки из под скобочной конструкции.. А можно поподробнее с этого места ? 0

Dragokas 17996 / 7697 / 892 Регистрация: 25.12.2011 Сообщений: 11,470 Записей в блоге: 16
	20.11.2015, 21:23	8
	Сообщение от vavun А я как раз пытался от этого отказаться Не ты ли в соседней теме рекомендовал юзеру не использовать слишком "пирамидальную" конструкцию кода? Сообщение от vavun А можно поподробнее с этого места ? А, нет, работает. Что-то подзабыл, в каких случаях так нельзя. В твоем случае, попытка раскрыть переменную из под того же блока скобок, где и происходило присвоение значения. 1

@vavun 10582 / 5545 / 864 Регистрация: 07.04.2013 Сообщений: 15,660
	20.11.2015, 22:22 [ТС]	11
	Сообщение от Dragokas %1 в подпрограмме обозначает аргумент подпрограммы А так прокатит ? ) Windows Batch file call :PROG "%1" & exit /b 0

@vavun 10582 / 5545 / 864 Регистрация: 07.04.2013 Сообщений: 15,660
	20.11.2015, 22:24 [ТС]	13
	Прокатило вроде Добавлено через 28 секунд Сообщение от Dragokas Воткнуть 3-й строкой кода ComSpec: Сейчас проверим, благодарю 0

@vavun 10582 / 5545 / 864 Регистрация: 07.04.2013 Сообщений: 15,660
	20.11.2015, 22:33 [ТС]	15
	Ну да, логично Добавлено через 17 секунд Dragokas, благодарю Добавлено через 26 секунд Сообщение от b0gus может быть так: В принципе можно и так Добавлено через 5 минут Dragokas, сработало как нужно 0