Как узнать язык системы?

if "!x: =!"=="1049" (
echo Русская винда
) else (
echo Английская винда
)

@echo off
wmic path Win32_OperatingSystem get oslanguage|more +1|set/p x=^& cmd/v/c if "!x: =!"=="1049" (echo:Кодовая страница RU) else (if "!x: =!"=="1033" (echo:Кодовая страница EN))
pause>nul

@echo off
for /f "tokens=3" %%a in ('reg query "HKEY_USERS\.DEFAULT\Keyboard Layout\Preload"^|find "REG_SZ"') do (
 if %%a==00000409 echo:Язык входа в сиистему EN 00000409
 if %%a==00000419 echo:Язык входа в сиистему RU 00000419
)
pause>nul

@echo off
systeminfo|find /i "Язык системы:"
pause

@echo off
systeminfo|find /i "Язык ввода:"
pause

@echo off
echo wsh.echo getlocale>%Temp%\LCID.vbs
for /f %%l in ('cscript //nologo %Temp%\LCID.vbs') do (
  If %%l==1049 (echo Язык системы: русский) Else echo Язык системы: нерусский
)
del %Temp%\LCID.vbs
pause

setlocal
  set "key=HKU\.DEFAULT\Control Panel\International"
  for /f "tokens=3" %%I in (
    'reg query "%key%" /v Locale'
  ) do set "loc=%%I"
 
  if %loc%==00000419 (
  Photoshop_RU.exe -param1 -param2
  ) else (
  Photoshop_EN.exe -param1 -param2
  )
endlocal

@echo off
setlocal
  set "key=HKU\.Default\Control Panel\Desktop\MuiCached"
  for /f "tokens=3" %%I in (
    'reg query "%key%" /v MachinePreferredUILanguages'
  ) do set "loc=%%I"
 
  if %loc%==ru-RU (
  echo Russian languge
  ) else (
  echo Other language
  )
endlocal
pause

@echo off
setlocal
  set "key=HKU\.Default\Control Panel\International"
  for /f "tokens=3" %%I in (
    'reg query "%key%" /v LocaleName'
  ) do set "loc=%%I"
 
  if %loc%==ru-RU (
  echo Russian languge
  ) else (
  echo Other language
  )
endlocal
pause

@echo off
setlocal EnableExtensions
set "loc="
set "Lang="
for /f "tokens=3" %%I in ('reg query "HKCU\Control Panel\Desktop" /v "PreferredUILanguages"') do set "loc=%%I"
if not defined loc for /f "tokens=3" %%I in ('reg query "HKCU\Control Panel\International" /v "Locale"') do set "loc=%%I"
if "%loc%"=="ru-RU" set "Lang=RU"
if "%loc%"=="00000419" set "Lang=RU"
if "%Lang%"=="RU" (
  echo Russian language
) else (
  echo Other language
)
pause

ListRegistryLinks.exe hku

@echo off
setlocal EnableExtensions
set "loc="
set "Lang="
for /f "tokens=3" %%I in ('reg query "HKCU\Control Panel\International" /v "LocaleName"') do set "loc=%%I"
if not defined loc for /f "tokens=3" %%I in ('reg query "HKCU\Control Panel\International" /v "Locale"') do set "loc=%%I"
if "%loc%"=="ru-RU" set "Lang=RU"
if "%loc%"=="00000419" set "Lang=RU"
if "%Lang%"=="RU" (
  echo Russian language
) else (
  echo Other language
)
pause

for /f "tokens=3" %%I in ('2^>NUL reg query "HKCU\Control Panel\Desktop" /v "PreferredUILanguages"') do set "loc=%%I"

@echo off
SetLocal EnableExtensions
 
Call :GetSystemVersion "OSVer" "Core" "Build"
Echo Your operating system: %OSVer% %Core% %Build%
 
 
SET varIP=192.168.134.7
SET varCE=N20170813
 
SET varDriver=Xerox WorkCentre 5325 PCL6
SET varDriverFolder32=\\vodokanal.spb.ru\service\soft\Drivers\Xerox\Xerox WC 5325\32-bit_x86
SET varDriverFolder64=\\vodokanal.spb.ru\service\soft\Drivers\Xerox\Xerox WC 5325\64-bit_x64
 
if "%Core%"=="x32" SET varDriverFolder=%varDriverFolder32%
if "%Core%"=="x64" SET varDriverFolder=%varDriverFolder64%
 
SET varDriverFile=%varDriverFolder%\x2GSANX.inf
SET varName=%varCE% Xerox WC 5325
 
REM "Deleting TCP/IP port"
CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnport.vbs -d -r IP_%varIP%
CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnport.vbs -d -r %varIP%
 
REM "Creating TCP/IP port"
CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnport.vbs -a -r IP_%varIP% -o raw -n 9100 -h %varIP%
 
REM "Installation message"
@ECHO.
@ECHO Please do not close this window.
@ECHO.
@ECHO Once the installation is complete this Setup window will exit.
@ECHO.
 
REM "Driver installation"
  
if "%_ver%"=="5.1" (rundll32.exe printui.dll,PrintUIEntry /ia /m "%varDriver%" /f "%varDriverFile%") else (CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prndrvr.vbs -a -m "%varDriver%" -h "%varDriverFolder%" -i "%varDriverFile%")
rem pnputil.exe -a "%varDriverFile%"
 
REM "Printer deletion"
@ECHO.
@ECHO Completing installation.
CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnmngr.vbs -d -p "%varName%" 
 
 
REM "Printer installation"
@ECHO.
@ECHO Completing installation.
CSCRIPT /nologo C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnmngr.vbs -a -p "%varName%" -m "%varDriver%" -r "IP_%varIP%"
 
 
REM "Making it Default printer"
REM CSCRIPT C:\Windows\System32\Printing_Admin_Scripts\ru-RU\prnmngr.vbs -p "%varName%" -t
 
@ECHO Thank you.
PAUSE
 
 
goto :eof
 
:GetSystemVersion
:: Определить версию ОС
:: %1-исх.Переменная для хранения названия ОС
:: %2-исх.Переменная для хранения разрядности ОС
:: %3-исх.Переменная для хранения версии сборки ОС
  Set "Bitness=x64"& If "%PROCESSOR_ARCHITECTURE%"=="x86" If Not Defined PROCESSOR_ARCHITEW6432 Set "Bitness=x32"
  set "%~2=%Bitness%"
  For /F "delims=" %%a in ('ver') do set _ver=%%a
  Set _ver="%_ver: =" "%"
  For %%a in (%_ver%) do set _ver=%%~a
  for /F "delims=]" %%a in ("%_ver%") do set %~3=%%a
  set _ver=%_ver:~0,3%
  SET %~1=Unknown
  if "%_ver%"=="5.0" SET %~1=Windows 2000
  if "%_ver%"=="5.1" SET %~1=Windows XP
  if "%_ver%"=="5.2" if "%Bitness%"=="x64" (SET %~1=Windows XP) else (SET %~1=Windows 2003)
  if "%_ver%"=="6.0" (
    Reg.exe query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "ProductName"|>nul Find /i "Vista"&&(
    SET %~1=Windows Vista) || (SET %~1=Windows 2008)
  )
  if "%_ver%"=="6.1" SET %~1=Windows 7
  if "%_ver%"=="6.2" SET %~1=Windows 8
  if "%_ver%"=="6.3" SET %~1=Windows 8.1
  if "%_ver%"=="6.4" SET %~1=Windows 10
  if "%_ver%"=="10." SET %~1=Windows 10
  set _ver=
 
Exit /B