Рекурсивный поиск и удаление каталога. Пробелы в имени каталога

@MadBittern · Регистрация: 12.11.2012

Author24 — интернет-сервис помощи студентам

Со вторым днем зимы всех.

Есть bat:

Windows Batch file

@echo off
rem unsvn.bat
setlocal
rem rdir=название_удаляемых_каталогов
set rdir=Startup
 
rem Раскоментировать чтоб задавать имя удаляемого каталога в строке параметров:
rem set rdir=%1
set fpath=%~dps0
call :func %fpath:~0,-1%
goto end
:func
for /f "delims=" %%i in ('dir %1 /a:d /b') do IF /I %%i==%rdir% ( rmdir /s /q %1\%%i && echo deleted %1\%%i ) ELSE ( call :func %1\%%i )
exit /b
:end
rem Удалить самого себя:
rem del /Q /F %fpath%%~nx0
pause

Прекрасно отрабатывает, на глубину вложенности, до каталога с пробелом в имени, как решить эту проблему? Писать путь в кавычках не вариант т.к он может быть разный, но в пути всегда будет присутствовать, как минимум, один каталог в имени которого пробел.

YuS_2 · 02.12.2016, 11:31

Сообщение от MadBittern

Писать путь в кавычках не вариант т.к он может быть разный

Не вижу препятствий... если положено пути с пробелами заключать в кавычки, то необходимо таки сделать это, иначе получите то, что и получили...

@alpap · 02.12.2016, 12:45

MadBittern,
Глубина вложенности по уму задается в dir. Проверку лучше делать через if exist, а кавычки (как сказал выше YuS_2) это вообще часть синтаксиса в случае работы с путями и параметрами.

Сообщение от MadBittern

Писать путь в кавычках не вариант т.к он может быть разный

Приведите хоть один неустраивающий вариант, интересно.

@MadBittern · 02.12.2016, 13:07 **[ТС]**

Сообщение от YuS_2

Не вижу препятствий...

Сообщение от alpap

Приведите хоть один неустраивающий вариант, интересно.

У меня порядка 100 машин в сети, каталоги присутствуют на каждой, причем в нескольких экземплярах по разным путям, путь может иметь вид

"C://(1/pc_name/user_name/user_na me/ip/user/Documents and Setting/ )/(1/pc_name/user_name/user_na me/ip/user)/dir_name/dir_na me/targetdir"

от 6 до n+1 искомых каталогов на машину, где n количество локальных доменных пользователей ПК, я физически не могу знать все искомые пути. Если я правильно понял то заключать в кавычки нужно конечный путь до файла, если нет поправте меня.

YuS_2 · 02.12.2016, 13:42

Сообщение от MadBittern

физически не могу знать все искомые пути.

А их и не надо знать, но:

Сообщение от https://www.microsoft.com/resources/documentation/windows/xp/all/proddocs/en-us/cmd.mspx?mfr=true

File and directory name completion correctly processes file names that contain white space or special characters if you place quotation marks around the matching path.
The following special characters require quotation marks: & < > [ ] { } ^ = ; ! ' + , ` ~ [white space]
If the information that you supply contains spaces, use quotation marks around the text (for example, "Computer Name").

Добавлено через 2 минуты

Сообщение от MadBittern

заключать в кавычки нужно конечный путь до файла, если нет поправте меня.

Вот Ваш сценарий, но с правильным использованием кавычек:

Windows Batch file

@echo off
rem unsvn.bat
setlocal
rem "rdir=название_удаляемых_каталогов"
set "rdir=Startup"
 
rem Раскоментировать чтоб задавать имя удаляемого каталога в строке параметров:
rem set "rdir=%1"
set "fpath=%~dp0"
call :func "%fpath:~0,-1%"
goto end
:func
for /f "delims=" %%i in ('dir "%~1" /a:d /b') do IF /I "%%~i"=="%rdir%" (echo rmdir /s /q "%~1\%%~i" && echo deleted "%~1\%%~i") ELSE ( call :func "%~1\%%~i" )
exit /b
:end
rem Удалить самого себя:
rem del /Q /F "%fpath%%~nx0"
pause

Добавлено через 4 минуты
Можете запустить сценарий и пронаблюдать, что будет удаляться и с какими путями
Для реального использования, вот здесь:

Windows Batch file

1	(echo rmdir /s /q "%~1\%%~i" && ...

не забудьте удалить команду echo

YuS_2 Любознательный 5668 / 1683 / 314 Регистрация: 10.03.2016 Сообщений: 3,824
	02.12.2016, 11:31	2
	Сообщение от MadBittern Писать путь в кавычках не вариант т.к он может быть разный Не вижу препятствий... если положено пути с пробелами заключать в кавычки, то необходимо таки сделать это, иначе получите то, что и получили... 0

@alpap 4334 / 2124 / 661 Регистрация: 26.04.2015 Сообщений: 6,823
	02.12.2016, 12:45	3
	MadBittern, Глубина вложенности по уму задается в dir. Проверку лучше делать через if exist, а кавычки (как сказал выше YuS_2) это вообще часть синтаксиса в случае работы с путями и параметрами. Сообщение от MadBittern Писать путь в кавычках не вариант т.к он может быть разный Приведите хоть один неустраивающий вариант, интересно. 0

@MadBittern 7 / 7 / 2 Регистрация: 12.11.2012 Сообщений: 203
	02.12.2016, 13:07 [ТС]	4
	Сообщение от YuS_2 Не вижу препятствий... Сообщение от alpap Приведите хоть один неустраивающий вариант, интересно. У меня порядка 100 машин в сети, каталоги присутствуют на каждой, причем в нескольких экземплярах по разным путям, путь может иметь вид `"C://(1/pc_name/user_name/user_na me/ip/user/Documents and Setting/ )/(1/pc_name/user_name/user_na me/ip/user)/dir_name/dir_na me/targetdir"` от 6 до n+1 искомых каталогов на машину, где n количество локальных доменных пользователей ПК, я физически не могу знать все искомые пути. Если я правильно понял то заключать в кавычки нужно конечный путь до файла, если нет поправте меня. 0

	02.12.2016, 13:42

Рекурсивный поиск и удаление каталога. Пробелы в имени каталога

Решение