Команда ROBOCOPY и размер папки

@echo off
setlocal enabledelayedexpansion
chcp 1251>nul
set /p src=Входная папка:
set /p output=Выходная папка:
set kol=0
FOR %%a IN ("!src!\*") DO (
 set /a kol=!kol!+1
)
set kol1=0
FOR %%a IN ("!src!\*") DO (
 robocopy "!src!" "!output!" "%%~nxa">nul
 set /a kol1=!kol1!+1
 set /a percentage1=!kol1!*100
 set /a percentage=!percentage1!/!kol!
 cls
 echo Скопировано !kol1! файлов из !kol! ^(!percentage!%%^)
)
echo Копирование завершено^!
pause>nul
chcp 866>nul
exit 0

@Echo Off
SetLocal enabledelayedexpansion EnableExtensions
chcp 1251>nul
set /p src=Входная папка:
set /p output=Выходная папка:
 
Call :GetFolderSize "%src%" TotalSize
Call :ConvertBytes %TotalSize% strTotalSize
 
Call :GetTemporaryName tmpfile
dir "%src%" /b /s /a:-d>"%tmpfile%"
for /F "Delims=" %%A in ('find /v /c ""^<"%tmpfile%"') do Set /A TotalCount=%%A
 
set /A Count=0
FOR /F "UseBackQ delims=" %%A IN ("%tmpfile%") DO (
  robocopy /S "%src%" "%output%" "%%~nxA">nul
  set /A Count+=1
  set /A Size=!Size!+%%~zA
  set /A percentage=!Size!*100/%TotalSize%
  Call :ConvertBytes !Size! strSize
  cls
  echo Скопировано !Count! файлов из %TotalCount%. !strSize! из !strTotalSize! ^(!percentage!%%^)
)
echo Копирование завершено^!
del "%tmpfile%"
chcp 866>nul
pause
exit 0
 
:GetFolderSize %1-Folder_Name %2-Var_Name.Size
Call :GetTemporaryName tmpfile
Dir "%~1" /-C /S /A:-D>"%tmpfile%"
for /f %%A in ('find /v /c "" ^< "%tmpfile%"') do Set /A Count=%%A
Set /A Count-=2
For /F "tokens=1-3" %%a IN ('more +%Count% ^< "%tmpfile%"') Do Set %~2=%%c& Goto :DirSizeExt
:DirSizeExt
Del "%tmpfile%"
::Set /a dirsizeT=dirsize+0
::If Not "%dirsizeT%"=="%dirsize%" Echo Число %dirsize% слишком велико для обработки в CMD& Exit /B
Exit /B
 
:GetTemporaryName %1-var_Name
set sTempName=%temp%\temp%random%.tmp
if exist "%sTempName%" (goto :GetTemporaryName) else (set %1=%sTempName%)
Exit /B
 
:ConvertBytes %1-Bytes %2-var_name_Size_with_Measure
Set %~2=%~1 B
if %~1 GEQ 1024 Set /A %~2=%~1/1024& Set %~2=!%~2! KB
if %~1 GEQ 1048576 Set /A %~2=%~1/1024/1024& Set %~2=!%~2! MB
Exit /B