Каталог простых примеров решенных задач BAT/CMD, с чего начать (■■■ основная тема ■■■)

@Echo Off
:: Кодировка файла 'Кириллица DOS' (866)
Set var=123456789
Echo.
Echo                    Запись        Значение
Echo.
Echo Переменная полностью            %%var%%     %var%
Echo.
Echo Первые три символа         %%var:~0,3%%    %var:~0,3%
Echo Последние три символа           %%var:~-3%% %var:~-3%
Echo Три символа начиная с шестого     %%var:~5,3%%    %var:~5,3%
Echo Без первых трех символов      %%var:~3%%  %var:~3%
Echo Без последних трех символов        %%var:~0,-3%%   %var:~0,-3%
Echo Без первых двух и последних трех    %%var:~2,-3%%   %var:~2,-3%
Echo.
Echo Замена части переменной (45 на abc) %%var:45=abc%%  %var:45=abc%
Echo Замена части переменной и символов
Echo до нее (23, и все что до этого, на xyz)   %%var:*23=xyz%% %var:*23=xyz%
Echo Удаление части переменной (567)     %%var:567=%%    %var:567=%
Pause>Nul

@echo off 
Setlocal
set st=abcdefghijklmnopqrstuvwxyz
call :var_Count "%st%" count
echo %count%
exit /b
 
:var_count
set var=%~1
if not defined var exit /b
set var=%var:~1%
set /a %2+=1
call :var_count "%var%" %2
exit /b

:var_count %1-in.Text %2.out.Len.of.Text
  set _var=%~1& set _count=0
  :_count_loop
  set _var=%_var:~1%
  set /a _count+=1
  if not defined _var (set %~2=%_count%& exit /b) else (goto :_count_loop)
Exit /B

:var_count
::%1 - текст
::%2 - Переменная для хранения кол-ва символов в тексте
  set "_text=%~1"
  if "%_text%"=="" (set %~2=0& Exit /B)
  set _TCount=
  for /L %%C in (0,1,8184) do if "!_text:~%%C,1!"=="" (goto var_count_ext) else (set _TCount=%%C)
:var_count_ext
  set /A _TCount+=1
  set %~2=%_TCount%
Exit /B

@echo off
set /p param=Введите имя переменной среды:
for /f %%a in ('call echo %%%param%%%') do (
  if "%%a"=="%%%param%%%" (
      echo Переменная не определена
    ) else (
      echo Переменная определена, ее значение равно %%a)
  )
)
pause>nul

@echo off
chcp 1251
setlocal
set files=Русс.lnk 1111*.lnk *z.lnk
%homedrive%
if exist "%homedrive%%homepath%\desktop" (set homedesk=desktop) else (set homedesk=Рабочий стол)
if exist "%public%" (set comdesk=%public%\%homedesk%) else (set comdesk=%allusersprofile%\%homedesk%)
chdir "%homedrive%%homepath%\%homedesk%"
for %%a in (%files%) do (echo del /q "%%a"&echo del /q "%comdesk%\%%a" >nul)
endlocal
chcp 866

@Echo Off
SetLocal enabledelayedexpansion
 
Call :RtoL "Stroka" Rev
Echo %Rev%
pause>nul
Goto :eof
 
:RtoL
Set Cnt=
Call :var_count "%~1" Cnt
set var=%~1
set Cnt-=1
Set %2=
for /L %%C in (%Cnt%,-1,0) do Set %2=!%2!!var:~%%C,1!
Exit /B
 
:var_count
set var=%~1
if not defined var exit /b
set var=%var:~1%
set /a %2+=1
call :var_count "%var%" %2
exit /b

set server=s1
set netfolder=budget$
set UncPath=\\%server%\%netfolder%
set RegKey=%UncPath:\=#%
REM net use x: /delete
net use x: "%UncPath%" /persistent:no
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\%RegKey%" /v "_LabelFromReg" /d "Бюджет 2013" /f
REM start x:\

@echo off
echo            Без кавычек : %~1 
echo     Полное имени файла : %~f1
echo       Только имя диска : %~d1
echo    Только путь к файлу : %~p1
echo       Только имя файла : %~n1
echo Расширение имени файла : %~x1
echo     Путь в формате 8.3 : %~s1
echo               Атрибуты : %~a1
echo    Даты /времени файла : %~t1
echo          Размера файла : %~z1
echo               Венегрет : %~ztasxnpdf1
pause

@echo off
for /F "delims=" %%A in ('dir c:\windows\media\*.wav /b /s') do (
  echo Имя файла с расширением : %%~nxA
)
pause

@Echo Off
SetLocal
set min=-50
set max=50
set /a i=%random%%%(max-min+1)+min
Echo:%i%
pause>nul

@echo off
Call :GetTemporaryName Name
Echo Temporary Name is %Name%
pause& exit
 
:GetTemporaryName %varName%
set sTempName=%temp%\temp%random%.tmp
if exist "%sTempName%" (goto :GetTemporaryName) else (set %1=%sTempName%)

<nul set /p a=text
<nul set /p a=text

set a=test
set b=TEST
if /i %a%==%b% echo OK

@echo off
Setlocal EnableDelayedExpansion
 
set Utext= Up case text--~@#*()_+-
Call :Case Utext U
echo %Utext%
 
set Ltext=lAW CASE TEXT--~@#*()_+-
Call :Case Ltext L
echo %Ltext%
 
pause
Goto :eof
 
:Case %1-var %2.option-L-or-U
if not Defined CaseA Call :FillSlovar
set word=!%~1!
if not Defined word Exit /B
set tempvar=
set /A n=-1
:newsymbol
set /A n+=1
set "symb=!word:~%n%,1!"
if "%symb%"=="" (Set "%~1=%tempvar%"& Exit /B)
if "!case%~2%symb%!"=="" (
  set "tempvar=%tempvar%%symb%"
) else (
  set "tempvar=%tempvar%!case%~2%symb%!"
)
goto :newsymbol
 
:FillSlovar
Set AlphabetL=abcdefghigklmnopqrstuvwxyz
Set AlphabetU=ABCDEFGHIJKLMNOPQRSTUVWXYZ
For /L %%C in (0,1,25) do (
  set caseU!AlphabetL:~%%C,1!=!AlphabetU:~%%C,1!
  set caseL!AlphabetU:~%%C,1!=!AlphabetL:~%%C,1!
)
Exit /B

@Echo Off
Setlocal EnableDelayedExpansion
Set /A num=3
::Вычисляем 3 в 4-й степени
Call :Stepping num 4
Echo %num%
pause
exit /B
 
:Stepping %1 - Переменная с числом %2 - Степень
set /A s=%2
if %s%==0 (Set /A %1=1& exit /b)
if %s%==1 exit /b
set step=%3
if not defined step set step=!%1!
set /A s-=1
set /A %1*=%step%
Call :Stepping %1 %s% %step%
exit /b

call :isin строка подстрока

setlocal enabledelayedexpansion

:strlength
set string_q12e=%~1
set counter_0121=0
:again_r0067
if "!string_q12e:~%counter_0121%,1!"=="" (set strlength_=!counter_0121!&exit /b)
set /a counter_0121=!counter_0121!+1
goto :again_r0067

call :strlength <Строка>

setlocal enabledelayedexpansion
set num=1
set param1=test
set value=!param%num%!

set num=1
set param1=test
call set value=%%param%num%%%

@echo off
set param=1
call :me "variable"
echo Value from sub=%variable%
::Проверяем изменилось ли значение переменной
echo Old value=%param% is saved !
pause
goto :eof
 
:me
setlocal
::Используем точно такое же имя переменной
set param=123
endlocal& set %~1=%param%
exit /b