Тонкости языка, редкие команды и сложные скрипты

::Получает значение последнего токена в строке, отделенного в тексте указанным разделителем
::Имеет преимущество перед другими парсерами:
:: - разделителями могут быть некоторые спецсимволы, например знак "=";
:: - количество токенов неограничено.
:GetLastToken %1-in.String %2-in.Delimiter %3-out.Last.Token.Variable
Set "%~3="
Set "_String=%~1"
Set _nLastDelim=-1
for /L %%C in (0,1,8184) do (
  if "!_String:~%%C,1!"=="" Goto ex_GetLastToken
  if "!_String:~%%C,1!"=="%~2" Set _nLastDelim=%%C
)
:ex_GetLastToken
Set /A _nLastDelim+=1
Set "%~3=!_String:~%_nLastDelim%!"
Exit /B

@echo off
set st=C:\Users\Fire\Desktop\Личный кабинет абонента.url
set "st="%st:\=" "%""
for %%a in (%st%) do set st=%%~a
echo %st%

::Удаляет справа лишние пробелы, или другие подряд идущие символы, заданные переменной %2 (Symbol)
:RTrimSpaces %1-in.String %2-in.Symbol %3-out.String.Variable
Set "%~3="
Set "_String=%~1"
for /L %%C in (0,1,8184) do (
  if "!_String:~%%C,1!"=="" Goto ex_RTrimSpaces
  if "!_String:~%%C,1!"=="%~2" (if not Defined LastSpace (Set nSpace=%%C& Set LastSpace=true)) else (Set LastSpace=& Set nSpace=)
)
:ex_RTrimSpaces
if Defined nSpace (Set "%~3=!_String:~0,%nSpace%!") else (Set "%~3=!_String!")
Exit /B

:BL.String.CreateDEL_ESC
@echo off
:: Creates two variables with one character DEL=Ascii-08 and ESC=Ascii-27
:: DEL and ESC can be used  with and without DelayedExpansion
setlocal
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%A in (1) do rem"') do (
  rem ENDLOCAL
  set "DEL=%%a"
  rem set "DEL=%DEL:~0,1%
  set "ESC=%%b"
  goto ext
)
:ext
<nul set /p test=Tes_
<nul set /p test=%DEL%
echo t

@echo off
::Первый параметр - число в десятичное системе счисления.
::Второй параметр - основание выходной системы счисления (от 2 до 16)
setlocal enabledelayedexpansion
chcp 1251>nul
set dec=%~1
if not "%~2"=="" (set osn=%~2) else (set osn=2)
if !dec! LSS 0 (set /a dec=0 - !dec!&set mn=1)
set tempr=!dec!
set bin=
set H=set HEX.
!H!10=A&!H!11=B&!H!12=C&!H!13=D&!H!14=E&!H!15=F
if !osn! GTR 16 (echo.Слишком большое основание. Максимум 16&exit /b)
if !osn! LSS 2 (echo.Слишком маленькое основание. Минимум 2&exit /b)
:again
 if !tempr! LSS 2 (goto :out)
 set /a tbin=!tempr! %% !osn!
 set /a tmchs=!tempr! - !tbin!
 set /a tempr=!tmchs! / !osn!
 if !tbin! GEQ 10 (set tbin=!HEX.%tbin%!)
 set bin=!tbin!!bin!
goto :again
:out
if "!bin!"=="" (set bin=0)
if not !tempr!==0 (set bin=!tempr!!bin!)
if "!mn!"=="1" (set bin=-!bin!)
echo.!bin!
endlocal&exit /b

:ReadTo
for /f "usebackq tokens=*" %%A IN (`find /C /V ""^<"%~1"`) DO (set %~3=%%A)
(for /L %%A IN (1,1,!%~3!) DO (set %~2.%%A=&set /p %~2.%%A=))<"%~1"
exit /b

Call :ReadTo <имя файла> <имя псевдомассива> <имя переменной с количеством строк>

@echo off
setlocal enabledelayedexpansion
(echo.1
echo.2
echo.
echo.
echo.""
echo.x)>file.txt
call :ReadTo file.txt string counter
for /L %%A IN (1,1,%counter%) DO (echo.!string.%%A!)
pause>nul
exit /b
 
:ReadTo
for /f "usebackq tokens=*" %%A IN (`find /C /V ""^<"%~1"`) DO (set %~3=%%A)
(for /L %%A IN (1,1,!%~3!) DO (set %~2.%%A=&set /p %~2.%%A=))<"%~1"
exit /b

(for /L %%A IN (1,1,!%~3!) DO set /p %~2.%%A=)<"%~1"

:split
:: Попарное получение токенов из строки. Номера токенов задаются параметром № 2.
:: %1 - вх. строка
:: %2 - вх. номера токенов
:: %3 - вых.переменная, для хранения 1-го значения
:: %4 - вых.переменная, для хранения 2-го значения
  set "%~3="& set "%~4="
  set g=for /f "tokens=%~2" %%a in ^("%~1"^) do set "%~3=%%a"^& set "%~4=%%b"
  %g%
exit /b

@echo off
::задаем строку 
set st=один два три четыре пять
::получаем 2-е и 3-е слово
call :split "%st%" "2,3" "first" "second"
::выводим на экран
echo Первое слово: %first%
echo Второе слово: %second%
pause& goto :eof

@echo off
SetLocal EnableExtensions
Call :Logica -2147483648 2147483648 LSS && echo false || echo true
echo errorlevel = %errorlevel%
<nul set /p x=Результат сравнения: 
if "%errorlevel%"=="0" (echo false)
if "%errorlevel%"=="1" (echo true)
if "%errorlevel%"=="2" (echo error)
pause
goto :eof

:Logica
:: Логические операции сравнения для чисел, превышающих арифметику CMD
:: Возвращает Errorlevel 1, если true, или 0, если false, 2, если неверно введен параметр
:: %1 - 1-е число
:: %2 - 2-е число
:: %3 - Логическая операция.
:: Допустимые операции:
:: LSS - меньше
:: lEQ - меньше или равно
:: GTR - больше
:: GEQ - больше или равно
  set operation=%~3
  set numb1=%~1
  set numb2=%~2
  ::Удаляем знаки +
  if "%numb1:~0,1%"=="+" set numb1=%numb1:~1%
  if "%numb2:~0,1%"=="+" set numb2=%numb2:~1%
  ::Проверка на равенство
  if "%numb1%"=="%numb2%" (
    if /i "%operation%"=="lEQ" exit /B 1
    if /i "%operation%"=="GEQ" exit /B 1
    if /i "%operation%"=="lSS" exit /B 0
    if /i "%operation%"=="GTR" exit /B 0
  )
  if /i "%operation%"=="lEQ" set operation=LSS
  if /i "%operation%"=="GEQ" set operation=GTR
  ::Если сравниваются отрицательные числа, нужно в конце переворачивать логику
  set inverse=
  if "%numb1:~0,1%"=="-" if "%numb2:~0,1%"=="-" set inverse=true
  ::Проверка на знак
  if "%numb1:~0,1%"=="-" if "%numb2:~0,1%" NEQ "-" (set mean=LSS& goto :ext_Logica)
  if "%numb2:~0,1%"=="-" if "%numb1:~0,1%" NEQ "-" (set mean=GTR& goto :ext_Logica)
  ::Удаляем знаки -
  if "%numb1:~0,1%"=="-" set numb1=%numb1:~1%
  if "%numb2:~0,1%"=="-" set numb2=%numb2:~1%
  :s_Logica
    ::Берем цифры по одному разряду справа
    if "%numb1%"=="" (set r1=) else (set r1=%numb1:~-1%)
    if "%numb2%"=="" (set r2=) else (set r2=%numb2:~-1%)
    if "%r1%"=="" if "%r2%"=="" goto ext_Logica
    if "%r1%"=="" set r1=0
    if "%r2%"=="" set r2=0
    if %r1% NEQ %r2% if %r1% GTR %r2% (set mean=GTR) else (set mean=LSS)
    if "%numb1%" neq "" set numb1=%numb1:~0,-1%
    if "%numb2%" neq "" set numb2=%numb2:~0,-1%
  goto s_Logica
  :ext_Logica
  if defined inverse if "%mean%"=="GTR" (set mean=LSS) else (set mean=GTR)
  if "%operation%"=="GTR" if "%mean%"=="GTR" (exit /B 1) else (exit /B 0)
  if "%operation%"=="LSS" if "%mean%"=="LSS" (exit /B 1) else (exit /B 0)
exit /B 2

:Reg_Write
  :: %1-вх.Ключ
  :: %2-вх.Имя параметра
  :: %3-вх.Тип параметра { REG_SZ, REG_BINARY, REG_DWORD, REG_QWORD, REG_MULTI_SZ, REG_EXPAND_SZ }
  :: %4-вх.Значение
  reg.exe add "%~1" /v "%~2" /t "%~3" /d "%~4" /f
Exit /B %errorlevel%

:Reg_Read
  :: %1-вх.Ключ
  :: %2-вх.Имя параметра
  :: %3-исх.Переменная для хранения значения
  :: %4-исх.(опционально)-Переменная для хранения типа параметра
  set "%~3="& if "%~4" neq "" set "%~4="
  For /f "tokens=2*" %%a In ('Reg.exe query "%~1" /v "%~2"') do (
    set "%~3=%%~b"& if "%~4" neq "" set "%~4=%%~a"
  )
Exit /B

:Reg_Read
  :: %1-вх.Ключ
  :: %2-вх.Имя параметра
  :: %3-исх.Переменная для хранения значения
  :: %4-исх.(опционально)-Переменная для хранения типа параметра
  set "%~3="& if "%~4" neq "" set "%~4="
  For /f "tokens=1-2*" %%a In ('cmd /e:ON /v:ON /c "Reg.exe query "%~1" /v "%~2"^& echo ^!errorlevel^! err %~2"') do (
    if "%%b"=="err" (set err=%%a) else (set "%~3=%%~c"& if "%~4" neq "" set "%~4=%%~b")
  )
Exit /B %err%

set test=%1 
set test=%test:&=^&% 
echo %test:~1,-1%

@echo off
::Путь к запускаемому бату в роле службы
set src=d:\bat.bat
 
sc create My_Service binPath= %windir%\SysWOW64\srvany.exe DisplayName= "My Service"
reg add "HKLM\SYSTEM\CurrentControlSet\Services\My_Service\Parameters" /f /v Application /t REG_SZ /d "%src%"
net start "My_Service"
pause

@echo off
net stop "My_Service"
sc delete "My_Service"
pause

@echo off
echo %date% %time% > c:\autoexnt.log
set >> c:\autoexnt.log
net stop AutoExNT > nul
exit

<test.txt (
  for /l %%i in (1 1 4) do set /p "="
  set /p "st="
)
for /f "tokens=1* delims==" %%i in ("%st%") do set "st=%%j"

copy/b nul >> FILE.EXT+,,