Форум программистов, компьютерный форум, киберфорум
Наши страницы
Batch (CMD/BAT)
Войти
Регистрация
Восстановить пароль
 
 
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
#1

Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора* - CMD/BAT

10.01.2013, 15:41. Просмотров 60442. Ответов 106

Эта тема - ответвление Тонкости языка, редкие команды и сложные скрипты

Постим сюда детали, которые Вы получили опытным путем.
Которые считаете уникальными, или могут быть полезными при наборе кода BAT файлов, лучшего понимания принципов работы среды командной строки.
Пишем ошибки, которые иногда допускаете, а потом ломаете голову, почему не работает

Писать можно много и часто, даже если это мелочь. Все соберем вместе. Весомые замечания перенесем в указанную выше тему.

Собрано по категориям:

Файловые операции
5) Использование рабочего каталога Bat файла в роле начального для выполнения команд в нем на ОС >= Vista ссылка
8) Как проверить - существует ли папка ссылка
10) Не использовать && после команды Del. ссылка
12) После перехода в другой каталог проверять успех операции ссылка
18) Листинг текущего каталога или корневого ссылка
24) Работа с файлами/папками, в именах которых есть буквы украинского алфавита. ссылка

Символы
1) Экранирование спецсимвола ссылка
13) Сохранение концевого пробела в переменную ссылка
17) Запятая и точка с запятой - разделители аргументов ссылка
30) Экранирование номера потока в перенаправлении вывода Echo ссылка

Переменные
2) Использование одноименных переменных без обнуления ссылка
3) Пренебрежение Setlocal ссылка
3.1) Не указав Setlocal EnableDelayedExpansion, используем знаки восклицания (!) для раскрытия значения переменных ссылка
6) Инициализация числового типа данных ссылка
14) Обход ошибки "Режим вывода команд на экран (ECHO) включен" ссылка
16) Пробелы тоже могут являться частью названия переменной ссылка
23) Для команды SET всегда заключайте в кавычки переменную и значение, если ним является изменяемое имя файла ссылка
28) Двойное раскрытие переменной. Первыми раскрываются проценты. ссылка
29) Конструкция вида Echo.!Var:~0,1! не работает. ссылка

Циклы
7) EOL в цикле FOR - правильный порядок модификаторов ссылка
9) Использовать UseBackQ при чтении содержимого файла, имя которого может меняться ссылка
25) Получение даты и времени файла через цикл и команду For без ключа /S (рекурсия) и подпрограммы ссылка

Кодировка
4) Сохранение BAT-файла с кодировкой перевода строк в UNIX-стандарте ссылка
26) Кодировка в консоли ссылка
27) Текстовой файл не читается циклом по неизвестной причине ссылка

Тесты, оптимизация и граничные возможности интерпретатора
15) Граничные значения для числового типа в CMD ссылка
19) Максимальная глубина рекурсии = 593*. ссылка
20) Максимальная длина значения строки ссылка
21) Оптимизация кода ссылка
22) Тест замедления работы операторов при перегрузке оперативной памяти ссылка

Другое
1) Указывая метку подпрограммы, можно через пробел указывать ее описание. Среда не будет "ругаться" ссылка
11) Внимательно выбирайте имя для BAT(CMD)-файла ссылка
0
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
10.01.2013, 15:41
Я подобрал для вас темы с готовыми решениями и ответами на вопрос Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора* (CMD/BAT):

Ошибки при запуске bat-файлов
У меня проблема, что при запуске cmd.exe, что при запуске любого *.bat-файла, появляется такое же сообщение "c:/programПрограмма не...

Последовательный запуск нескольких BAT-файлов из основного BAT-файла
Доброго времени суток всем... Помогите кто понимает.. Есть bat... @echo off start "" "D:\$\Pale Moon\1\Palemoon-Portable"...

Запуск bat-файлов с параметрами, являющимися модификациями принятого запускающим bat-файлом параметра
Написать командный файл, который: • принимает в качестве параметра полное имя файла (диск+каталог+имя) • вызывает файл 1.bat, передавая...

Как определить количество цветов в подгружаемом рисунке и наиболее частые цвета
Заранее благодарен...

Ошибки при создании заметки
Пару дней назад установил Друпал на Xampp, частенько на разных страницах пришет не большие "user warning" но при этом не отказывался...

Частые ошибки
Есть проблема и уверен что системная, а не программная. Проблема в том что во время установки программ, они устанавливаются не правильно,...

106
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
04.02.2013, 00:55  [ТС] #21
Заметки
26) Кодировка в консоли
По-умолчанию, текстовые файлы в Windows создаются в Win-кодировке (кодовая страница 1251).
При этом сама консоль работает в кодировке DOS (CP-866).

Когда в консоль попадает такой текст, он отображается некорректно.
1) Команда:
Bash
chcp 1251>nul
приводит консоль к той же кодовой странице, что и текст из файла и т.о. мы видим нормальный русский текст,
а не т.н. "крякозябры".
>nul - чтобы не выводилось сообщение от самой команды.

2) Альтернативой является сохранение самого текста (текстового файла) уже в кодировке, с которой по-умолчанию работает консоль (CP-866). Но такого функционала у встроенного блокнота Windows нет. И нужно использовать другие текстовые редакторы: Русский текст в консоли

Недостатком 1-го способа является то, что сообщения от всех системных команд написаны в кодировке CP-866.
И если воспользоваться командой chcp 1251, мы получим "крякозябры" уже от встроенных команд.

Английский язык отображается одинаково в обеих кодировках.
1
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
11.03.2013, 02:23  [ТС] #22
Application Crash консоли

Bash
1
(for %%A in () do echo %%A) | Rem
2
Badger
91 / 91 / 4
Регистрация: 25.06.2012
Сообщений: 278
11.03.2013, 02:47 #23
Цитата Сообщение от Dragokas Посмотреть сообщение
(for %%A in () do echo %%A) | Rem
Хз... А что должно было произойти?)
0
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
11.03.2013, 03:01  [ТС] #24
Это я уже сократил - было %* как в этом примере Список всех файлов в каталогах, пути к которым указаны в параметрах
строка № 5.

Цитата Сообщение от Badger Посмотреть сообщение
А что должно было произойти?)
Например, сообщение о критической ошибке, как всегда. У меня в Win 7x64 консоль вообще вылетает. Интересно, в XP тоже самое?
0
Миниатюры
Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*  
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
12.03.2013, 03:48  [ТС] #25
27) Текстовой файл не читается циклом
(словно он пустой)

Проверьте, что файл создан не в Unicode кодировке.
Для перекодировки существует утилита win_iconv
0
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
19.03.2013, 02:27  [ТС] #26
28) Двойное раскрытие переменной. Первыми раскрываются проценты.

И такое иногда забывается:
Правильно:
Bash
echo !param.%n%!
Неправильно:
Bash
echo %param.!n!%
Полный пример кода. (Цель - урезать строку на кол-во символов, заданное другой переменной):

Bash
1
2
3
4
5
6
7
8
9
10
@echo off
SetLocal EnableDelayedExpansion
set stroka=Азъ есмь царь
::урезать слева
set ns=4
::урезать справа
set ne=5
 
Echo !stroka:~%ns%,-%ne%!
pause>nul
0
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
22.03.2013, 03:12  [ТС] #27
29) Конструкция вида Echo.!Var:~0,1! не работает.
Баг (наверное)

Демонстрация ошибки:

Bash
1
2
3
4
5
@echo off
Setlocal EnableDelayedExpansion
 
Set Var=12345
Echo.!Var:~0,1!
Способ обхода ошибки (добавляем пробел):

Bash
1
2
3
4
5
@echo off
Setlocal EnableDelayedExpansion
 
Set Var=12345
Echo. !Var:~0,1!
Интересно, что такой формат работает правильно (видимо CMD что-то не нравится в запятой):
Bash
1
2
3
4
5
@echo off
Setlocal EnableDelayedExpansion
 
Set Var=12345
Echo.!Var:~1!
1
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
10.05.2013, 02:03  [ТС] #28
Баги:

И все таки баг такой?
Записать список всех файлов из каталога К, имена которых заканчиваются на цифру, в файл F

Добавлено через 1 минуту
Надо найти время сосчитать, сколько там скобок внутри файла для FindStr критично:
Меню с запуском программ
0
gimntut
879 / 182 / 15
Регистрация: 18.07.2011
Сообщений: 257
13.05.2013, 21:34 #29
Цитата Сообщение от Dragokas Посмотреть сообщение
И все таки баг такой?
Dragokas, ты забыл про формат 8.3
Достаточно было выполнить
Bash
1
dir /x
и всё встало бы на свои места.
0
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
25.06.2013, 22:10  [ТС] #30
Перенаправление вывода цикла в файл без дозаписи

Недавно видел у FraidZZ.
Очень полезная штука, когда хочешь сделать запись в файл всего накопленного буфера сразу.
Причем, если файл уже существует, он будет стерт.

Bash
1
2
3
4
5
6
7
8
9
10
11
12
@echo off
:: Выведет в файл последнюю итерацию
for /L %%C in (1,1,5) do (
  echo %%C
) > file1.txt
 
:: Выведет в файл все итерации
(
  for /L %%C in (1,1,5) do (
    echo %%C
  )
) > file2.txt
4
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
26.06.2013, 08:58  [ТС] #31
В ходе неудачного эксперимента по превращению конвеерного потока в файловый:
Получил - не знаю зачем это может понадобится:

Диагностический режим цикла, при котором все изменения внутри него не сохраняются: переменным на самом деле не присваиваются значения, но каждая итерация цикла выводится на экран.

Bash
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
@echo off
SetLocal EnableExtensions EnableDelayedExpansion
set before=10
(
  for /L %%C in (1,1,1) do (
    echo %before%
    set d=15
    set n=%%C& set after=%d%& set after=!d!
    echo !n!
    echo !after!
  )
) 1>&2 | set x=
echo ----------
echo %n%
echo %after%
pause
UPD. Объяснение этого процесса: Экранирование номера потока в перенаправлении вывода ECHO
1
Миниатюры
Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*  
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
02.07.2013, 08:03  [ТС] #32
Различия Start.exe и Start: BAT-файл для открытия ссылки в браузере
0
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
14.07.2013, 21:10  [ТС] #33
Скобки в математических операциях

Скобки в качестве приоритета для математических операций могут быть указаны просто так:

Bash
1
set /a i=%random%%%(max-min+1)+min
Но, если они находятся под другими скобками, следует обязательно их экранировать:

Bash
1
2
3
4
for /L %%C in (1,1,%n%) do (
  set /a i=!random!%%^(max-min+1^)+min
  <nul set /p "x=!i! ">> "%file%"
)
4
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
16.07.2013, 01:40  [ТС] #34
Заключайте под дополнительные общие кавычки команду, выполняемую циклом, если она состоит из более чем 1 парной кавычки.

Иначе можем получить такие сообщения:
  • ... не является внутренней или внешней командой, исполняемой программой или пакетным файлом.
  • Синтаксическая ошибка в имени файла или папки

Пример:

Bash
for /f %%a in ('"%~dp0fsum.exe" -md5 -d"%windir%\system32" "notepad.exe"') do echo Cheksum: -----%%a------
выдаст ошибку.

Добавляем внешние парные кавычки:
for /f %%a in ('""%~dp0fsum.exe" -md5 -d"%windir%\system32" "notepad.exe""') do echo Cheksum: -----%%a------

Это согласуется с правилами, описанными в синтаксисе CMD /?, так как команда цикла выполняется именно под CMD /C
(в этом можно убедится открыв список процессов, и наблюдая еще +1 CMD.exe при входе в цикл).
6
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
17.07.2013, 17:20  [ТС] #35
Кодовые страницы, поддерживаемые CMD.

Интересная инфа из поста за авторством Ris
Цитата Сообщение от Ris
P.S. Методом научного тыка
Bash
@for /l %%i in (1,1,65001) do @chcp %%i > nul 2>nul&&echo %%i >> chcp.txt
)
определил что CMD поддерживает следующие кодировки:
Кликните здесь для просмотра всего текста
Код
37 
437 
500 
708 
720 
737 
775 
850 
852 
855 
857 
858 
860 
861 
862 
863 
864 
865 
866 
869 
870 
874 
875 
1026 
1047 
1140 
1141 
1142 
1143 
1144 
1145 
1146 
1147 
1148 
1149 
1250 
1251 
1252 
1253 
1254 
1255 
1256 
1257 
1258 
1361 
10000 
10001 
10002 
10003 
10004 
10005 
10006 
10007 
10008 
10010 
10017 
10021 
10029 
10079 
10081 
10082 
20000 
20001 
20002 
20003 
20004 
20005 
20105 
20106 
20107 
20108 
20127 
20261 
20269 
20273 
20277 
20278 
20280 
20284 
20285 
20290 
20297 
20420 
20423 
20424 
20833 
20838 
20866 
20871 
20880 
20905 
20924 
20932 
20936 
20949 
21025 
21027 
21866 
28591 
28592 
28593 
28594 
28595 
28596 
28597 
28598 
28599 
28603 
28605 
38598 
50220 
50221 
50222 
50225 
50227 
50229 
51949 
52936 
54936 
55000 
55001 
55002 
55003 
55004 
57002 
57003 
57004 
57005 
57006 
57007 
57008 
57009 
57010 
57011 
65000 
65001
2
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
24.07.2013, 02:46  [ТС] #36
К заметке о предельных возможностях командной строки:
  • 1. Максимальная длина аргумента
  • 2. Максимальное количество аргументов

Условия теста1: передача 1-го длинного аргумента из языка VBScript, используя объект WScript.Shell и метод Exec.
Возврат обратно. Сравнение длинны переданной и полученной строки.
Условия теста2: передача множества аргументов длинной в 1 символ...

Результаты теста1:
Максимальная длина аргумента = 8150.

Результаты теста2:
Макс. кол-во аргументов = 4075
4075 * 2 = 8150 (4075 аргументов + 4075 пробелов между ними).

Возможная погрешность теста:
Узкими местами могут быть:
1) ограниченность метода Exec.
2) ограниченность команды Echo.
3) ограничения, накладываемые на интерпретатор CMD
...

Код эксперимента

MaxArgTest.cmd
Bash
1
@echo %*
SendArgMaxLen.vbs

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
'Определение максимальной длины передаваемого аргумента методом эксперимента (подбор половинным делением)
option explicit
 
Const CriticalMAX = 10000
 
dim Home, oStream, Str, nCheck, curMAX, curMIN, nOK
 
Home = WScript.ScriptFullName
Home = left(Home, instrrev(Home, "\") - 1)
 
nCheck = CriticalMAX
curMAX = CriticalMAX
curMIN = 0
 
Do
 
  set oStream = Createobject("WScript.Shell").Exec(Home & "\MaxArgTest.cmd " & string(nCheck, "A"))
  Str = oStream.StdOut.ReadAll()
  set oStream = Nothing
 
  if len(Str) - 2 <> nCheck Then ' - 2 'CrLf
    curMAX = nCheck - 1
  else
    nOK = nCheck
    curMIN = nCheck + 1
  end if
 
  nCheck = (curMAX - curMIN) \ 2 + curMIN
 
  msgbox "MIN = " & cstr(curMIN) & "   " & "MAX = " & cstr(curMAX) & "    " & "Len of String = " & cstr(len(Str)) & _
vbcrlf & "Now Checking " & cstr(nCheck)
 
Loop until curMIN >= curMAX
 
msgbox "MAX possible is " & cstr(nOK)


SendArgMaxCount.vbs
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
'Определение максимального количества аргументов методом эксперимента (подбор половинным делением)
option explicit
 
Const CriticalMAX = 10000
 
dim Home, oStream, Str, nCheck, curMAX, curMIN, nOK
 
Home = WScript.ScriptFullName
Home = left(Home, instrrev(Home, "\") - 1)
 
nCheck = CriticalMAX
curMAX = CriticalMAX
curMIN = 0
 
Do
 
  set oStream = Createobject("WScript.Shell").Exec(Home & "\MaxArgTest.cmd" & replace(string(nCheck, "A"), "A", " A"))
  Str = oStream.StdOut.ReadAll()
  set oStream = Nothing
 
  if len(Str) - (nCheck - 1) - 2 <> nCheck Then ' - (nCheck - 1) ' кол-во пробелов между аргументами ' - 2 'CrLf
    curMAX = nCheck - 1
  else
    nOK = nCheck
    curMIN = nCheck + 1
  end if
 
  nCheck = (curMAX - curMIN) \ 2 + curMIN
 
  msgbox "MIN = " & cstr(curMIN) & "   " & "MAX = " & cstr(curMAX) & "    " & "Len of String = " & cstr(len(Str)) & _
vbcrlf & "Now Checking " & cstr(nCheck)
 
Loop until curMIN >= curMAX
 
msgbox "MAX possible is " & cstr(nOK)
1
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
11.08.2013, 02:08  [ТС] #37
Когда нужны дополнительные @echo off и знаки @

Экранирование номера потока в перенаправлении вывода ECHO

Также, если мы вручную запускаем консоль,
иногда весьма удобно пользоваться @echo off, когда текущий каталог имеет очень длинное имя:

Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*

Теперь вариант, когда мы не пишем @echo off, но используем @.
Оцените компактность 2-го варианта:

Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*
1
MihaniX
135 / 45 / 2
Регистрация: 06.08.2013
Сообщений: 292
Записей в блоге: 4
11.08.2013, 19:01 #38
Что это?
Почему-то когда я набираю start cscript.exe вылезает консоль с нормальным текстом.
0
Миниатюры
Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*   Наиболее частые ошибки, заметки особенностей программинга BAT файлов, баги интерпретатора*  
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
11.08.2013, 21:35  [ТС] #39
Это проблемы с кодировкой в Вашей системе. Похоже повреждены записи в реестре.

Вот сделал скрипт восстановления кодировок.
Заменяются реестровые записи:
HKCU\Control Panel\International
HKLM\SYSTEM\CurrentControlSet\Control\Nls\CodePage
и файлы *.NLS в Windows\System32

Резервное копирование Ваших исходных веток реестров и файлов включено в скрипт. Можно не бояться.
(совместимость - Windows 7 x32 и x64). Возможно Windows Vista (надо проверить).

В конце - перезагрузите систему.

UPD. Забыл, что у NLS-файлов особые права. Прикручу эту фишку - Восстановление шрифтов после сбоя, и добавлю команду восстановления прав по таблице ACL. Тогда выложу скрипт целиком.

Готово: Полезные BAT/CMD скрипты
________________________________________________________________________

Upd. 07.07.2014

На самом деле это из-за поврежденного или отсутствующего файла справки к cscript.exe
Он должен называться cscript.exe.mui и находится, например для русской локализации системы, здесь: %SystemRoot%\System32\ru-RU\
2
Dragokas
Эксперт WindowsАвтор FAQ
16922 / 7007 / 851
Регистрация: 25.12.2011
Сообщений: 10,803
Записей в блоге: 16
04.10.2013, 02:00  [ТС] #40
Исправление проблемы, когда не работает вывод коротких имен файлов Dir /X
Источник: techguy.org

Режим представления коротких имен файлов может быть отключен.
Проверить это можно, введя команду:
Bash
fsutil behavior query disable8dot3

Чтобы снова включить этот режим, введите:

1) для XP:
Bash
fsutil behavior set disable8dot3 0

2) для Vista и выше:
Bash
fsutil behavior set disable8dot3 2

Напомню, что данный режим отображает альтернативные имена в формате 8.3 и будет удобен,
когда требуется работать с именами файлов и папок, имеющих:
Для автоматической подстановки и парсинга имен в формате 8.3. можно воспользоваться такой циклической конструкцией:

Bash
for /f "skip=5 tokens=4" %%? in ('dir /X /-C /A-D "c:\users\alex\desktop\*"') do echo %%?
Учитывайте, что эта команда выводит в конце 2 лишних строки.
Для их фильтрации придется усложнить математику:

Bash
1
2
3
4
5
@echo off
SetLocal EnableDelayedExpansion
set dir_com=dir /X /-C /A-D "c:\users\alex\desktop\*"
for /F %%? in ('%dir_com%^| find /C /V ""') do set Total=%%?& Set /A Total-=7&:: 7 = skip+2
for /F "skip=5 tokens=4" %%? in ('%dir_com%') do Set /A C+=1& if !C! LEQ %Total% echo %%?
2
04.10.2013, 02:00
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
04.10.2013, 02:00
Привет! Вот еще темы с решениями:

Частые ошибки winapi
Подскажите, что я делаю не так. Программа запускается без ошибок, но кнопку, которую я создаю, не видно, не видно иконку и изображение,...

Частые ошибки в работе компьютера
Доброго времени суток. Перейду сразу к делу: После включения компьютера никакая программа не работает более 5-10 минут. Сразу закрывается...

Частые BSOD и разные ошибки
Здравствуйте, помогите с проблемой: уже на протяжении где-то 2 месяцев постоянно выпадает BSOD (раньше никогда такого не было), ошибки в...

Частые системные ошибки windows 8
Что то уж слишком часто начали появляться системные ошибки, почти все разные, ноут HP ENVY M6, ему всего 2 месяца. Подскажите в чем может...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
40
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru