Поочередный запуск cmd файлов в Delphi

ShellExecute(Handle, 'open', PChar('Adobe_reader\silent.cmd'), nil, nil, SW_Hide); 
ShellExecute(Handle, 'open', PChar('ccleaner\silent.cmd'), nil, nil, SW_Hide);

// запуск внешней программы и ожидание ее завершения, если Hide = True, то ConsoleOutput заполняется косольным выводом программы
function StartAndWait(const CmdLine, WorkFolder: string; const TimeOut: Cardinal; const Hide: Boolean; out ExitCode: Cardinal; out ConsoleOutput: AnsiString): Integer;
var
  si: TStartupInfo;
  pi: TProcessInformation;
  hReadOut, hWriteOut, hReadIn, hWriteIn: THandle;
  sa: TSecurityAttributes;
  Buff: array[Byte] of AnsiChar;
  Avail, tc: Cardinal;
  Readed: Integer;
begin
  ZeroMemory(@si, SizeOf(si));
  si.cb:= SizeOf(si);
  si.dwFlags:= STARTF_USESHOWWINDOW;
  if Hide then
    begin
      ZeroMemory(@sa, SizeOf(sa));
      sa.nLength:= SizeOf(sa);
      sa.bInheritHandle:= True;
      sa.lpSecurityDescriptor:= nil;
      CreatePipe(hReadOut, hWriteOut, @sa, 0);
      CreatePipe(hReadIn, hWriteIn, @sa, 0);
 
      si.wShowWindow:= SW_HIDE;
      si.dwFlags:= si.dwFlags or STARTF_USESTDHANDLES;
      si.hStdInput:= hReadIn;
      si.hStdOutput:= hWriteOut;
      si.hStdError:= hWriteOut;
    end
  else
    si.wShowWindow:= SW_SHOW;
 
  if CreateProcess(nil, PChar(GetEnvironmentVariable('COMSPEC')+' /C '+CmdLine), nil, nil, True, 0, nil, IIf(WorkFolder <> '', PChar(WorkFolder), nil), si, pi) then
    begin
      ConsoleOutput:= '';
      tc:= GetTickCount+TimeOut;
      repeat
        Sleep(100);
        if Hide then
          while PeekNamedPipe(hReadOut, nil, 0, nil, @Avail, nil) and (Avail > 0) do
            begin
              Readed:= FileRead(hReadOut, Buff, Min(Avail, SizeOf(Buff)-1));
              Buff[Readed]:= #0;
              ConsoleOutput:= ConsoleOutput+AnsiString(Buff);
            end;
      until (not GetExitCodeProcess(pi.hProcess, ExitCode)) or
            (ExitCode <> STILL_ACTIVE) or
            ((TimeOut > 0) and (GetTickCount > tc));
 
      if ExitCode = STILL_ACTIVE then
        if TerminateProcess(pi.hProcess, 0) then
          Result:= 1 // Timeout expired
        else
          Result:= 2 // Timeout expired, not killed
      else
        Result:= 0; // OK
 
      CloseHandle(pi.hThread);
      CloseHandle(pi.hProcess);
    end
  else
    Result:= -1; // Execute error
 
  if Hide then
    begin
      CloseHandle(hReadOut);
      CloseHandle(hWriteOut);
      CloseHandle(hReadIn);
      CloseHandle(hWriteIn);
    end;
end;

function IIf(const Expression: Boolean; const IfTrue, IfFalse: Pointer): Pointer;
begin
  if Expression then
    Result:= IfTrue
  else
    Result:= IfFalse;
end;
 
function Min(const Val1, Val2: Cardinal): Cardinal;
begin
  if Val1 < Val2 then
    Result := Val1
  else
    Result := Val2;
end;

ShellExecuteEx(Handle, 'open', PChar('Adobe_reader\silent.cmd'), nil, nil, SW_Hide);

procedure TForm1.Button1Click(Sender: TObject);
var
  ShExecInfo: SHELLEXECUTEINFO;
begin
  ZeroMemory(@ShExecInfo, SizeOf(SHELLEXECUTEINFO));
  with ShExecInfo do
  begin
    cbSize := SizeOf(SHELLEXECUTEINFO);
    fMask := SEE_MASK_NOCLOSEPROCESS;
    lpFile := 'D:\silent.cmd';
    nShow := SW_SHOW;
  end;
  ShellExecuteEx(@ShExecInfo);
  WaitForSingleObject(ShExecInfo.hProcess, INFINITE);
  ShowMessage('Готово!');
end;