Нужно заменить значения в 16-ричном коде

procedure TForm1.Button1Click(Sender: TObject);
var
  f: file of byte;
  b: byte;
begin
  memo1.Clear;
  assignfile(f, 'D:\1.bmp');
  reset(f);
  while (not EOF(f)) do
  begin
    read(f, b);
    memo1.Text:=memo1.Text+inttohex(b, 2)+' ';
  end;
  closefile(f);

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, Classes;
var ST: TStream;
    FName: String;
    Str: String;
    Str2: String;
    c: Char;
begin
  FName := 'C:\123.dat';
  ST := TFileStream.Create(FName, fmCreate);
 
  Str := 'Hello world';
  // пишем сперва в файл что-то, я выбрал строку...
  ST.WriteBuffer(Pointer(Str)^, Length(Str) * SizeOf(Str[1]));
//----------------------------------------------------------------
  // сдвигаемся вначало, и читаем оттуда
  ST.Position := 0;
  SetLength(Str2, Length(Str));
  ST.ReadBuffer(Pointer(Str2)^, Length(Str2) * SizeOf(Str2[1]));
 
  Writeln(Str2);
 
  // сдвигаемся в 3 "позицию" и пишем туда X,
  //конечно позиция додна быть годной, я тут никаких проверок по этому поводу не делал..
  ST.Position := SizeOf(Char) * 3;
  c := 'X';
  ST.WriteBuffer(c, SizeOf(Char));
//----------------------------------------------------------------
  // сдвигаемся вначало, и читаем оттуда
  ST.Position := 0;
  SetLength(Str2, Length(Str));
  ST.ReadBuffer(Pointer(Str2)^, Length(Str2) * SizeOf(Str2[1]));
 
  Writeln(Str2);
 
  ST.Position := SizeOf(Char) * 6;
  c := 'Y';
  ST.WriteBuffer(c, SizeOf(Char));
//----------------------------------------------------------------
  // сдвигаемся вначало, и читаем оттуда
  ST.Position := 0;
  SetLength(Str2, Length(Str));
  ST.ReadBuffer(Pointer(Str2)^, Length(Str2) * SizeOf(Str2[1]));
 
  Writeln(Str2);
 
  ST.Free;
  Readln;
end.

//Запись в файл нескольких смежных байт по заданному смещению.
//С использованием процедуры BlockWrite().
procedure TForm1.Button1Click(Sender: TObject);
var
  F : File;
  FileName : String;
  Arr : array of Byte;
begin
  //Выделяем память для массива.
  SetLength(Arr, 5);
  //Записываем в массив значения байтов.
  Arr[0] := $41;
  Arr[1] := $42;
  Arr[2] := $43;
  Arr[3] := $44;
  Arr[4] := $45;
 
  //Путь к файлу, который надо обработать.
  FileName := ExtractFilePath(ParamStr(0)) + 'file.dat';
  //Связываем файловую переменную с именем файла.
  AssignFile(F, FileName);
  //Открываем файл в режиме чтение/запись. При этом задаём размер наименьшего
  //блока доступа равным 1-му байту.
  Reset(F, 1);
  try
    //Проверяем - достаточный ли размер файла. Размер файла выражается в количестве
    //наименьших блоков доступа. Мы открывали файл с наименьшим блоком доступа = 1 байт,
    //поэтому получим размер файла в байтах.
    if FileSize(F) < 9 + Length(Arr) then
    begin
      ShowMessage('Внимание! Размер файла недостаточный. Действие отменено.');
      Exit; //При этом управление сначала перейдёт в раздел finally - end.
    end;
    //Переходим по смещению = 9.
    Seek(F, 9);
    //Начиная с текущей позиции, записываем в файл содержимое массива.
    BlockWrite(F, Arr[0], Length(Arr));
  finally
    CloseFile(F); //Закрываем файл.
  end;
end;

//Запись в файл нескольких смежных байт по заданному смещению.
//С использованием файлового потока типа TFileStream.
procedure TForm1.Button1Click(Sender: TObject);
var
  Fs : TFileStream;
  FileName : String;
  Arr : array of Byte;
begin
  //Выделяем память для массива.
  SetLength(Arr, 5);
  //Записываем в массив значения байтов.
  Arr[0] := $41;
  Arr[1] := $42;
  Arr[2] := $43;
  Arr[3] := $44;
  Arr[4] := $45;
 
  //Путь к файлу, который надо обработать.
  FileName := ExtractFilePath(ParamStr(0)) + 'file.dat';
  //Создаём экземпляр файлового потока и открываем файл в режиме записи (fmOpenWrite)
  //с запретом на запись другим процессам (fmShareDenyWrite). Если надо открыть
  //файл в режиме чтение/запись, то следует использовать константу fmOpenReadWrite.
  Fs := TFileStream.Create(FileName, fmOpenWrite + fmShareDenyWrite);
  try
    //Проверяем - достаточный ли размер файла.
    if Fs.Size < 9 + Length(Arr) then
    begin
      ShowMessage('Внимание! Размер файла недостаточный. Действие отменено.');
      Exit; //При этом управление сначала перейдёт в раздел finally - end.
    end;
    //Переходим по смещению = 9.
    Fs.Position := 9;
    //Начиная с текущей позиции, записываем в файловый поток содержимое массива.
    Fs.Write(Arr[0], Length(Arr));
  finally
    FreeAndNil(Fs); //Уничтожаем экземпляр потока и закрываем файл.
  end;
end;

//Поиск первого вхождения и замена данных в файле. Для файлов, которые можно полностью загрузить в память.
procedure TForm1.Button1Click(Sender: TObject);
var
  Fs : TFileStream;
  FileName : String;
  Sf, Sr, SBuff : AnsiString; //AnsiString - тип, описывающий строку однобайтных символов.
  Offs : Int64;
begin
  Sf := #$56#$57#$58#$59#$5A; //= 'VWXYZ'. //Последовательность искомых байт.
  Sr := #$41#$42#$43#$44#$45; //= 'ABCDE'. //Последовательность заменяющих байт.
 
  FileName := ExtractFilePath(ParamStr(0)) + 'file.dat'; //Путь к файлу.
  //Создаём экземпляр файлового потока и открываем файл в режиме чтения и записи
  //(fmOpenReadWrite), с запретом на запись из других процессов (fmShareDenyWrite).
  Fs := TFileStream.Create(FileName, fmOpenReadWrite + fmShareDenyWrite);
  try
    SetLength(SBuff, Fs.Size); //Выделяем память для буфера.
    Fs.Read(SBuff[1], Length(SBuff)); //Загружаем в буфер данные файлового потока.
    //Поиск в буфере SBuff первого вхождения подстроки Sf. Результат получаем в виде смещения.
    Offs := Pos(Sf, SBuff) - 1;
    if Offs > -1 then //Если подстрока найдена.
    begin
      Fs.Position := Offs; //Перемещаем указатель потока к найденной подстроке.
      Fs.Write(Sr[1], Length(Sr)); //Записываем новую последовательность байтов.
    end;
  finally
    FreeAndNil(Fs); //Уничтожаем экземпляр файлового потока и закрываем файл.
  end;
 
  if Offs > -1 then
    ShowMessage('Заданная последовательность байт найдена. Смещение = ' + IntToStr(Offs)
      + '. Записано новое содержимое.')
  else
    ShowMessage('Заданная последовательность байт не найдена.');
end;

FileName := ExtractFilePath(ParamStr(0)) + 'file.dat';

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  FileCtrl, StrUtils;
 
{Функция выполняет поиск в файле aFileName заданной цепочки байт aSf и вставку
на найденных позициях заменяющей цепочки байт aSr.
При успешном выполнении функция возвращает значение = True, иначе - False.
В список aSl записывается журнал выполнения. Запись в журнал будет отменена,
если aSl = nil.
aPref - задаёт префикс в строках, которые выводятся в журнал. Например, через
aPref можно задать отступ: ' '.}
function ProcFile(const aFileName : String; const aSf, aSr : AnsiString;
  aSl : TStrings; const aPref : String) : Boolean;
const
  SelfName = 'ProcFile()';
  //Размер буфера в байтах. Этот размер не должен быть меньше размера искомой подстроки.
  SizeBuff = 100000;
var
  Fs : TFileStream;
  SBuff : AnsiString; //AnsiString - тип, описывающий строку однобайтных символов.
  FOffs, Offs, SizeRes, Cnt : Int64;
begin
  Result := False;
  //Проверки.
  if Length(aSf) <> Length(aSr) then
    raise Exception.Create(SelfName + '. Длины aSf и aSr отличаются.');
  if SizeBuff < Length(aSf) then
    raise Exception.Create(SelfName + '. Размер буфера меньше длины aSf.');
 
  //Создаём экземпляр файлового потока и открываем файл в режиме чтения и записи
  //(fmOpenReadWrite), с запретом на запись из других процессов (fmShareDenyWrite).
  try
    Fs := TFileStream.Create(aFileName, fmOpenReadWrite + fmShareDenyWrite);
  except
    on e: Exception do
    begin
      if Assigned(aSl) then
        aSl.Add(aPref + 'Ошибка! Не удалось открыть файл. Сообщение: ' + e.Message);
      Exit;
    end;
  end;
  //Обработка данных потока (файла).
  try
    try
      SetLength(SBuff, SizeBuff); //Выделяем память для буфера.
      Cnt := 0;   //Количество выполненных замен.
      FOffs := 0; //Смещение указателя потока до чтения очередного блока данных.
      repeat
        SizeRes := Fs.Read(SBuff[1], SizeBuff); //Загружаем в буфер данные файлового потока.
        if SizeRes < SizeBuff then //Если в буфер загружено менее, чем SizeBuff байт (при достижении конца потока).
          SetLength(SBuff, SizeRes); //Изменяем размер буфера в соответствии с количеством загруженных байт.
        //Поиск в буфере.
        Offs := PosEx(aSf, SBuff, 1) - 1; //Смещение искомой подстроки в буфере.
        while Offs > -1 do
        begin
          Inc(Cnt); //Количество выполненных замен.
          Fs.Position := FOffs + Offs; //Перемещаем указатель потока к найденной подстроке.
          Fs.Write(aSr[1], Length(aSr)); //Записываем новую последовательность байтов.
          Offs := PosEx(aSf, SBuff, Offs + 2) - 1; //Продолжаем поиск в буфере со следующей позиции.
        end;
        FOffs := FOffs + SizeRes; //Смещение указателя потока с учётом последнего прочитанного блока.
        if FOffs < Fs.Size then   //Если пока не дошли до конца файла.
          Dec(FOffs, Length(aSf) - 1); //Откатываем смещение к неисследованной области.
        Fs.Position := FOffs;
      until Fs.Position = Fs.Size; //Прекращаем поиск, если достигли конца потока.
    except
      on e: Exception do
      begin
        if Assigned(aSl) then
          aSl.Add(aPref + 'Ошибка! Исключение возникло при обработке файла. Сообщение: ' + e.Message);
        Exit; //При этом управление сначала перейдёт в раздел finally - end.
      end;
    end;
  finally
    FreeAndNil(Fs); //Уничтожаем экземпляр файлового потока и закрываем файл.
  end;
 
  if Assigned(aSl) then
    aSl.Add(aPref + 'Количество замен: ' + IntToStr(Cnt));
  Result := True;
end;
 
{Процедура в заданном директории aPath (и во всех вложенных директориях, при aSubDir = True)
находит файлы по заданной маске aMask и в найденных файлах выполняет замену всех
вхождений цепочки байт aSf на цепочку aSr.
Если маска не задана, то будет использована маска = '*'.
Сведения о выполненных действиях выводятся в журнал aSl.
aSubDir - True, если надо обработать вложенные директории, False - иначе.}
procedure ProcDir(const aPath, aMask : String; const aSf, aSr : AnsiString;
  aSl : TStrings; const aSubDir : Boolean);
var
  Path, Mask : String;
  Srch : TSearchRec;
  Attr : Integer;
begin
  //Добавляем в конец строки слеш, если его нет.
  Path := IncludeTrailingPathDelimiter(aPath);
  //Маска.
  if aMask <> '' then
    Mask := aMask
  else
    Mask := '*';
 
  //В текущем директории ищем файлы по заданной маске.
  aSl.Add('Папка: ' + Path);
  Attr := faAnyFile - faVolumeID - faDirectory;
  if FindFirst(Path + Mask, Attr, Srch) = 0 then
  try
    repeat
      aSl.Add('    Файл: ' + Srch.Name);
      ProcFile(Path + Srch.Name, aSf, aSr, aSl, '        ');
    until FindNext(Srch) <> 0;
  finally
    FindClose(Srch);
  end;
 
  if aSubDir then //Если нужно обработать вложенные директории.
  begin
    //В текущем директории ищем все вложенные директории и для каждого из них выполняем рекурсивный вызов.
    Attr := faDirectory;
    if FindFirst(Path + '*', Attr, Srch) = 0 then
    try
      repeat
        if (Srch.Attr and Attr = Attr) and (Srch.Name <> '.') and (Srch.Name <> '..') then
          ProcDir(Path + Srch.Name, Mask, aSf, aSr, aSl, aSubDir);
      until FindNext(Srch) <> 0;
    finally
      FindClose(Srch);
    end;
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  S, Path, Mask : String;
  Sf, Sr : AnsiString;
begin
  //Директорий, в котором лежит исполняемый файл программы.
  Path := ExtractFilePath(ParamStr(0));
  //Диалог выбора директория.
  if not SelectDirectory('Выбор папки', '', Path) then
    Exit;
  {
  if not SelectDirectory(Path, [sdAllowCreate, sdPerformCreate, sdPrompt], 0) then
    Exit;
  }
  //Проверка существования директория.
  if not DirectoryExists(Path) then
  begin
    MessageBox(Handle, 'Заданная папка не найдена. Действие отменено.', 'Отмена!',
      MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Маска имён файлов.
  Mask := Edit1.Text;
  if Mask = '' then
    Mask := '*';
 
  {Искомая и заменяющая цепочки байт. Они должны быть заданы в виде шестнадцатиричных
  кодов. Каждый байт должен быть пердставлен двумя шестнадцатиричными цифрами.
  Запись должна быть без пробелов и состоять только из шестнадцатиричных цифр.
  Пример: 4B4C4D4E Этому значению, согласно таблице ASCII соответствует строка: KLMN }
 
  //Искомая цепочка байт.
  S := Edit2.Text;
  SetLength(Sf, Length(S) div 2);
  HexToBin(PChar(S), PAnsiChar(Sf), Length(Sf));
  //Заменяющая цепочка байт.
  S := Edit3.Text;
  SetLength(Sr, Length(S) div 2);
  HexToBin(PChar(S), PAnsiChar(Sr), Length(Sr));
 
  //Проверки.
  if Length(Sf) <> Length(Sr) then
  begin
    MessageBox(Handle, 'Длины искомой и заменяющей цепочек различны. Действие отменено.',
      'Отмена!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
  if Sf = '' then
  begin
    MessageBox(Handle, 'Искомая цепочка не задана. Действие отменено.',
      'Отмена!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  Memo1.Text := 'Начальный директорий: ' + Path;
  Memo1.Lines.Add('Маска: "' + Mask + '"');
  Memo1.Lines.Add('Искомая цепочка байт, HEX:'#9 + Edit2.Text);
  Memo1.Lines.Add('Заменяющая цепочка байт, HEX:'#9 + Edit3.Text);
  Memo1.Lines.Add('----------');
 
  ProcDir(Path, Mask, Sf, Sr, Memo1.Lines, True); //Поиск и обработка файлов.
  Memo1.Lines.Add('----------');
end;
 
end.