Форум программистов, компьютерный форум, киберфорум
Наши страницы

Delphi для начинающих

Войти
Регистрация
Восстановить пароль
 
Белая волчица
1 / 1 / 0
Регистрация: 20.02.2010
Сообщений: 65
#1

Построение приоритетных очередей и обработка данных на их основе - Delphi

02.06.2015, 21:12. Просмотров 940. Ответов 6
Метки нет (Все метки)

Доброго времени суток!

Необходимо реализовать очередь на базе списков, применяя комбинированный алгоритм для ее обслуживания. Затем продемонстрировать выполнение основных операций с элементами очереди: поиск, добавление, удаление.

Может может кто-нибудь помочь?
0
Лучшие ответы (1)
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
02.06.2015, 21:12
Здравствуйте! Я подобрал для вас темы с ответами на вопрос Построение приоритетных очередей и обработка данных на их основе (Delphi):

Построение графиков/диаграмм в Delphi на основе данных в Access - Delphi
Здравствуйте! Пишу программу, в которой хочу построить график и диаграмму на основе данных в в Access. Так как в программировании новичок,...

Динамические структуры данных: Определить число шагов, через которое одна из очередей станет пустой - Delphi
В работе во всех вариантах используются односвязные списки, информационная часть которых – целое число или строка. Требуется создать список...

Построение графика на основе данных из БД - C#
возможно, эту тему лучше было бы создать в ASP.NET. суть моего вопроса такова: есть БД. из нее я запросом вытаскиваю данные, на...

Построение графика на основе введенных данных - C++ Builder
Имеется программа, на основе введенных данных, строится график, но в результате вместо графика в image белый фон и программа зависает. ...

Построение прогноза на основе статистических данных - Теория вероятностей
Здравствуйте. У меня возникла проблема при решении производственной задачи. Большой ресторан типа фастфуд, кажый день готовит...

Построение графиков на основе данных из Qtableview - C++ Qt
Привет всем! В моей программе есть Qtableview, которая показывает результаты sql запросов. Там есть 2 колонки: ДАТА и ЧИСЛОВОЕ ЗНАЧЕНИЕ....

6
bv7
21 / 9 / 2
Регистрация: 24.05.2014
Сообщений: 56
02.06.2015, 22:17 #2
Я бы вопрос ставил так
Цитата Сообщение от Белая волчица Посмотреть сообщение
Доброго времени суток!
Необходимо реализовать очередь на базе списков, применяя комбинированный алгоритм для ее обслуживания. Затем продемонстрировать выполнение основных операций с элементами очереди: поиск, добавление, удаление.
Может может кто-нибудь помочь?
Цена вопроса ...

Иначе давай свои наработки будем всем миром думать.

Могу посоветовать "Гугл в помощь." (C)
0
Белая волчица
1 / 1 / 0
Регистрация: 20.02.2010
Сообщений: 65
02.06.2015, 22:31  [ТС] #3
Наработки вот:

Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Edit1: TEdit;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
Type
 
TPList=^TList;
  TList=record
    x:integer;
    next:TPList;
  End;
 
var
  Form1: TForm1;
 
  Stek:TPList;
  HeadTurn,TailTurn:TPList;
  
implementation
 
{$R *.dfm}
 
//процедура заполнения списка
procedure TForm1.Button1Click(Sender: TObject);
begin
 //создание первого элемента,если список пуст
 if (HeadTurn=nil) then
 begin
  new(HeadTurn);
  TailTurn:=HeadTurn;
  HeadTurn^.x:=strtoint(edit1.Text);
  HeadTurn^.next:=nil;
 end else
 begin
 //в конец списка
  new(TailTurn^.next);
  TailTurn^.next^.x:=strtoint(edit1.text);
  TailTurn^.next^.next:=nil;
  TailTurn:=TailTurn^.next;
 end;
end;
 
//процедура вывода списка
procedure TForm1.Button2Click(Sender: TObject);
var
  Stek1:TPList;
begin
 memo1.Clear;
 if HeadTurn=nil then memo1.Lines.add('Очередь пуста!');
  Stek1:=HeadTurn;
 while (Stek1<>nil) do
 begin
  memo1.Lines.Add(inttostr(Stek1^.x));
  Stek1:=Stek1^.next;
 end;
end;
 
procedure TForm1.Button3Click(Sender: TObject);
var
  elem:TPList;
begin
 memo1.Clear;
 elem:=HeadTurn;
 while (elem<>nil) do
 begin
  HeadTurn:=HeadTurn^.next;
  Dispose(elem);
  elem:=HeadTurn;
 end;
 memo1.Lines.Add('Очередь удалена!');
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
//Инициализация списков...
  Stek:=nil;
  HeadTurn:=nil;
  TailTurn:=nil;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
var
  elem:TPList;
begin
 //удаление очереди
  elem:=HeadTurn;
  while (elem<>nil) do
  begin
    HeadTurn:=HeadTurn^.next;
    Dispose(elem);
    elem:=HeadTurn;
  end;
end;
 
end.
Но тут всё как-то туго. Очередь заполняю и удаляю... С поиском пока никак. Да и с комбинированным алгоритмом для обслуживания очереди вообще вынос мозга.

Я даже не уверена, что делаю то, что нужно..
0
Mawrat
12794 / 5701 / 672
Регистрация: 19.09.2009
Сообщений: 8,807
03.06.2015, 07:50 #4
Белая волчица, за основу можно взять проект из сообщения: Создание очереди #17 или из Создание очереди #18. Потом надо сформулировать чёткое определение приоритета. И реализовать его в коде процедуры QueuePush().

О поиске. Здесь разные подходы могут быть. Можно реализовать поиск, работая со списком элементов, а не с механизмом очереди. В этом случае исходная очередь не изменяется и поиск получается более быстрый. Если при поиске надо действовать только через механизм очереди, то следует применить приём переливания очередей. В этом случае исходная очередь подвергнется изменениям - сначала её элементы будут перелиты во вторую очередь и параллельно выполнится поиск, затем - элементы из второй очереди будут перелиты обратно - в первую очередь.

Добавлено через 15 минут
О приоритете. Если основными данными элементов являются числа, то определения приоритета могут быть, например, такими:
- Меньшие - в начале, большие - в конце (или обратное правило).
- Нечётные - в начале, чётные - в конце (или обратное правило).
- Простые числа - в начале, остальные - в конце (или обратное правило).
И т. д.
1
Mawrat
12794 / 5701 / 672
Регистрация: 19.09.2009
Сообщений: 8,807
04.06.2015, 13:20 #5
Пример. Очередь с приоритетом. Правило приоритета: от начала - к концу по возрастанию ключей.
Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  //Тип ключа (основные данные).
  TData = Integer;
  //Тип указателя на элемент списка (это элемент очереди).
  TPElem = ^TElem;
  //Тип элемента списка (очереди).
  TElem = record
    Data : TData;   //Ключ (значение основных данных).
    PNext : TPElem; //Указатель на следующий элемент списка (очереди).
  end;
 
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Edit1: TEdit;
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
  public
    { Public declarations }
    FPQueue : TPElem; //Очередь.
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
{ Релизация очереди с приоритетом.
  Правило приоритета: от начала - к концу по возрастанию ключей (значений основных данных). }
 
{Добавление элемента в очередь согласно правилу приоритета.
Правило приоритета: от начала - к концу по возрастанию ключей (значений основных данных).}
procedure QueuePush(var aPQ : TPElem; const aData : TData);
var
  P, PPrev : TPElem;
begin
  New(P);           //Выделяем память для элемента и указатель на него записываем в переменную P.
  P^.Data := aData; //Запись основных данных.
  {Если список пуст, или ключ нового элемента не превышает ключа первого элемента,
  то новый элемент становится первым элементом списка.}
  if (aPQ = nil) or (aData <= aPQ^.Data) then
  begin
    P^.PNext := aPQ;
    aPQ := P;
  end
  else //Иначе, если список не пустой и ключ нового элемента превышает ключ первого элемента списка.
  begin
    //Согласно правилу приоритета ищем элемент, который должен быть расположен непосредственно перед новым элементом.
    PPrev := aPQ;
    while (PPrev^.PNext <> nil) and not (aData <= PPrev^.PNext^.Data) do
      PPrev := PPrev^.PNext;
    //Вставка нового элемента за элементом PPrev.
    P^.PNext := PPrev^.PNext;
    PPrev^.PNext := P;
  end;
end;
 
{Изъятие элемента из начала очереди.
Если очередь не пуста, то из её начала изымается элемент и возвращается
через параметр aData. В этом случае, функция возвращает значение True.
Если очередь пуста, то операция отменяется, а функция возвращает значение False.}
function QueuePop(var aPQ : TPElem; var aData : TData) : Boolean;
var
  P : TPElem;
begin
  Result := False;    //Отмечаем, что действие пока не выполнено.
  if aPQ <> nil then  //Если список не пустой.
  begin
    P := aPQ;         //Запоминаем указатель на первый элемент списка.
    aData := P^.Data; //Возвращаем данные первого элемента.
    aPQ := P^.PNext;  //Исключаем первый элемент из списка.
    Dispose(P);       //Освобождаем память, занятую под исключённый элемент.
    Result := True;   //Отмечаем, что действие выполнено.
  end;
end;
 
//Освобождение памяти, занятой для элементов очереди (очистка очереди).
procedure QueueFree(var aPQ : TPElem);
var
  Data : TData;
begin
  while QueuePop(aPQ, Data) do;
end;
 
//Запись очереди в список типа TStrings.
procedure QueueToList(aPQ : TPElem; aList : TStrings);
begin
  aList.Clear;
  while aPQ <> nil do
  begin
    aList.Add(IntToStr(aPQ^.Data));
    aPQ := aPQ^.PNext;
  end;
end;
 
{ TForm1 }
 
//Кнопка: Добавить (добавить элемент в очередь, согласно правилу приоритета).
procedure TForm1.Button1Click(Sender: TObject);
var
  Data : TData;
begin
  if not TryStrToInt(Edit1.Text, Data) then
  begin
    MessageBox(Handle, 'Неверная запись числа.', 'Повторите ввод',
      MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
  QueuePush(FPQueue, Data);          //Добавляем элемент в очередь (согласно правилу приоритета).
  QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
end;
 
//Кнопка: Извлечь (извлечь элемент из начала очереди).
procedure TForm1.Button2Click(Sender: TObject);
var
  Data : TData;
begin
  if QueuePop(FPQueue, Data) then      //Попытка извлечь элемент из начала очереди.
  begin
    Edit1.Text := IntToStr(Data);      //Запись взятого элемента в Edit.
    QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
  end;
end;
 
//Кнопка: Очистить (очистить очередь).
procedure TForm1.Button3Click(Sender: TObject);
begin
  QueueFree(FPQueue); //Освобождение памяти, выделенной для элементов очереди.
  QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
end;
 
//Перед закрытием формы.
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;   //Задаём действие - уничтожение формы.
  QueueFree(FPQueue); //Освобождение памяти, выделенной для элементов очереди.
end;
 
end.
1
Вложения
Тип файла: 7z QueueWithPriority-01.7z (157.9 Кб, 9 просмотров)
Mawrat
12794 / 5701 / 672
Регистрация: 19.09.2009
Сообщений: 8,807
05.06.2015, 09:36 #6
Лучший ответ Сообщение было отмечено автором темы, экспертом или модератором как ответ
Добавил две реализации поиска - через прямой доступ к списку и через механизм очереди.
Delphi
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  //Тип ключа (основные данные).
  TData = Integer;
  //Тип указателя на элемент списка (это элемент очереди).
  TPElem = ^TElem;
  //Тип элемента списка (очереди).
  TElem = record
    Data : TData;   //Ключ (значение основных данных).
    PNext : TPElem; //Указатель на следующий элемент списка (очереди).
  end;
 
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Edit1: TEdit;
    Edit2: TEdit;
    Memo1: TMemo;
    Memo2: TMemo;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    FPQueue : TPElem; //Очередь.
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
{ Релизация очереди с приоритетом.
  Правило приоритета: от начала - к концу по возрастанию ключей (значений основных данных). }
 
{Добавление элемента в очередь согласно правилу приоритета.
Правило приоритета: от начала - к концу по возрастанию ключей (значений основных данных).}
procedure QueuePush(var aPQ : TPElem; const aData : TData);
var
  P, PPrev : TPElem;
begin
  New(P);           //Выделяем память для элемента и указатель на него записываем в переменную P.
  P^.Data := aData; //Запись основных данных.
  {Если список пуст, или ключ нового элемента не превышает ключа первого элемента,
  то новый элемент становится первым элементом списка.}
  if (aPQ = nil) or (aData <= aPQ^.Data) then
  begin
    P^.PNext := aPQ;
    aPQ := P;
  end
  else //Иначе, если список не пустой и ключ нового элемента превышает ключ первого элемента списка.
  begin
    //Согласно правилу приоритета ищем элемент, который должен быть расположен непосредственно перед новым элементом.
    PPrev := aPQ;
    while (PPrev^.PNext <> nil) and not (aData <= PPrev^.PNext^.Data) do
      PPrev := PPrev^.PNext;
    //Вставка нового элемента за элементом PPrev.
    P^.PNext := PPrev^.PNext;
    PPrev^.PNext := P;
  end;
end;
 
{Изъятие элемента из начала очереди.
Если очередь не пуста, то из её начала изымается элемент и возвращается
через параметр aData. В этом случае, функция возвращает значение True.
Если очередь пуста, то операция отменяется, а функция возвращает значение False.}
function QueuePop(var aPQ : TPElem; var aData : TData) : Boolean;
var
  P : TPElem;
begin
  Result := False;    //Отмечаем, что действие пока не выполнено.
  if aPQ <> nil then  //Если список не пустой.
  begin
    P := aPQ;         //Запоминаем указатель на первый элемент списка.
    aData := P^.Data; //Возвращаем данные первого элемента.
    aPQ := P^.PNext;  //Исключаем первый элемент из списка.
    Dispose(P);       //Освобождаем память, занятую под исключённый элемент.
    Result := True;   //Отмечаем, что действие выполнено.
  end;
end;
 
//Освобождение памяти, занятой для элементов очереди (очистка очереди).
procedure QueueFree(var aPQ : TPElem);
var
  Data : TData;
begin
  while QueuePop(aPQ, Data) do;
end;
 
//Запись очереди в список типа TStrings.
procedure QueueToList(aPQ : TPElem; aList : TStrings);
begin
  aList.Clear;
  while aPQ <> nil do
  begin
    aList.Add(IntToStr(aPQ^.Data));
    aPQ := aPQ^.PNext;
  end;
end;
 
{ TForm1 }
 
//Кнопка: Добавить (добавить элемент в очередь, согласно правилу приоритета).
procedure TForm1.Button1Click(Sender: TObject);
var
  Data : TData;
begin
  if not TryStrToInt(Edit1.Text, Data) then
  begin
    MessageBox(Handle, 'Неверная запись числа.', 'Повторите ввод',
      MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
  QueuePush(FPQueue, Data);          //Добавляем элемент в очередь (согласно правилу приоритета).
  QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
end;
 
//Кнопка: Извлечь (извлечь элемент из начала очереди).
procedure TForm1.Button2Click(Sender: TObject);
var
  Data : TData;
begin
  if QueuePop(FPQueue, Data) then      //Попытка извлечь элемент из начала очереди.
  begin
    Edit1.Text := IntToStr(Data);      //Запись взятого элемента в Edit.
    QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
  end;
end;
 
//Кнопка: Очистить (очистить очередь).
procedure TForm1.Button3Click(Sender: TObject);
begin
  QueueFree(FPQueue); //Освобождение памяти, выделенной для элементов очереди.
  QueueToList(FPQueue, Memo1.Lines); //Показываем изменения в Memo.
end;
 
//Кнопка: Поиск с прямым доступом к списку.
procedure TForm1.Button4Click(Sender: TObject);
var
  P : TPElem;
  Data : TData;
  i, Cnt : Integer;
  S : String;
begin
  Data := StrToInt(Edit2.Text); //Искомое значение.
  Memo2.Text := 'Искомое значение: ' + IntToStr(Data);
 
  //Поиск.
  P := FPQueue;
  i := 0;   //Порядковый номер элемента в списке.
  Cnt := 0; //Количество найденных элементов.
  S := '';  //Строка с перечнем позиций, на которых найдено значение.
  while P <> nil do
  begin
    Inc(i);
    if P^.Data = Data then //Если обнаружен элемент с искомым значением.
    begin
      Inc(Cnt);
      if Cnt > 1 then
        S := S + ', ';
      S := S + IntToStr(i);
    end;
    P := P^.PNext;
  end;
 
  //Ответ.
  Memo2.Lines.Add('Найдено элементов: ' + IntToStr(Cnt));
  if Cnt > 0 then
    Memo2.Lines.Add('Перечень найденных позиций: ' + S);
end;
 
//Кнопка: Поиск через механизм очереди.
procedure TForm1.Button5Click(Sender: TObject);
var
  PQ : TPElem;
  Data, DataTmp : TData;
  i, Cnt : Integer;
  S : String;
begin
  Data := StrToInt(Edit2.Text); //Искомое значение.
  Memo2.Text := 'Искомое значение: ' + IntToStr(Data);
 
  //Поиск.
  PQ := nil; //Начальная инициализация вспомогательной очереди.
  i := 0;    //Порядковый номер элемента в списке.
  Cnt := 0;  //Количество найденных элементов.
  S := '';   //Строка с перечнем позиций, на которых найдено значение.
  //Переливаем элементы из очереди FPQueue в очередь PQ и осуществляем поиск.
  while QueuePop(FPQueue, DataTmp) do
  begin
    QueuePush(PQ, DataTmp);
    Inc(i);
    if DataTmp = Data then //Если обнаружен элемент с искомым значением.
    begin
      Inc(Cnt);
      if Cnt > 1 then
        S := S + ', ';
      S := S + IntToStr(i);
    end;
  end;
  //Переливаем элементы обратно - из очереди PQ в очередь FPQueue.
  while QueuePop(PQ, DataTmp) do
    QueuePush(FPQueue, DataTmp);
 
  //Сейчас вспомогательная очередь пуста. Освобождать занятую для неё память
  //не требуется. Тем не менее, для повышения надёжности кода выполним вызов
  //процедуры освобождения памяти.
  QueueFree(PQ);
 
  //Ответ.
  Memo2.Lines.Add('Найдено элементов: ' + IntToStr(Cnt));
  if Cnt > 0 then
    Memo2.Lines.Add('Перечень найденных позиций: ' + S);
end;
 
//Кнопка: Очистить результаты поиска.
procedure TForm1.Button6Click(Sender: TObject);
begin
  Memo2.Clear;
end;
 
//Перед закрытием формы.
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;   //Задаём действие - уничтожение формы.
  QueueFree(FPQueue); //Освобождение памяти, выделенной для элементов очереди.
end;
 
end.
1
Миниатюры
Построение приоритетных очередей и обработка данных на их основе  
Вложения
Тип файла: 7z QueueWithPriority-02.7z (160.2 Кб, 15 просмотров)
Белая волчица
1 / 1 / 0
Регистрация: 20.02.2010
Сообщений: 65
05.06.2015, 14:26  [ТС] #7
Огромное спасибо!
Буду разбираться
0
05.06.2015, 14:26
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
05.06.2015, 14:26
Привет! Вот еще темы с ответами:

TreeView: построение дерева на основе данных из БД Access - C#
Такова проблема. Есть 3 таблицы в БД. 1-компания, 2 - отдел, 3-пользователь в 1-компания столбцы - id_firma, name_firma в 2 - отдел...

TreeView: построение дерева на основе данных из БД Oracle 11g xe - C#
Добрый вечер.Столкнулся с такой проблемой.У меня есть три таблицы Partners P_ID ALIAS REGION INDIVIDUALS ID_FL P_ID ...

Чтение бинарного файла и построение графика на основе его данных - C++ Builder
Начал изучать c++ builder недавно и столкнулся с проблемой. Надо построить график, и при этом чтобы по одной кнопке происходила запись, а...

Построение иерарх. дерева на основе существующей БД. Как ускорить вывод данных. - C# ASP.NET
Есть БД в которой заложен вывод данных в иерархическом виде (1С) т.е. там есть ID и ParentID (вхождение в ветвь). Мне нужно вывести...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
7
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.