Создайте изображение шарика из компонентов Shape и запрограммируйте его взрыв

unit MyClasses;
 
interface
uses ExtCtrls, Types, Controls, Classes, Sysutils;
 
type
 
TParticle=class
private
  function GetPosition: TPoint;
  procedure SetPosition(const Value: TPoint);
public
  shp:TShape;
  angle:single;
  start:TPoint;
  startTime:Int64;
  speed:Single; // px / msec
  function Crd(aTime:int64):TPoint;
  constructor Create(Parent: TWinControl; p:TPoint; aangle:single; aspeed:single); reintroduce;
  destructor Destroy; override;
  property Position: TPoint read GetPosition write SetPosition;
end;
 
implementation
 
{ TParticle }
 
function TParticle.Crd(aTime: int64): TPoint;
begin
  Result.X := Round(start.X + speed * (atime-startTime) * Cos(angle));
  Result.Y := Round(start.y + speed * (atime-startTime) * Sin(angle));
end;
 
constructor TParticle.Create(Parent: TWinControl; p:TPoint; aangle:single; aspeed:single);
begin
  start := p;
  startTime := TThread.GetTickCount;
  shp := TShape.Create(nil);
  shp.Parent := parent;
  shp.SetBounds(p.x,p.y,10,10);
  shp.shape := stCircle;
  angle := aangle;
  speed := aspeed;
end;
 
destructor TParticle.Destroy;
begin
  FreeAndNil(shp);
  inherited;
end;
 
function TParticle.GetPosition: TPoint;
begin
  result := Point(shp.Left, shp.Top);
end;
 
procedure TParticle.SetPosition(const Value: TPoint);
begin
  shp.Left := Value.X;
  shp.Top := Value.Y;
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics,
  Controls, Forms, Dialogs, ExtCtrls, StdCtrls,
  Contnrs, MyClasses;
 
type
  TForm1 = class(TForm)
    pnl1: TPanel;
    shp1: TShape;
    tmr1: TTimer;
    procedure shp1MouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure FormCreate(Sender: TObject);
    procedure tmr1Timer(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FStartTime:Int64;
  public
    list : TObjectList;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  list:=TObjectList.Create;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  list.Free;
end;
 
procedure TForm1.shp1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
var
  i: Integer;
  p:TParticle;
begin
  shp1.Hide;
  FStartTime := TThread.GetTickCount;
  Randomize;
  for i := 0 to 3 do
  begin
    p:=TParticle.Create(pnl1, Point(shp1.Left,shp1.Top), 2*pi*random, 0.5*random);
    list.Add(p);
  end;
  tmr1.Enabled := true;
end;
 
procedure TForm1.tmr1Timer(Sender: TObject);
var i:integer;
begin
  for i := 0 to list.Count-1 do
  begin
    TParticle(list[i]).Position := TParticle(list[i]).Crd(TThread.GetTickCount);
  end;
 
  if TThread.GetTickCount-FStartTime>5000 then
    tmr1.Enabled := False;
end;
 
end.