Реализация течения времени. Виртуальное время. Замедление и ускорение относительно реального времени.

var
  //Начальный момент времени.
  TimeStart : TTime = 0;
  //Реальное время, прошедшее от начального момента.
  TimeCur : TTime = 0;
  //Виртуальное время, прошедшее от начального момента.
  TimeCurV : TTime = 0;
  //Отслеживаемый реальный интервал.
  Period : TTime = 0;
  //Отслеживаемый витруальный интервал.
  PeriodV : TTime = 0;
  //Коэффициент скорости течения виртуального времени относительно реального времени.
  //Speed = <Интервал виртуального времени> / <Интервал реального времени>.
  Speed : Extended = 0;
 
//Запуск/перезапуск таймера.
procedure TForm1.Button1Click(Sender: TObject);
begin
  //Выключаем таймер.
  Timer1.Enabled := False;
  //Интервал таймера.
  //Timer1.Interval := 200; //200 миллисекунд.
 
  //Коэффициент скорости течения виртуального времени.
  Speed := StrToFloatDef(Edit2.Text, 0);
  if Speed <= 0 then begin
    ShowMessage(
      'Коэффициент скорости течения времени должен быть положительным числом.'
      + #10 + 'Действие отменено.'
    );
    Exit;
  end;
  //Значение отслеживаемого периода виртуального времени, заданное в секундах,
  //переводим в формат данных типа TTime (TDateTime).
  PeriodV := StrToIntDef(Edit1.Text, 0) / (24 * 60 * 60);
  if PeriodV < 0 then begin
    ShowMessage(
      'Отслеживаемый период должен быть неотрицательным числом.'
      + #10 + 'Действие отменено.'
    );
    Exit;
  end;
  //Значение отслеживаемого периода реального времени.
  Period := PeriodV / Speed;
 
  //Показываем нулевые значения времени.
  Label1.Caption := FormatDateTime('hh:nn:ss', 0);
  Label2.Caption := FormatDateTime('hh:nn:ss', 0);
  //Определяем текущее время.
  TimeStart := Time;
  //Включаем таймер.
  Timer1.Enabled := True;
end;
 
//Останов таймера.
procedure TForm1.Button2Click(Sender: TObject);
begin
  //Выключаем таймер.
  Timer1.Enabled := False;
  //Показываем нулевые значения времени.
  Label1.Caption := FormatDateTime('hh:nn:ss', 0);
  Label2.Caption := FormatDateTime('hh:nn:ss', 0);
end;
 
//Обработка тиков таймера.
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  //Узнаём сколько прошло реального времени.
  TimeCur := Time - TimeStart;
  //Узнаём сколько прошло виртуального времени.
  TimeCurV := TimeCur * Speed;
 
  //Отслеживаем момент, когда истечёт заданный виртуальный интервал.
  if TimeCurV >= PeriodV then begin
    //Останавливаем таймер.
    Timer1.Enabled := False;
    //Показываем конечное значение реального времени.
    Label1.Caption := FormatDateTime('hh:nn:ss', Period);
    //Показываем конечное значение виртуального времени.
    Label2.Caption := FormatDateTime('hh:nn:ss', PeriodV);
    //Сообщение.
    ShowMessage('Заданный период истёк.');
    //Выходим.
    Exit;
  end;
 
  //Показыавем сколько реального времени прошло.
  Label1.Caption := FormatDateTime('hh:nn:ss', TimeCur);
  //Показыавем сколько виртуального времени прошло.
  Label2.Caption := FormatDateTime('hh:nn:ss', TimeCurV);
end;