Как программно дублировать форму с компонентами на ней?

@skv84 · Регистрация: 27.02.2012

Author24 — интернет-сервис помощи студентам

Всем привет! Я пишу мини инспектор объетов как в delphi и надо программно продублировать форму вместе со всеми компонентами. Копирование файла dfm не предлагать. Допустим

Pascal

    BinStream := TMemoryStream.Create;
    try
      FileStream := TFileStream.Create(SaveDialog.FileName, fmOpenWrite or fmCreate);
      try
        NewForm := TfmNewForm.Create(Self);
        NewForm := TfmNewForm(ActiveMDIChild); // тут я копирую только свойство самой формы,
                                                        // без компонентов, правильно?
        NewForm.FormStyle := fsNormal;              // ставлю нужное мне свойство
        .... // удаляю прочие лишние события формы
 
        // а вот теперь нужно перенести на NewForm все компоненты из ActiveMDIChild
        for i := 0 to ActiveMDIChild.ControlCount - 1 do
        begin
          // как здесь правильно сделать ? т.к. вылетает с ошибкой "list index out of bound (3)"
          NewControl := TControl.Create(Self);
          NewControl := ActiveMDIChild.Controls[i];
          NewControl.Parent := NewForm;
        end;
        // записываю всю форму с компонентами
        BinStream.WriteComponent(NewForm);
        BinStream.Seek(0, soFromBeginning);
        ObjectBinaryToText(BinStream, FileStream);
        NewForm.Free;
      finally
        FileStream.Free;
      end;
    finally
      BinStream.Free
    end;

@Alex_pac · 27.02.2012, 20:47

Я пишу мини инспектор объетов как в delphi

не ясна задача. по-подробней пожалуйста.

@skv84 · 27.02.2012, 22:03 **[ТС]**

Дык всю задачу я изложил в коде с комментариями. Т.е. непонятен сам принцип дублирования формы.

@Alex_pac · 28.02.2012, 01:17

Delphi

function FormClone(formparent:pointer):pointer; // фукнция клонирует любую форму
 var
    ms : TMemoryStream;
 begin
    ms := TMemoryStream.Create;
    try
      ms.WriteComponent(formparent) ;
      ms.Position := 0;
      Result := TFormClass(TForm(formparent).ClassType).CreateNew(Application) ;
      ms.ReadComponent( Result) ;
      //Result.Left := TForm(formparent).Left + 10;
      // Result.Top := TForm(formparent).Top + 10;
      // Result.Show;
    finally
      ms.Free;
    end;
 end;

пример

Delphi

procedure TForm1.Button2Click(Sender: TObject);
var f: TForm1;
begin
  f:=FormClone(self);
  //f.Show;
end;

@skv84 · 28.02.2012, 08:14 **[ТС]**

Спасибо! Работает!

DenNik · 28.02.2012, 10:46

а зачем такие сложности? не лучше ли создать еще один экземпляр нужной формы, или так не подойдет?

Delphi

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
var
  NewForm: TForm1;
begin
  NewForm:= TForm1.Create(Application);
  NewForm.Show;
end;
 
end.

@skv84 · 28.02.2012, 14:39 **[ТС]**

Нет, у меня, я поправлюсь, не просто инспектор объектов, а дизайнер форм. При редактировании формы мне надо чтобы в dfm файлик форма записалась в "чистом" виде: только форма и контролы. Без всяких там событий и ненужных компонентов, типа TSizeCtrl. Поэтому, переделав вышеупомянутый пример, сделал так. Именно сохранение формы:

Pascal

procedure TfmMainForm.SaveFromMainMenu1Click(Sender: TObject);
var
  BinStream  : TMemoryStream;
  FileStream : TFileStream;
  i          : Integer;
  NewForm    : TForm;
 
   function ControlClone(p : pointer; Comp: TComponent): pointer;
   var
      ms : TMemoryStream;
   begin
      ms := TMemoryStream.Create;
      try
        ms.WriteComponent(p) ;
        ms.Position := 0;
        Result := TControlClass(TControl(p).ClassType).Create(Comp);
        ms.ReadComponent( Result) ;
      finally
        ms.Free;
      end;
   end;
 
begin
  if SaveDialog.Execute then
  begin
    BinStream := TMemoryStream.Create;
    try
      FileStream := TFileStream.Create(SaveDialog.FileName, fmOpenWrite or fmCreate);
      try
        NewForm           := TForm.Create(Self);
        // ActiveMDIChild - форма, где проводилось редактирование, в ней куча ненужных событий и компонентов 
        // берем только нужное 
        NewForm.Left      := TfmNewForm(ActiveMDIChild).Left;
        NewForm.Top       := TfmNewForm(ActiveMDIChild).Top;
        NewForm.Width     := TfmNewForm(ActiveMDIChild).Width;
        NewForm.Height    := TfmNewForm(ActiveMDIChild).Height;
        for i:=0 to TfmNewForm(ActiveMDIChild).ControlCount-1 do
        begin
          // копируем контролы
          NewForm.InsertControl(ControlClone(ActiveMDIChild.Controls[i], NewForm));
        end;
        BinStream.WriteComponent(NewForm);
        BinStream.Seek(0, soFromBeginning);
        ObjectBinaryToText(BinStream, FileStream);
        NewForm.Free;
      finally
        FileStream.Free;
      end;
    finally
      BinStream.Free
    end;
  end;
end;

Вот теперь работает как надо!

@Alex_pac 1302 / 708 / 107 Регистрация: 25.05.2011 Сообщений: 2,158 Записей в блоге: 51
	27.02.2012, 20:47	2
	Я пишу мини инспектор объетов как в delphi не ясна задача. по-подробней пожалуйста. 0

@skv84 0 / 0 / 0 Регистрация: 27.02.2012 Сообщений: 4
	27.02.2012, 22:03 [ТС]	3
	Дык всю задачу я изложил в коде с комментариями. Т.е. непонятен сам принцип дублирования формы. 0

@skv84 0 / 0 / 0 Регистрация: 27.02.2012 Сообщений: 4
	28.02.2012, 08:14 [ТС]	5
	Спасибо! Работает! 0

	28.02.2012, 14:39