Как сделать, чтобы "Робот Петька" не заходил на остальные на форме?

procedure TForm1.Button3Click(Sender: TObject);
begin
button1.Top:=button1.Top+1;
if (button1.Top>471) then
begin
button1.Top:=471;
end;
end;
procedure TForm1.Button4Click(Sender: TObject);
begin
button1.Left:=button1.Left+1;
if (button1.left>649) then
begin
button1.Left:=649;
end;
end;
procedure TForm1.Button5Click(Sender: TObject);
begin
button1.Left:=button1.Left-1;
if button1.Left<0 then
begin
button1.left:=0;
end;
end;
procedure TForm1.SpeedButton1Click(Sender: TObject);
var
CH,CW:integer;
begin
randomize;
CH:=random(ClientHeight-speedbutton1.Height);
CW:=random(ClientWidth-speedbutton1.Width);
if (CH<0) or (CW<0) then
begin
CH:=CH+speedbutton1.Height;
CW:=CW+speedbutton1.Width;
speedbutton1.Top:=CH;
speedbutton1.Left:=CW;
end
else
speedbutton1.Top:=CH;
speedbutton1.Left:=CW;
end;
procedure TForm1.SpeedButton2Click(Sender: TObject);
begin
shape1.width:=shape1.width + 1;
shape1.height:=shape1.height + 1;
end;
procedure TForm1.SpeedButton3Click(Sender: TObject);
begin
shape1.width:=shape1.width - 1;
shape1.height:=shape1.height - 1;
end;

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    btnRobot: TButton;
    btnUp: TButton;
    btnLeft: TButton;
    btnDown: TButton;
    btnRight: TButton;
    Button6: TButton; // Это так, просто разбросанные кнопки для теста
    Button7: TButton;
    Button8: TButton;
    btnExit: TButton;
    procedure btnExitClick(Sender: TObject);
    procedure btnUpClick(Sender: TObject);
    procedure btnDownClick(Sender: TObject);
    procedure btnLeftClick(Sender: TObject);
    procedure btnRightClick(Sender: TObject);
  private
    { Private declarations }
    function CheckRobotMove(DeltaX, DeltaY : Integer) : Boolean;
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
const Step = 2;
 
procedure TForm1.btnDownClick(Sender: TObject);
begin
   if CheckRobotMove(0, Step) then
      btnRobot.Top := btnRobot.Top + Step;
end;
 
procedure TForm1.btnExitClick(Sender: TObject);
begin
   Close;
end;
 
procedure TForm1.btnLeftClick(Sender: TObject);
begin
   if CheckRobotMove(-Step, 0) then
      btnRobot.Left := btnRobot.Left - Step;
end;
 
procedure TForm1.btnRightClick(Sender: TObject);
begin
   if CheckRobotMove(Step, 0) then
      btnRobot.Left := btnRobot.Left + Step;
end;
 
procedure TForm1.btnUpClick(Sender: TObject);
begin
   if CheckRobotMove(-Step, 0) then
      btnRobot.Top := btnRobot.Top - Step;
end;
 
function TForm1.CheckRobotMove(DeltaX, DeltaY : Integer): Boolean;
var
   NewBounds, Foo : TRect;
   i : Integer;
begin
   Result := False;
   NewBounds := btnRobot.BoundsRect;
   OffsetRect(NewBounds, DeltaX, DeltaY);
 
   // Сначала проверим, не выходим ли за границы формы
   if not PtInRect(Self.ClientRect, NewBounds.TopLeft) or
      not PtInRect(Self.ClientRect, NewBounds.BottomRight) then Exit;
 
   for i := 0 to Self.ControlCount - 1 do // А потом - смотрим, не наедем ли на другой контрол
   begin
      if Controls[i] <> btnRobot then // Самого с собой сравнивать не будем
      begin
         if IntersectRect(Foo, NewBounds, Controls[i].BoundsRect) then Exit;
      end;
   end;
   Result := True; // Вернем True, если всё нормально и можно двигать робота
end;
 
end.