13104 / 5885 / 1706
Регистрация: 19.09.2009
Сообщений: 8,808
|
|
17.01.2013, 10:31
|
2
|
 Сообщение было отмечено keeet как решение
Решение
На форму надо положить Button1 : TButton и два Мемо: Memo1, Memo2 : TMemo. Для кнопки Button1 создать обработчик события OnClick и раздел implementation в модуле оформить так:
| Delphi | 1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
| implementation
{$R *.dfm}
type
//Тип основных данных списка.
TData = Integer;
//Тип указателя на элемент списка.
TPElem = ^TElem;
//Тип элемента списка.
TElem = record
Data : TData;
PNext : TPElem;
end;
//Тип, описывающий однонаправленный список.
TDList = record
PFirst, PLast : TPElem; //Указатели на первый и последний элементы списка.
end;
//Инициализация списка. Внимание! Эту процедуру можно выполнять только
//в отношении пустого списка. Иначе - будут утечки памяти.
procedure Init(var aList : TDList);
begin
aList.PFirst := nil;
aList.PLast := nil;
end;
//Добавление элемента в конец однонаправленного списка.
procedure Add(var aList : TDList; const aData : TData);
var
PElem : TPElem;
begin
New(PElem);
PElem^.Data := aData;
PElem^.PNext := nil;
if aList.PFirst = nil then
aList.PFirst := PElem
else
aList.PLast^.PNext := PElem;
aList.PLast := PElem;
end;
//Удаление элемента однонаправленного списка по указателю
//на предыдущий элемент. Если указатель на предыдущий элемент равен NIL,
//то удаляется первый элемент списка.
procedure Del(var aList : TDList; var aPPrev : TPElem);
var
PElem : TPElem;
begin
if aList.PFirst = nil then Exit;
if aPPrev = nil then begin
PElem := aList.PFirst;
aList.PFirst := PElem^.PNext;
end else begin
PElem := aPPrev^.PNext;
if PElem <> nil then aPPrev^.PNext := PElem^.PNext;
end;
if aList.PLast = PElem then aList.PLast := aPPrev;
if PElem <> nil then Dispose(PElem);
end;
//Освобождение памяти, занятой под список и инициализация списка.
procedure ListFree(var aList : TDList);
var
PNext, PDel : TPElem;
begin
PNext := aList.PFirst;
while PNext <> nil do begin
PDel := PNext;
PNext := PNext^.PNext;
Dispose(PDel);
end;
Init(aList);
end;
//Распечатка однонаправленного списка.
function ListToStr(const aList : TDList) : String;
var
PElem : TPElem;
begin
Result := '';
if aList.PFirst = nil then begin
Result := 'Список пуст.';
Exit;
end;
PElem := aList.PFirst;
while PElem <> nil do begin
if PElem <> aList.PFirst then Result := Result + ', ';
Result := Result + IntToStr(PElem^.Data);
PElem := PElem^.PNext;
end;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
L : TDList;
PElem, PPrev : TPElem;
i : Integer;
S : String;
begin
//Начальная инициализация списка.
Init(L);
//Читаем числа из Мемо и добавляем их в список.
//Предполагается, что каждое число в Мемо расположено на отдельной строке.
for i := 0 to Memo1.Lines.Count - 1 do begin
S := Memo1.Lines[i];
if S <> '' then Add(L, StrToIntDef(S, 0));
end;
Memo2.Lines.Add('--------------------------------------------------');
Memo2.Lines.Add('Составлен список:');
Memo2.Lines.Add(ListToStr(L));
//Удаляем из списка элементы с отрицательным значением.
PPrev := nil;
PElem := L.PFirst;
while PElem <> nil do begin
if PElem^.Data < 0 then begin
PElem := PElem^.PNext;
Del(L, PPrev);
end else begin
PPrev := PElem;
PElem := PPrev^.PNext;
end;
end;
Memo2.Lines.Add('Список после удаления отрицательных элементов:');
Memo2.Lines.Add(ListToStr(L));
//Освобождение памяти, занятой под список.
ListFree(L);
end;
end. |
|
1
|
(
Сообщение было отмечено keeet как решение
