Множества. Найти все слова, котрые состоят из тех же букв, что и последнее слово текста.

 
program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils,
  Windows;
 
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S : String;
  i, Len, Pos1 : Integer;
  Df, DTmp : set of Char;
begin
  //Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  //Если после переключения русские буквы показываются неверно,
  //следует открыть системное меню консольного окна - щелчком мыши в левом
  //верхнем углу окна консоли и выбрать:
  //Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  repeat
    Writeln('Задайте строку:');
    Readln(S);
 
    Writeln('Слова, состоящие из тех же букв, что и последнее слово:');
    //Длина строки.
    Len := Length(S);
    //Множество букв последнего слова.
    Df := [];
    //Множество букв в очередном слове.
    DTmp := [];
    //Позиция конца слова.
    Pos1 := 0;
    //Перебор символов строки справа - налево.
    for i := Len downto 1 do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Составляем множество букв очередного слова.
      DTmp := DTmp + [ S[i] ];
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then Pos1 := i;
      //Отслеживаем начало слова.
      if (i = 1) or (S[i - 1] in D) then begin
        //Множество букв последнего слова.
        if Df = [] then Df := DTmp;
        //Распечатка тех слов, которые состоят из тех же букв, что
        //и последнее слово.
        if Df = DTmp then Writeln( Copy(S, i, Pos1 - i + 1) );
        //Обнуление множества букв слова.
        DTmp := [];
      end;
    end;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.
 

 
unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Множество разделителей слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S : String;
  i, Len, Pos1 : Integer;
  Df, DTmp : set of Char;
begin
  S := Memo1.Text;
 
  Memo2.Lines.Add('Слова, состоящие из тех же букв, что и последнее слово:');
  //Длина строки.
  Len := Length(S);
  //Множество букв последнего слова.
  Df := [];
  //Множество букв в очередном слове.
  DTmp := [];
  //Позиция конца слова.
  Pos1 := 0;
  //Перебор символов строки справа - налево.
  for i := Len downto 1 do begin
    //Пропускаем разделители.
    if S[i] in D then Continue;
    //Составляем множество букв очередного слова.
    DTmp := DTmp + [ S[i] ];
    //Отслеживаем конец слова.
    if (i = Len) or (S[i + 1] in D) then Pos1 := i;
    //Отслеживаем начало слова.
    if (i = 1) or (S[i - 1] in D) then begin
      //Множество букв последнего слова.
      if Df = [] then Df := DTmp;
      //Распечатка тех слов, которые состоят из тех же букв, что
      //и последнее слово.
      if Df = DTmp then Memo2.Lines.Add( Copy(S, i, Pos1 - i + 1) );
      //Обнуление множества букв слова.
      DTmp := [];
    end;
  end;
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  Memo1.Clear;
end;
 
procedure TForm1.Button3Click(Sender: TObject);
begin
  Memo2.Clear;
end;
 
end.