Создать файл, записать в него текст и закрыть файл

format  MZ                       ;Исполняемый файл DOS EXE (MZ EXE)
entry   code_seg:start            ;Точка входа в программу
stack   200h                      ;Размер стека
;--------------------------------------------------------------------
segment data_seg                ;Cегмент данных
        String          db      'Kak mne nadoel asm'    ;Строка
        SLen            dw      $-String                ;Длина строки
        FileName        db      'filename.txt', 0
        Handle          dw      ?                       ;описатель файла
 
        msgErrCreateFile        db      'Create file error', '$'
        msgErrWriteFile         db      'Write file error', '$'
;--------------------------------------------------------------------
segment code_seg                ;Сегмент кода
start:                          ;Точка входа в программу
        mov     ax,     data_seg        ;Инициализация регистра DS
        mov     ds,     ax
 
        ;открытие файла на запись
        mov     ah,     3Ch     ;CREAT - CREATE OR TRUNCATE FILE
        lea     dx,     [FileName]      ;имя файла
        mov     cx,     0               ;атрибуты файла - простой файл
        int     21h
        jnc     .OkCreate
        ;в случае ошибки вывести сообщение и завершить программу
        mov     ah,     09h
        lea     dx,     [msgErrCreateFile]
        int     21h
        jmp     .Exit
        ;в случае успешного создания файла продолжить программу
.OkCreate:
        mov     [Handle],       ax
        ;запись в файл
        mov     ah,     40h     ;WRITE - WRITE TO FILE OR DEVICE
        mov     bx,     [Handle]        ;описатель файла
        mov     cx,     [SLen]          ;длина буфера записи
        lea     dx,     [String]        ;буфер записи
        int     21h
        jnc     .OkWrite
        ;в случае ошибки вывести сообщение, закрыть файл и завершить программу
        mov     ah,     09h
        lea     dx,     [msgErrWriteFile]
        int     21h
        jmp     .CloseFile
.OkWrite:
        ;в случае успешного записи в файл продолжить программу
 
.CloseFile:
        ;закрыть файл
        mov     ah,     3Eh     ;CLOSE - CLOSE FILE
        mov     bx,     [Handle]        ;описатель файла
        int     21h
 
.Exit:
        ;завершение программы
        mov     ax,     4C00h
        int     21h             ;Завершение программы