Вывести на экран ФИО тех студентов две оценки у которых 3

@Gleb_KK · Регистрация: 01.12.2014

Author24 — интернет-сервис помощи студентам

Составить список из 15 студентов, для каждого указать ФИО и оценки с 4 экзаменов. Составить программу , которая будет вводить данные для каждого студента заносить их в список и делать обработку (Вывести на экран ФИО тех студентов две оценки у которых 3)

Добавлено через 2 минуты
Прощу прощение за ошибку в описании темы , там не двоих с тройками, а тех у кого 2 оценки с экзаменов тройки.

@vint-81 · 04.02.2015, 19:46

Кликните здесь для просмотра всего текста

Pascal

uses crt;
const n=5;{15 количество студентов}
      nazvanie:array[1..4] of string=('математика','физика','химия','информатика');
type otmetki=array[1..4] of byte;
     student=record
        name:string;
        ot:otmetki;
       end;
     ukaz=^s;
     s=record
        inf:student;
        next:ukaz;
       end;
var u,hv,tmp:ukaz;
    i,j,k:integer;
procedure vivod(head:ukaz);
var tmp:ukaz;
    i:integer;
begin
 write('+');
 for i:=1 to 5 do write('-----------+');writeln;
 write('|  фамилия  |');
 for i:=1 to 4 do write(nazvanie[i]:11,'|');writeln;
 write('+');
 for i:=1 to 5 do write('-----------+');writeln;
 tmp:=head;
 while tmp<>nil do
  begin
   with tmp^.inf do
    begin
     write('|',name:11,'|');
     for i:=1 to 4 do write(ot[i]:11,'|');writeln;
    end;
  tmp:=tmp^.next
  end;
 write('+');
 for i:=1 to 5 do write('-----------+');writeln;
end;
 
begin
 clrscr;
 u:=nil;
 new(u);
 u^.next:=nil;
 with u^.inf do
  begin
   writeln('1 студент');
   write('Фамилия: ');readln(name);
   for i:=1 to 4 do
    begin
     write(nazvanie[i],': ');
     readln(ot[i]);
    end
  end;
 clrscr;
 hv:=u;
 for i:=2 to n do
  begin
   new(tmp);
   hv^.next:=tmp;
   tmp^.next:=nil;
   with tmp^.inf do
    begin
     writeln(i,' студент');
     write('Фамилия: ');readln(name);
     for j:=1 to 4 do
      begin
       write(nazvanie[j],': ');readln(ot[j]);
      end;
    end;
   hv:=tmp;
   clrscr;
  end;
 writeln('все студенты');
 vivod(u);
 writeln('студенты у которых за экзамены две оценки: 3');
 tmp:=u;
 while tmp<>nil do
  begin
   k:=0;
   with tmp^.inf do
    begin
     for i:=1 to 4 do if ot[i]=3 then inc(k);
     if k=2 then writeln(name)
    end;
   tmp:=tmp^.next
  end;
 readln
end.

@volvo · 04.02.2015, 20:17

Долго будем писать велосипеды? Есть же TFPGList<Record>, все проще:

stud.pp

Pascal

{$mode delphi}
unit stud;
 
interface
 
const
  numMarks = 4;
type
  tmarks = array[1 .. numMarks] of byte;
  tstudent =
  record
    fio : string;
    marks : tmarks;
 
    class operator Equal(a, b : tstudent) : boolean;
    procedure Print;
  end;
 
implementation
 
class operator tstudent.Equal(a, b : tstudent) : boolean;
begin
  result := a.fio = b.fio;
end;
 
procedure tstudent.Print;
var m : integer;
begin
  write(fio:12); for m in marks do write(m:3);
  writeln;
end;
 
end.

test.pp

Pascal

{$mode objfpc}
uses fgl, crt, stud;
 
type
  student_list = specialize TFpgList<tstudent>;
 
var
  lst : student_list;
  student : tstudent;
  more : char;
  i, count : integer;
 
begin
  lst := student_list.Create;
 
  repeat
    write('fio: '); readln(student.fio);
    for i := 1 to numMarks do
    begin
      write('  mark #', i, ': '); readln(student.marks[i]);
    end;
    lst.Add(student);
 
    write('continue? (y/n)'); readln(more);
  until upcase(more) = 'N';
 
  writeln('all students:');
  for student in lst do student.Print;
 
  writeln('selected:');
  for student in lst do
    with student do
    begin
      count := 0;
      for i in marks do inc(count, ord(i = 3));
      if count > 1 then student.Print;
    end;
 
  lst.Free;
end.

Сообщение от Gleb_KK

тех у кого 2 оценки с экзаменов тройки

Ровно 2, или не меньше двух? Мой вариант показывает 2 и больше...

@Gleb_KK · 05.02.2015, 16:53 **[ТС]**

volvo, сказали равно 2 , но и за этот вариант спасибо большое, мало ли !

Добавлено через 20 часов 32 минуты
volvo, а как можно сделать такую же программу, только с меню и процедурами?
Меню такого типа :
1)Init (инициализация);
2)Add_pbeg(добавить в начало списка);
3)Del_pbeg(удалить в начале списка);
4)List(показать список);
5)size(сколько элементов);
6)clear(очистить список);
7)Find(Это и есть та часть , которая ищет студентов с 2 тройками)
8)Exit;

@Gleb_KK 0 / 0 / 0 Регистрация: 01.12.2014 Сообщений: 48
		1
	Вывести на экран ФИО тех студентов две оценки у которых 3 04.02.2015, 18:33. Показов 1254. Ответов 3 Метки нет (Все метки) Составить список из 15 студентов, для каждого указать ФИО и оценки с 4 экзаменов. Составить программу , которая будет вводить данные для каждого студента заносить их в список и делать обработку (Вывести на экран ФИО тех студентов две оценки у которых 3) Добавлено через 2 минуты Прощу прощение за ошибку в описании темы , там не двоих с тройками, а тех у кого 2 оценки с экзаменов тройки. 0

@Gleb_KK 0 / 0 / 0 Регистрация: 01.12.2014 Сообщений: 48
	05.02.2015, 16:53 [ТС]	4
	volvo, сказали равно 2 , но и за этот вариант спасибо большое, мало ли ! Добавлено через 20 часов 32 минуты volvo, а как можно сделать такую же программу, только с меню и процедурами? Меню такого типа : 1)Init (инициализация); 2)Add_pbeg(добавить в начало списка); 3)Del_pbeg(удалить в начале списка); 4)List(показать список); 5)size(сколько элементов); 6)clear(очистить список); 7)Find(Это и есть та часть , которая ищет студентов с 2 тройками) 8)Exit; 0

Вывести на экран ФИО тех студентов две оценки у которых 3

Решение