Определить количество всех отрицательных компонент типизированного файла вещественных чисел

program file_of_single;
{Задача с [url]https://www.cyberforum.ru/free-pascal/thread1628086.html[/url]
 
 Дан типизированный файл вещественных (Single) чисел.
 Определить количество всех отрицательных.
 
 Подпрограмма должна быть написана в стиле защитного программирования.
 Необходимо предусмотреть обработку всех возможных ошибок. Описать все
 необходимые типы данных. Написать спецификацию к подпрограмме.}
{$mode objfpc}{$H+}
 
uses
    {$IFDEF UNIX}{$IFDEF UseCThreads}
    cthreads,
    {$ENDIF}{$ENDIF}
    sysutils, {для активации механизма исключений}
    Classes;
{Спецификация:
Функция принимает аргумент aFileName - имя файла вещественных числе
и возвращает целое - количество отрицательных чисел,
либо в случае неудачи значение -1}
function ProcessFile(const aFileName: string): integer;
var
  fHandle: file of Single;
  value: Single;
begin
  Result:= 0;
  try
      AssignFile(fHandle, aFileName);
 
    try
      Reset(fHandle);
 
      if FileSize(fHandle) > MaxInt then
         Raise Exception.Create('The file is too big. Integer overflow!');
 
      repeat
        Read(fHandle, value);
        if value < 0 then inc(Result);
      until EOF(fHandle) ;
 
    finally
      CloseFile(fHandle);
    end;
 
  except
    Result:= -1;
    exit;
  end;
 
end;
 
var
  fHTestFile: file of Single;
begin
  //testing
  AssignFile(fHTestFile, '_test.dat');
  Rewrite(fHTestFile);
  Write(fHTestFile, Single(15.0));
  Write(fHTestFile, Single(-15.0));
  Write(fHTestFile, Single(0.0));
  Write(fHTestFile, Single(99.0));
  CloseFile(fHTestFile);
  //корректный файл с 1-м отрицательным
  writeln('output should be 1, but we have: ', ProcessFile('_test.dat'));
  //корректный файл без отрицательных
  AssignFile(fHTestFile, '_test.dat');
  Rewrite(fHTestFile);
  Write(fHTestFile, Single(15.0));
  Write(fHTestFile, Single(15.0));
  Write(fHTestFile, Single(0.0));
  Write(fHTestFile, Single(99.0));
  CloseFile(fHTestFile);
  writeln('output should be 0, but we have: ', ProcessFile('_test.dat'));
  //несуществующий файл
  writeln('output should be -1, but we have: ', ProcessFile('___test.dat'));
  //файл неправильного формата
  writeln('output should be -1, but we have: ', ProcessFile('file_of_single.exe'));
 
  readln;
end.