Задача на сортировку простым выбором

@Viwwna · Регистрация: 18.11.2011

Author24 — интернет-сервис помощи студентам

Вот такая задача
Дана целочисленная матрица размером MхN. Пусть для каж-дой строки матрицы определена функция f(a), равная сумме составных чисел, являющихся элементами строки a. Упоря-дочить (переставить) строки матрицы по неубыванию в со-ответствии со следующим критерием: строка a считается «больше» строки b, если f(a) > f(b). Используйте алгоритм простого выбора.

ВНИМАНИЕ: в задаче необходимо составить программу, реализующую алгоритм сортировки. На экран выводятся исходный и результирующий массивы. Алгоритм сортировки оформить в виде процедуры.

Может у кого-нибудь есть наметки на подобную задачу? ЗАРАНЕЕ СПАСИБО

Составила вот что:

Pascal

const n=3; m=4;
type
    index=1..n;
    element = array[1..m] of real;
    mas = array[index] of element;
 
function f(s:element):real;
var
    i:integer;
    y:real;
begin
    y:=0;
    for i:=1 to m do   y:=y+s[i];
    f:=y
end;
 
procedure sort(var a:mas);
var i,j,k:index;
      x:element;
begin
    for i:=1 to n-1 do
         begin
         k:=i;
         x:=a[i];
         for j:=i+1 to n do
              if f(a[j])< f(x) then begin k:=j; x:=a[j] end;
         a[k]:=a[i];
         a[i]:=x
         end;
end;

Как вывести матрицу начальную и упорядоченную на экран???

@volvo · 27.11.2011, 15:41

Сообщение от Viwwna

Как вывести матрицу начальную и упорядоченную на экран???

Написать процедуру для вывода матрицы и вызвать ее до сортировки и после:

Pascal

const
   n = 3;
   m = 4;
type
   index = 1 .. n;
   element = array[1 .. m] of integer;
   mas = array[index] of element;
 
function f(s : element) : integer;
var
   i, j, sum : integer;
   divisors : integer;
begin
    sum := 0;
    for i := 1 to m do
    begin
       divisors := 0;
       for j := 2 to trunc(sqrt(s[i])) do
          if s[i] mod j = 0 then inc(divisors);
 
       if divisors > 0 then
          sum := sum + s[i];
    end;
    f := sum
end;
 
procedure sort(var a:mas);
var
   i, j, k : index;
   x : element;
begin
   for i := 1 to n - 1 do
   begin
      k := i;
      x := a[i];
      for j := i + 1 to n do
         if f(a[j]) < f(x) then
         begin
            k := j; x := a[j]
         end;
 
      a[k] := a[i];
      a[i] := x
   end;
end;
 
procedure print(const a : mas);
var i, j : integer;
begin
   for i := 1 to n do
   begin
      for j := 1 to m do write(a[i, j]:4);
      writeln;
   end;
end;
 
const
   a : mas =
   (
      ( 2,  3,  4,  5), // f =  4
      (10, 11, 12, 15), // f = 37
      (17, 19, 23, 19)  // f =  0
   );
 
begin
   writeln('До:');
   print(a);
   sort(a);
   writeln('После:');
   print(a);
end.

(у тебя неправильно находился результат функции F, нужно не сумму всех элементов, а сумму всех составных - т.е., не простых чисел, присутствующих в строке)

@Viwwna · 27.11.2011, 16:55 **[ТС]**

Сообщение от UI

(у тебя неправильно находился результат функции F, нужно не сумму всех элементов, а сумму всех составных - т.е., не простых чисел, присутствующих в строке)

Да, Спасибо ОГРОМНОЕ, Ты прав.....

@Viwwna 0 / 0 / 1 Регистрация: 18.11.2011 Сообщений: 129
	27.11.2011, 16:55 [ТС]	3
	Сообщение от UI (у тебя неправильно находился результат функции F, нужно не сумму всех элементов, а сумму всех составных - т.е., не простых чисел, присутствующих в строке) Да, Спасибо ОГРОМНОЕ, Ты прав..... 0

Опции темы