Ревью небольшого кода

module Main where
 
import Control.Applicative
import Control.Monad
import Data.Char
import Data.List
import qualified Data.Vector as V
import System.Environment
import System.IO
 
generateOpcodesFromMask :: String -> [String]
generateOpcodesFromMask ('*':ms) = [((head $ show x):y) | x <- [0, 1], y <- generateOpcodesFromMask ms]
generateOpcodesFromMask (m:ms) = [(m:y) | y <- generateOpcodesFromMask ms]
generateOpcodesFromMask [] = [""]
 
convertOpcodes :: [String] -> [Int]
convertOpcodes opcodes = foldl (\a b -> 2*a + digitToInt b) 0 <$> opcodes
 
addNameToOpcodes :: String -> [Int] -> [(Int, String)]
addNameToOpcodes name = map (\x -> (x, name))
 
getOpcodesWithName :: [String] -> [(Int, String)]
getOpcodesWithName [mask, name] = addNameToOpcodes name $ convertOpcodes $ generateOpcodesFromMask mask
getOpcodesWithName _ = error "getOpcodesWithName: invalid line"
 
fillFreeOpcodes :: Int -> [(Int, String)] -> [String]
fillFreeOpcodes maskLength opcodes = V.toList $ V.replicate (2 ^ maskLength) "INVALID" V.// opcodes
 
solveProblem :: Int -> [[String]] -> [String]
solveProblem maskLength contents = fillFreeOpcodes maskLength $ contents >>= getOpcodesWithName
 
main :: IO ()
main = do
  [inputFile, maskLength] <- getArgs
  withFile inputFile ReadMode $ \fd -> do
    contents <- hGetContents fd
    putStrLn "const std::vector<InstructionType> instructions_decoding_table{";
    putStr $ unlines $ (\name -> "InstructionType::" ++ name ++ ",") <$>
                       (solveProblem (read maskLength) $ words <$> (lines contents))
    putStrLn "};"

generateOpcodesFromMask ('*':ms) = [((head $ show x):y) | x <- [0, 1], y <- generateOpcodesFromMask ms]

generateOpcodesFromMask ('*':ms) = [(x:y) | x <- ['0', '1'], y <- generateOpcodesFromMask ms]

{-# LANGUAGE OverloadedStrings #-}
 
module Main where
 
import Control.Applicative
import Control.Monad
import qualified Data.ByteString.Char8 as S8
import Data.Char
import Data.List
import qualified Data.Vector as V
import System.Environment
import System.IO
 
generateOpcodesFromMask :: S8.ByteString -> [S8.ByteString]
generateOpcodesFromMask mask
  | S8.null mask = [""]
  | S8.head mask == '*' = [S8.cons x y | x <- ['0', '1'], y <- generateOpcodesFromMask (S8.tail mask)]
  | otherwise = [S8.cons (S8.head mask) y | y <- generateOpcodesFromMask (S8.tail mask)]
 
convertOpcodes :: [S8.ByteString] -> [Int]
convertOpcodes opcodes = S8.foldl' (\a b -> 2 * a + digitToInt b) 0 <$> opcodes
 
addNameToOpcodes :: S8.ByteString -> [Int] -> [(Int, S8.ByteString)]
addNameToOpcodes name = fmap (\x -> (x, name))
 
getOpcodesWithName :: [S8.ByteString] -> [(Int, S8.ByteString)]
getOpcodesWithName [mask, name] = addNameToOpcodes name $ convertOpcodes $ generateOpcodesFromMask mask
getOpcodesWithName _ = error "getOpcodesWithName: invalid line"
 
fillFreeOpcodes :: Int -> [(Int, S8.ByteString)] -> [S8.ByteString]
fillFreeOpcodes maskLength opcodes = V.toList $ V.replicate (2 ^ maskLength) "INVALID" V.// opcodes
 
solveProblem :: Int -> [[S8.ByteString]] -> [S8.ByteString]
solveProblem maskLength contents = fillFreeOpcodes maskLength $ contents >>= getOpcodesWithName
 
main :: IO ()
main = do
  [inputFile, maskLength] <- getArgs
  contents <- S8.readFile inputFile
  S8.putStrLn $ S8.concat ["const std::vector<InstructionType> instructions_decoding_table{",
                           S8.unlines $ (\name -> S8.concat ["InstructionType::", name, ","]) <$>
                             (solveProblem (read maskLength) $ S8.words <$> (S8.lines contents)),
                           "};"]

{-# LANGUAGE OverloadedStrings,ViewPatterns #-}
 
-- ...
 
generateOpcodesFromMask (S8.uncons -> Just('*',t)) = do
    x <- ['0', '1']
    y <- generateOpcodesFromMask t
    [S8.cons x y]
generateOpcodesFromMask (S8.uncons -> Just(h,t)) = do
    y <- generateOpcodesFromMask t
    [S8.cons h y]
generateOpcodesFromMask _ = [""]
 
-- ...
 
addNameToOpcodes name = map (flip (,) name)