Форум программистов, компьютерный форум, киберфорум
Наши страницы
MS Office Word
Войти
Регистрация
Восстановить пароль
 
 
Рейтинг 4.83/6: Рейтинг темы: голосов - 6, средняя оценка - 4.83
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
1

Копирование из Word в Outlook VBA

11.09.2019, 13:56. Просмотров 1154. Ответов 26
Метки нет (Все метки)

Всем привет, я дилетант, от слова совсем. Первый раз столкнулся с макросами в целом.
На данный момент есть определенная, личная задача - необходимо автоматизировать перенос информации из Word в outlook.

Смотрите пример во вложении "ПримерWord" - Есть определнная таблица в Word (Активный документ, к статике не привязываюсь, т.к всегда будут разные документы Word), в ней есть поля (обозначено на скриншт: поле2, поле3, поле4 и т.д).
Необходимо информацию из этих полей, автоматически переносить в Outlook, смотрите вложения"ПримерOutlook" - в соотв. поля.

Т.е поле3 из таблицы Word идет в таблицу в Outlook, в такое же поле3 (но уже в outlook).
Поле2 из Word идет в Outlook Поле2
Поле4 из Word в поле Outlook Поле4 и так далее.
Надеюсь суть удалось донести.

Что есть на данный момент.

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub SendOutlookMessages()
 
 'Dimension variables.
 Dim OL As Object, MailSendItem As Object
 Dim W As Object
 Dim MsgTxt As String
 
 'Starts Word session
 Set W = GetObject(Application.ActiveDocument)
 
 
 'Pulls text from file for message body
 MsgTxt = W.Range(Start:=W.Paragraphs(1).Range.Start, _
    End:=W.Paragraphs(W.Paragraphs.Count).Range.End)
 
 'Starts Outlook session
 Set OL = CreateObject("Outlook.Application")
 Set MailSendItem = OL.CreateItem(olMailItem)
 
 With MailSendItem
     .Subject = "Example"
     .Body = MsgTxt
     .To = "Example"
     MailSendItem.Display
 End With
 
End Sub
Range стоит как пример, просто смотрел как он работает. Через Range, кажется тяжелее, чем копировать. Если письмо создать я могу, но заставится перенестить то что мне нужно из Word в Outlook - никак.

Прошу помочь, заранее Всем спасибо!!!
0
Миниатюры
Копирование из Word в Outlook VBA   Копирование из Word в Outlook VBA  
QA
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
11.09.2019, 13:56
Ответы с готовыми решениями:

Копирование данных из Word в Outlook
Такая задача: необходимо в документе Word найти Email человека и передать его в строку "Кому" в...

Шаблон письма из Word в Outlook через Excel VBA
Здравствуйте! Подскажите, пожалуйста, можно ли решить следующую задачу и как? Есть файл Excel, в...

Копирование изображений Word VBA
Здравствуйте. Есть проблема при копировании картинок из одного документа word в другой. Суть задачи...

VBA Outlook: Как открыть сообщение для редактирования через объектную модель Word?
Добрый день! Подскажите, плиз, как открыть сообщение (MailItem) для редактирования через...

Копирование построчно из Word в Exel через VBA
Доброго времени суток. Задача состоит в следующем - есть файл Word и файл Excel. В ворде написан...

26
ViterAlex
6949 / 3892 / 1572
Регистрация: 11.02.2013
Сообщений: 8,450
Завершенные тесты: 3
11.09.2019, 21:37 2
В лоб тут не решишь. Нужно передавать предварительно сформированный html. Как-то так:
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub SendEmail()
    Dim ol As Object, item As Object
    Set ol = CreateObject("Outlook.Application")
    
    Set item = ol.CreateItem(0)
 
 With item
     .BodyFormat = 2 'olFormatHTML
     .Subject = "Example"
     .To = "Example"
     .HtmlBody = "<html>" + _
                    "<style>" + _
                        "td {width:30%;background-color: lightblue;}" + _
                        ".rightalign {text-align:right;}" + _
                    "</style>" + _
                    "<table>" + _
                        "<tr>" + _
                            "<td>" + _
                            "Поле8" + _
                            "</td>" + _
                            "<td class=""rightalign"">" + _
                                "20:00" + _
                            "</td>" + _
                        "</tr>" + _
                        "<tr>" + _
                            "<td>" + _
                            "Поле9" + _
                            "</td>" + _
                            "<td class=""rightalign"">" + _
                                "21:00" + _
                            "</td>" + _
                        "</tr>" + _
                    "</table>" + _
                 "</html>"
     .Display
 End With
End Sub
0
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
11.09.2019, 21:46 3
Цитата Сообщение от ViterAlex Посмотреть сообщение
В лоб тут не решишь
есть ограничение на количество строк продолжения
да и знак плюс(+) может отрицательно сказаться - если одно из полей NULL, то получим NULL-строку
поэтому предпочитаю
Visual Basic
1
2
3
4
5
6
7
 dim s
s = "<html>" 
s=s & "<style>" 
s=s &  "td {width:30%;background-color: lightblue;}" 
 '''''остальные строки подобно
s=s & "</html>"
.HtmlBody=s
1
ViterAlex
6949 / 3892 / 1572
Регистрация: 11.02.2013
Сообщений: 8,450
Завершенные тесты: 3
12.09.2019, 08:13 4
Чтобы обойти ограничение на продолжение кода на другой строке, сделаем класс, который будет заниматься добавлением строк (Insert→Class Module). Имя класса StringBuilder
StringBuilder (Insert→Class Module)

Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
Option Explicit
'Класс для упрощения работы со строками
Public Result As String
 
'Добавление текста
Public Function Append(text As String) As String
    Result = Result & text
    Append = Result
End Function
 
'Добавление текста и новой строки
Public Function AppendLine(text As String) As String
    AppendLine = Append(text) & vbNewLine
End Function

Затем метод, который из массивов имён полей и их значений сформирует таблицу html
Кликните здесь для просмотра всего текста
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
'Создание письма с таблицей полей и их значений
'fieldNames — массив с именами полей
'fieldValues — массив со значениями полей
Sub CreateEmail(fieldNames() As String, fieldValues() As String)
    'Если массивы не равны, то выдаём ошибку
    If UBound(fieldNames) <> UBound(fieldValues) Then
        Err.Raise vbObjectError + 513, Description:="Массивы имён полей и их значений должны быть равны."
        Exit Sub
    End If
    'Создаём html
    Dim sb As New StringBuilder
    With sb
        .AppendLine "<html>"
        .AppendLine "<style>"
        .AppendLine "tr.odd {background-color:#aaa}" 'фон нечётных строк
        .AppendLine "td.right {text-align:right}" 'выравнивание текста
        .AppendLine "table {width:300px;}" 'ширина таблицы
        .AppendLine "</style>"
        .AppendLine "<table>"
        Dim i As Integer
        Dim tr As String 'открывающий тэг строки
        For i = 0 To UBound(fieldNames)
            tr = IIf(i Mod 2 = 0, "<tr>", "<tr class=""odd"">")
            .AppendLine tr
            .AppendLine "<td>" 'ячейка с именем поля
            .AppendLine "<p>" & fieldNames(i) & "</p>"
            .AppendLine "</td>"
            .AppendLine "<td class=""right"">" 'ячейка со значением поля
            .AppendLine "<p>" & fieldValues(i) & "</p>"
            .AppendLine "</td>"
            .AppendLine "</tr>"
        Next
        .AppendLine "</table>"
        .AppendLine "</html>"
    End With
    
    Dim ol As Object, item As Object
    Set ol = CreateObject("Outlook.Application")
    Set item = ol.CreateItem(0) 'olMailItem
    
    With item
        .BodyFormat = 2 'olFormatHTML
        .Subject = "Example"
        .To = "Example"
        .HtmlBody = sb.Result
        .Display
    End With
End Sub

Метод, формирующий массивы имён полей и их значений из таблицы документа:
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
'Извление из таблицы имён полей и их значений
Sub GetfieldNamessAndValues()
    Dim names(6) As String
    Dim values(6) As String
    
    names(0) = GetCellText(ThisDocument.Tables(1).Cell(2, 1))
    names(1) = GetCellText(ThisDocument.Tables(1).Cell(3, 1))
    names(2) = GetCellText(ThisDocument.Tables(1).Cell(4, 1))
    names(3) = GetCellText(ThisDocument.Tables(1).Cell(5, 1))
    names(4) = GetCellText(ThisDocument.Tables(1).Cell(6, 1))
    names(5) = GetCellText(ThisDocument.Tables(1).Cell(7, 3))
    names(6) = GetCellText(ThisDocument.Tables(1).Cell(7, 5))
    
    values(0) = GetCellText(ThisDocument.Tables(1).Cell(2, 2))
    values(1) = GetCellText(ThisDocument.Tables(1).Cell(3, 2))
    values(2) = GetCellText(ThisDocument.Tables(1).Cell(4, 2))
    values(3) = GetCellText(ThisDocument.Tables(1).Cell(5, 2))
    values(4) = GetCellText(ThisDocument.Tables(1).Cell(6, 2))
    values(5) = GetCellText(ThisDocument.Tables(1).Cell(7, 4))
    values(6) = GetCellText(ThisDocument.Tables(1).Cell(7, 6))
    
    CreateEmail names, values
End Sub
Вспомогательный метод для получения правильного текста ячейки таблицы:
Visual Basic
1
2
3
4
'Получение чистого текста ячейки таблицы
Function GetCellText(tablecell As Cell) As String
    GetCellText = Mid(tablecell.Range.text, 1, Len(tablecell.Range.text) - 2)
End Function
1
Вложения
Тип файла: zip SendEmailSample.zip (21.8 Кб, 3 просмотров)
12.09.2019, 08:13
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 10:30  [ТС] 5
Большое спасибо! Сейчас буду пробовать подгонять под документы.

Добавлено через 11 минут
Один небольшой вопрос, забыл написать выше - Если мне повверх таблицы в письме, вставлять текст - как это будет выглядить? -

Visual Basic
1
2
3
4
5
6
7
With item
        .BodyFormat = 2 'olFormatHTML
        .Subject = "Example"
        .To = "Example"
        .HtmlBody = sb.Result
        .Display
    End With
.body повверх .htmlbody навряд-ли сработает ?
0
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 10:38  [ТС] 6
Попробовал применить на исходник (полный документ ,откуда брал пример)
выдает ошибку (см. вложение). Скриншот немного кривой, ругаетя на первую строку names
0
Миниатюры
Копирование из Word в Outlook VBA  
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 13:08  [ТС] 7
Вообще хотелось бы уточнить, на какую часть кода обратить внимание при смене таблицы? Условно я удаляю в нашем примере одну ячейку - выдает аналогичную ошибку со скриншота выше
0
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
12.09.2019, 14:08 8
doORdie,
удивительно, но у меня все работает без корректировки, хотя таблица не однородная(есть объединенные ячейки)
на всякий случай можно заменить строки
Visual Basic
1
2
Dim names(0 To 6) As String
Dim values(0 To 6) As String
0
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 14:28  [ТС] 9
Попробовал, ситуация не изменилась (см. скриншот). Просто попробовал отработать макрос на нескольких документах (откуда брался пример - они все однотипные).

В файле несколько таблиц, но по логике, он должен отрабатывать первую, насколько я понял
0
Миниатюры
Копирование из Word в Outlook VBA  
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
12.09.2019, 15:01 10
Цитата Сообщение от doORdie Посмотреть сообщение
Попробовал, ситуация не изменилась (см. скриншот).
чудеса да и только
----------------------
выложите реальный файл(в крайнем случае выложите на файлообменник или почту)
супер секреты можете заменить на аааааа оооооо ддддддд

возможно проблема все-таки в некорректности таблицы, ее ячеек

Добавлено через 4 минуты
может все же не находит ThisDocument.Tables(1)
где у вас расположен код
- в документе с данными
- в normal.dot

добавьте перед желтой строкой
Visual Basic
1
2
debug.print ThisDocument.name
debug.print ThisDocument.tables.count
1
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 15:29  [ТС] 11
Код открываю по средствам создания нового макроса.

Во вложении скриншот с
debug.print ThisDocument.name
debug.print ThisDocument.tables.count

Также, вложил оригинальный Word файл, с указанием, какие ячейки будут нужны в письме (Need) и какие не нужны (No needed).
0
Миниатюры
Копирование из Word в Outlook VBA  
Вложения
Тип файла: docx ExampleWORD.docx (21.3 Кб, 4 просмотров)
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 15:50  [ТС] 12
UPD :

Поправить уже сообщение не могу. Понял в чем была ошибка на том моем скриншоте.

Вобщем применил для файла который выложил сюда (ExampleWord), также не работает, но теперь ругается на values 6.
Имя и колличество таблиц определяет (см.скриншот).

Насколько я понимаю, это из-за того что таблица "неккоректная"? Подскажите, пожалуйста, как можно подстроить код выше под разные виды таблиц? В какую сторону именно смотреть.

Заранее спасибо!
0
Миниатюры
Копирование из Word в Outlook VBA  
ViterAlex
6949 / 3892 / 1572
Регистрация: 11.02.2013
Сообщений: 8,450
Завершенные тесты: 3
12.09.2019, 16:02 13
Под разные таблицы нужно поправлять количество элементов в массиве (6 — это макс. индекс, значит строк в таблице 7)
Также нужно смотреть, чтобы правильно брались индексы строк и столбцов ячейки. В ExampleWord столбцов 5, а обращение в строке с ошибкой идёт к столбцу с индексом 6.
И да. В массивах элементы индексируются с 0, а в коллекциях, типа Rows, Tables — с 1. Это нужно понять и простить.
Цитата Сообщение от doORdie Посмотреть сообщение
Если мне повверх таблицы в письме, вставлять текст - как это будет выглядить?
Мы же формируем обычный html, поэтому перед таблицей нужно добавить, скажем, тэг <p></p> и в него записать нужный текст.

Кроме того, в моём коде нужно заменить ThisDocument на ActiveDocument
1
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 16:26  [ТС] 14
По тексту все понял, вопросов нет!
На актив документ поменял.

По поводу массивов - здесь совсем тяжко, т.к "матчасти" нет у меня совсем((

В Вашем Word файле, насколько я понимаю, 6 строк, и в коде прописано до 6 индекса? Хотя исходя из того, что Вы описали Выше - индекс 6 равен 7 строкам.

В документе ExampleWord, я вижу 8 строк в первой таблице (с учетом красной), и 4 во второй (с учетом красной). Как вы высчитали 5 столбцов, буду откровенен, мне не совсем понятно(((

Не сочтите за наглость, можно ли визуально показать, как будет выглядить массив для ExampleWord? Визуально так сказать оценить разницу.

Спасибо!
0
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
12.09.2019, 17:09  [ТС] 15
UPD: Чуть разобрался, поменял массив -
Visual Basic
1
2
3
4
5
6
7
8
9
10
 names(0) = GetCellText(ThisDocument.Tables(1).Cell(2, 1))
    names(1) = GetCellText(ThisDocument.Tables(1).Cell(3, 1))
    names(2) = GetCellText(ThisDocument.Tables(1).Cell(4, 1))
    names(3) = GetCellText(ThisDocument.Tables(1).Cell(5, 1))
    
    
    values(0) = GetCellText(ThisDocument.Tables(1).Cell(2, 2))
    values(1) = GetCellText(ThisDocument.Tables(1).Cell(3, 2))
    values(2) = GetCellText(ThisDocument.Tables(1).Cell(4, 2))
    values(3) = GetCellText(ThisDocument.Tables(1).Cell(5, 2))
Выдает след. ошибку (см. скриншот Word4). Если поменять Active на This, проблема остается.

Однако - когда копирую эту таблицу в ваш файл (который @ViterAlex прислал с утра) все начинает работать!!!!

Подскажите, пожалуйста, почему если таблицу перенести в ваш файл - макрос работает. Из моего файла, отказывается работать. (причем так со всеми файлами)
0
Миниатюры
Копирование из Word в Outlook VBA  
Изображения
 
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
12.09.2019, 17:16 16
ваша таблица кривая, поэтому с ней надо работать через selection
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub mm190912_table()
Dim c1 As Cell, s1 As String, s9
word.activedocument.select
For Each c1 In Selection.Cells
s1 = c1.Range.Text
s1 = Replace(s1, Chr(13), "`")
s1 = Replace(s1, Chr(10), "`")
s1 = Replace(s1, Chr(11), "`")
s1 = Replace(s1, Chr(7), " ")
s1 = Replace(s1, Chr(9), " ")
 
s9 = "|"
Debug.Print c1.RowIndex; s9; c1.ColumnIndex; s9; s1
Next c1
End Sub
получим
1 1 `
2 1 Pole1`
2 2 No needed`
2 3 Date`
2 4 No needed`
3 1 Pole2`
3 2 No needed`
3 3 Date`
3 4 No needed`
4 1 Pole3`
4 2 Need`
5 1 Pole4`
5 2 Need`
6 1 Pole5`
6 2 Need`
7 1 Date and Time`
7 2 Start Date `& Time`
7 3 Click here to enter a date.`Need
7 4 End Date `& Time`
7 5 Click here to enter a date.`Need
8 1 Pole6`
8 2 No needed`
0
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
12.09.2019, 17:21 17
сдвиг колонок относительно друг друга
через массив получим
`       
Pole1` No needed` Date` No needed`    
Pole2` No needed` Date` No needed`    
Pole3` Need`      
Pole4` Need`      
Pole5` Need`      
Date and Time` Start Date `& Time` Click here to enter a date.`Need End Date `& Time` Click here to enter a date.`Need   
Pole6` No needed`      
0
Миниатюры
Копирование из Word в Outlook VBA  
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
13.09.2019, 10:56  [ТС] 18
Спасибо! Только пока не до конца понимаю, куда эти манипуляции внести в уже существующий код? Перед массивами? А массивы указывать по нумерацию, которую Вы указали выше?

И также хотелось бы понять, что значит ошибка на скриншоте выше (в файле @witeralex работает макрос, а в моих файлах пишет данную ошибку)
0
shanemac51
Модератор
Эксперт MS Access
9058 / 3456 / 548
Регистрация: 07.08.2010
Сообщений: 9,682
Записей в блоге: 2
13.09.2019, 12:59 19
Цитата Сообщение от doORdie Посмотреть сообщение
а в моих файлах пишет данную ошибку
у вас таблицы КРИВЕЕ, чем в примере

код примерно такой
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
Sub mm190912_table()
Dim c1 As Cell, s1 As String, s9, j1, j2
Dim xm(8, 6) As String
word.activedocument.tables(1).select
For Each c1 In Selection.Cells
s1 = c1.Range.Text
'' символ (`) применен для наглядности, можно пробел или тег <br>
s1 = Replace(s1, Chr(13), "`")
s1 = Replace(s1, Chr(10), "`")
s1 = Replace(s1, Chr(11), "`")
s1 = Replace(s1, Chr(7), " ")
s1 = Replace(s1, Chr(9), " ")
 
s9 = "|"
Debug.Print c1.RowIndex; s9; c1.ColumnIndex; s9; s1
xm(c1.RowIndex, c1.ColumnIndex) = s1
Next c1
 
For j1 = 1 To 8  '' отладочная печать
Debug.Print
For j2 = 1 To 6
Debug.Print xm(j1, j2); s9;
Next j2
Next j1
CreateEmail2 xm
End Sub
 
'Создание письма с таблицей полей и их значений
'fieldNames — массив с именами полей
'fieldValues — массив со значениями полей
Sub CreateEmail2(xz)
   
    'Создаём html
    Dim i As Integer
    Dim tr As String 'открывающий тэг строки
    
    ''''''''''''''
    Dim sb As New StringBuilder
    With sb
        .AppendLine "<html>"
        .AppendLine "<style>"
        .AppendLine "tr.odd {background-color:#aaa}" 'фон нечётных строк
        .AppendLine "td.right {text-align:right}" 'выравнивание текста
        .AppendLine "table {width:300px;}" 'ширина таблицы
        .AppendLine "</style>"
        .AppendLine "<table>"
 
        
            tr = IIf(i Mod 2 = 0, "<tr>", "<tr class=""odd"">")
            .AppendLine tr
            .AppendLine "<td>" 'ячейка с именем поля
            .AppendLine "<p>" & xz(2, 1) & "</p>"
            .AppendLine "</td>"
            .AppendLine "<td class=""right"">" 'ячейка со значением поля
            .AppendLine "<p>" & xz(2, 2) & "</p>"
            .AppendLine "</td>"
            .AppendLine "</tr>"
       ''''
       .AppendLine tr
            .AppendLine "<td>" 'ячейка с именем поля
            .AppendLine "<p>" & xz(2, 3) & "</p>"
            .AppendLine "</td>"
            .AppendLine "<td class=""right"">" 'ячейка со значением поля
            .AppendLine "<p>" & xz(2, 4) & "</p>"
            .AppendLine "</td>"
            .AppendLine "</tr>"
        ''''''и так далее
        .AppendLine "</table>"
        .AppendLine "</html>"
    End With
 
    Dim ol As Object, item As Object
    Set ol = CreateObject("Outlook.Application")
    Set item = ol.CreateItem(0) 'olMailItem
 
    With item
        .BodyFormat = 2 'olFormatHTML
        .Subject = "Example"
        .To = "Example"
        .HtmlBody = sb.Result
        .Display
    End With
End Sub
1
doORdie
0 / 0 / 0
Регистрация: 11.09.2019
Сообщений: 17
13.09.2019, 13:30  [ТС] 20
Если дело в таблице, то почему при вставке в этот файл (который файл с макросом ViterAlex), именно этой кривой таблицы - код ViterAlex начинает работать, получается дело не в таблице?

При вставке вашего кода получаю след. ошибку -
0
Миниатюры
Копирование из Word в Outlook VBA  
13.09.2019, 13:30
Answers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
13.09.2019, 13:30

Outlook word-wrap & word-break в таблице
Суть проблемы: есть таблица и в её ячейке есть однословный длинный текст, который своей чистой...

Копирование содержимого word в word из Excel с макросом
Ребят, добрый вечер! Подскажите,. пожалуйста, мне надо по сути создать копию документа WORD из...

Разница в скорости vba word и vba access
Вопрос: из акса идет выгрузка данных в файл ворд, далее эти данные опять же из акса форматно...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
20
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2019, vBulletin Solutions, Inc.
Рейтинг@Mail.ru