Форум программистов, компьютерный форум, киберфорум
Наши страницы
Pascal (Паскаль)
Войти
Регистрация
Восстановить пароль
 
Рейтинг 4.60/5: Рейтинг темы: голосов - 5, средняя оценка - 4.60
Evgenyi
0 / 0 / 0
Регистрация: 05.10.2015
Сообщений: 1
#1

Нахождение длины кратчайшего пути от одной вершины-источника ко всем остальным вершинам графа

05.10.2015, 09:34. Просмотров 1095. Ответов 1
Метки нет (Все метки)

Напишите программу, реализующую нахождение длины кратчайшего пути от одной вершины – источника ко всем остальным вершинам графа с применением метода поиска в ширину. Используйте представление графа в виде матрицы смежности. ??

Заказываю контрольные, курсовые, дипломные и любые другие студенческие работы здесь.

0
Лучшие ответы (1)
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
05.10.2015, 09:34
Ответы с готовыми решениями:

Нахождение кратчайшего расстояния до вершины
Здравствуйте уважаемые форумчане, помогите пожалуйста с кодом. Он работает не...

Графы: Нахождение Кратчайшего Пути(нужно Решение)
Знаю, что тут туча задач на подобную тему, но очень нужна помощь читал уйму...

Для графа дерева найти длину пути от вершины U до V (использовать поиск в глубину и счётчик глубины рекурсии WG)
помоги, пожалуйста, нужна программа:wall: Для графа дерева найти длину пути...

кратчайшие пути из одной заданной вершины графа в другую
Найти, если возможно, кратчайшие пути из одной заданной вершины в ...

Нахождение кратчайшего пути от одной вершины графа до другой
Парни помогите доделать , в общем дан граф , я представил его связи в виде...

1
ФедосеевПавел
Модератор
3454 / 1951 / 817
Регистрация: 01.02.2015
Сообщений: 6,507
05.10.2015, 12:44 #2
Лучший ответ Сообщение было отмечено ZX Spectrum-128 как решение

Решение

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
{
Нахождение длины кратчайшего пути от одной вершины-источника
ко всем остальным вершинам графа с применением метода поиска
в ширину. Используйте представление графа в виде матрицы смежности.
}
program BFS;
 
type
{
Тип, для идентификации вершины в очереди
}
  TInfo = record
    Vertex: integer;
  end;
{
**************************************************************
Реализация очереди на динамических списках
**************************************************************
}
  PQueueElement = ^TQueueElement;
 
  TQueueElement = record
    Info: TInfo;
    Next: PQueueElement;
  end;
 
  TQueueRoot = record
    First, Last: PQueueElement;
  end;
 
  procedure QueueInit(var root: TQueueRoot);
  begin
    root.First := nil;
    root.Last  := nil;
  end;
 
  procedure QueuePush(var root: TQueueRoot; info: TInfo);
  var
    p: PQueueElement;
  begin
    new(p);
    p^.Info := info;
    p^.Next := nil;
    if Assigned(root.Last) then
      root.Last^.Next := p
    else
      root.First := p;
    root.Last := p;
  end;
 
  procedure QueuePop(var root: TQueueRoot; var info: TInfo);
  var
    p: PQueueElement;
  begin
    if not Assigned(root.Last) then
    begin
      exit;
    end;
    info := root.First^.Info;
    p := root.First;
    if root.First <> root.Last then
    begin
      root.First := root.First^.Next;
    end
    else
    begin
      root.First := nil;
      root.Last  := nil;
    end;
    dispose(p);
  end;
 
  function QueueIsEmpty(root: TQueueRoot): boolean;
  begin
    QueueIsEmpty := (root.First = nil);
  end;
 
  procedure QueueFree(var root: TQueueRoot);
  var
    p, q: PQueueElement;
  begin
    p := root.First;
    while Assigned(p) do
    begin
      q := p;
      p := p^.Next;
      Dispose(q);
    end;
    QueueInit(root);
  end;
 
  procedure QueuePushV(var root: TQueueRoot; V: integer);
  var
    info: TInfo;
  begin
    info.Vertex := V;
    QueuePush(root, info);
  end;
 
  procedure QueuePopV(var root: TQueueRoot; var V: integer);
  var
    info: TInfo;
  begin
    QueuePop(root, info);
    V := info.Vertex;
  end;
 
{
**************************************************************
Реализация алгоритма обхода в ширину (BFS)
**************************************************************
}
const
  INFINITY = MaxInt;
type
  TAjacentMatrix = array of array of integer;
  TDistance = array of integer;
 
  procedure BFS_Enumerate(n: integer; const M: TAjacentMatrix;
    StartNode: integer; var D: TDistance);
  var
    Queue: TQueueRoot;
    WaveNum: integer;
    V, i:  integer;
  begin
    if n <= 0 then
      exit;
    {инициализация матрицы расстояний}
    for V := 0 to n - 1 do
      D[V] := INFINITY;
    if (StartNode < 0) or (StartNode >= n) then
      exit;
    QueueInit(Queue);
    QueuePushV(Queue, StartNode);
    D[StartNode] := 0;
    while not QueueIsEmpty(Queue) do
    begin
      QueuePopV(Queue, V);
      WaveNum := D[V];
      for i := 0 to n - 1 do
      begin
        if i = V then
          continue;
        if M[V, i] <> 0 then
        begin
          if D[i] = INFINITY then
          begin
            QueuePushV(Queue, i);
            D[i] := WaveNum + 1;
          end;
        end;
      end;
    end;
    QueueFree(Queue);
  end;
 
{
**************************************************************
Чтение из файла матрицы смежности и начальной вершины
**************************************************************
}
const
  NOLINK_CHAR = '0';
  LINK_CHAR = '1';
 
  procedure AdjacentMatrixLoadFromFile(var a: TAjacentMatrix;
  var n: integer; var StartNode: integer; sFileName: string);
  var
    x, y: integer;
    s: string;
    f: TextFile;
  begin
    n := 0;
    Assign(f, sFileName);
    Reset(f);
    readln(f, n);
    SetLength(a, n, n);
    for x := 0 to n - 1 do
    begin
      readln(f, s);
      for y := 0 to n - 1 do
      begin
        if s[y + 1] = NOLINK_CHAR then
          a[x, y] := 0
        else
          a[x, y] := 1;
      end;
    end;
    readln(f, StartNode);
    Close(f);
  end;
 
  procedure ShowAdjacentMatrix(n: integer; const M: TAjacentMatrix);
  var
    i, j: integer;
  begin
    for i := 0 to n - 1 do
    begin
      for j := 0 to n - 1 do
        Write(M[i, j]: 2);
      writeln;
    end;
  end;
 
  procedure ShowDistance(n: integer; const D: TDistance);
  var
    i: integer;
  begin
    for i := 0 to n - 1 do
      if D[i] = INFINITY then
        Write(' inf')
      else
        Write(D[i]: 4);
    writeln;
  end;
 
var
  n: integer;         {количество вершин}
  M: TAjacentMatrix;  {матрица смежности}
  StartNode: integer; {вершина, от которой будут искаться минимальные расстояния}
  D: TDistance;       {массив расстояний от StartNode}
begin
  AdjacentMatrixLoadFromFile(M, n, StartNode, 'Adjacent.txt');
  SetLength(D, n);
  BFS_Enumerate(n, M, StartNode, D);
  ShowAdjacentMatrix(n, M);
  ShowDistance(n, D);
end.
0
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
05.10.2015, 12:44

Нахождение кратчайшего пути графа
Товарищи программисты! Помогите пожалуйста! Очень нужна программа на С++...

Нахождение кратчайшего пути в неорентированном графе от заданой вершины к заданной
Добрый день. Вот решаю задачку о кратчайщем расстояние между двумя верщинами в ...

Найти все вершины графа, к которым существует путь заданной длины от выделенной вершины графа
Написать программу на prologuse на русском языке как на примере(Определить,...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
2
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru