Форум программистов, компьютерный форум, киберфорум
Наши страницы
Pascal (Паскаль)
Войти
Регистрация
Восстановить пароль
 
Рейтинг 4.60/5: Рейтинг темы: голосов - 5, средняя оценка - 4.60
Алла23
0 / 0 / 1
Регистрация: 23.11.2015
Сообщений: 47
1

Вывести номер курса, на котором наибольший процент мужчин

01.02.2016, 16:32. Просмотров 955. Ответов 1
Метки нет (Все метки)

Сведения о студентах вуза записаны в массиве и содержат следующую информацию: фамилия, имя, отчество, пол (М или Ж), возраст (от 16 до 35), курс (от 1-го до 5-го). Напишите программу, которая выводит эту информацию и печатает следующие данные:
а) номер курса на котором наибольший процент мужчин;
б) самые распространенные мужские и женские имена;
в) фамилии (в алфавитном порядке) и инициалы всех студенток, возраст и отчества которых являются одновременно самыми распространенными.
0
Лучшие ответы (1)
Надоела реклама? Зарегистрируйтесь и она исчезнет полностью.
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
01.02.2016, 16:32
Ответы с готовыми решениями:

Определить и вывести на печать номер квадранта, в котором расположена точка
определить и вывести на печать номер квадранта, в котором расположена точка...

Вывести на экран номер строки в котором максимальное количество отрицательных элементов
Какие сторонки заменить ,что бы вывести на экран номер строки в котором...

дан двумерный массив. вывести на экран минимальный номер строки, в котором все элементы положительные.
Здравствуйте! Помогите, пожалуйста с решением задачи. Пожалуйста..... дан...

Определить номер курса
Вводится номер семестра N<=10. Вывести фразу "Я проучился N семестров",...

Программа выводит значение максимального элемента, затем номер строки и номер столбца, в котором он встречается
Решите пожалуйста задачу!!! Условие: В метании молота состязается n...

1
JokeR.BY
CAPITAL OF ROCK!
1278 / 705 / 982
Регистрация: 03.03.2010
Сообщений: 2,284
Завершенные тесты: 2
02.02.2016, 17:36 2
Лучший ответ Сообщение было отмечено Памирыч как решение

Решение

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
type
    TStudent = record
        firstName, patronymic, lastName: String[35];
        sex: Boolean;
        age: 16..35;
        studyYear: 1..5;
    end;
    TStudentArray = record
        ar: Array[Word] Of TStudent;
        size: Word;
    end;
    TStatistic = Array[Boolean] Of Word;
    TStatistic2 = record
        name: String[35];
        quantity: Word;
    end;
 
procedure InitStudentArray(var sa: TStudentArray);
begin
    sa.size := 0;
end;
 
procedure AddStudent(var sa: TStudentArray); //метод добавления студента в список
var
    c: Char;
begin
    with sa do
    begin
        with ar[size] do
        begin
            Write('First name: '); ReadLn(firstName);
            Write('Patronymic: '); ReadLn(patronymic);
            Write('Last name: '); ReadLn(lastName);
            repeat
                Write('Sex (F|M): '); ReadLn(c);
            until (c in ['F', 'M', 'f', 'm']);
            sex := ((c = 'M') Or (c = 'm'));
            Write('Age (16..35): '); ReadLn(age);
            Write('Study year (1..5): '); ReadLn(studyYear);
        end;
        Inc(size);
    end;
end;
 
procedure PrintStudentList(const sa: TStudentArray); //вывод на печать списка
var
    i: Word;
begin
    with sa do
        if (size = 0)
        then
            WriteLn('List is empty!')
        else
            for i := 0 to size - 1 do
                with ar[i] do
                    WriteLn(#9, i + 1, '. ', lastName, ' ', firstName[1], '.', patronymic[1], '.');
end;
 
procedure ZadA(const sa: TStudentArray); //задание А
var
    a: Array[1..5] Of TStatistic;
    i: Word;
    temp: Boolean;
    maxId: 1..5;
    max: Double;
begin
    with sa do
        if (size = 0)
        then
            WriteLn('List is empty!')
        else
        begin
            for i := 1 to 5 do
                for temp := False to True do
                    a[i, temp] := 0;
            //составляем сколько кого на каждом курсе
            for i := 0 to size - 1 do
                with ar[i] do
                    Inc(a[studyYear, sex]);
            maxId := 1; max := 0;
            //ищем максимальное соотношение
            for i := 2 to 5 do
                if ((a[i, False] + a[i, True] <> 0) And (a[i, True] / (a[i, False] + a[i, True]) > max))
                then
                begin
                    maxId := i;
                    max := a[i, True] / (a[i, False] + a[i, True]);
                end;
            if (max = 0)
            then //если мужчин вообще нет
                WriteLn('Not found any!')
            else //иначе показываем наилучшее соотношение
                WriteLn('Answer A: ', maxId, ' ', (max * 100):0:2, '%');
        end;
end;
 
function BestName(const sa: TStudentArray; const bySex, byPatr: Boolean): String; //поиск самого частого имени или отчества
var
    stat: Array[Word] Of TStatistic2;
    i, j, nStat, maxId: Word;
    isFound: Boolean;
begin
    //составляем таблицу частот
    with sa do
    begin
        nStat := 0;
        for i := 0 to size - 1 do
            if (ar[i].sex = bySex) //фильтруем по полу
            then
            begin
                j := 0; isFound := False;
                //ищем в уже отобранных
                while ((j < nStat) And (Not isFound)) do
                begin
                    if (byPatr)
                    then
                        isFound := (ar[i].patronymic = stat[j].name)
                    else
                        isFound := (ar[i].firstName = stat[j].name);
                    Inc(j);
                end;
                if (isFound)
                then //если такое имя уже есть в статистике - увеличиваем количество
                    Inc(stat[j - 1].quantity)
                else //иначе - создаём новый
                begin
                    stat[nStat].quantity := 1;
                    if (byPatr)
                    then
                        stat[nStat].name := ar[i].patronymic
                    else
                        stat[nStat].name := ar[i].firstName;
                    Inc(nStat);
                end;
            end;
    end;
    //ищем максимум
    maxId := 0;
    for i := 1 to nStat do
        if (stat[i].quantity > stat[maxId].quantity)
        then
            maxId := i;
    BestName := stat[maxId].name;
end;
 
procedure ZadB(const sa: TStudentArray);
begin
    if (sa.size = 0)
    then
        WriteLn('List is empty!')
    else
    begin
        WriteLn('Answer B: ', BestName(sa, False, False));
        WriteLn('Answer B: ', BestName(sa, True, False));
    end;
end;
 
procedure SwapStudents(var x, y: TStudent); //обмен значений
var
    z: TStudent;
begin
    z := x;
    x := y;
    y := z;
end;
 
procedure SortByName(var sa: TStudentArray); //пузырьковая сортировка по фамилии
var
    i, n, nNew: Word;
begin
    with sa do
        if (size > 1)
        then
        begin
            n := size - 1;
            repeat
                nNew := 0;
                for i := 1 to n do
                    if (UpCase(ar[i - 1].lastName) > UpCase(ar[i].lastName))
                    then
                    begin
                        SwapStudents(ar[i - 1], ar[i]);
                        nNew := i;
                    end;
                n := nNew;
            until (n = 0);
        end;
end;
 
procedure ZadC(const sa: TStudentArray);
var
    bestFirstName, bestPatronymic: String[35];
    saFiltered: TStudentArray;
    i: Word;
begin
    if (sa.size = 0)
    then
        WriteLn('List is empty!')
    else
    begin
        bestFirstName := BestName(sa, False, False); //находим самое частое имя
        bestPatronymic := BestName(sa, False, True); //и самое частое отчество
        saFiltered.size := 0;
        for i := 0 to sa.size - 1 do
            if ((Not sa.ar[i].sex) And (sa.ar[i].firstName = bestFirstName) And (sa.ar[i].patronymic = bestPatronymic)) //фильтруем согласно заданию в отдельный временный массив
            then
            begin
                saFiltered.ar[saFiltered.size] := sa.ar[i];
                Inc(saFiltered.size);
            end;
        if (saFiltered.size = 0)
        then
            WriteLn('Cannot found any!')
        else
        begin
            SortByName(saFiltered); //пущаем сортировку
            PrintStudentList(saFiltered); //выводим на экран
        end;
    end;
end;
 
var
    s: TStudentArray;
begin
    //тут можно было бы добавить менюшку и прочее-прочее, но лень
    InitStudentArray(s);
    AddStudent(s);
    AddStudent(s);
    AddStudent(s);
    AddStudent(s);
    AddStudent(s);
    PrintStudentList(s);
    ZadA(s);
    ZadB(s);
    ZadC(s);
end.
1
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
02.02.2016, 17:36

Определить процентное соотношение количества мужчин в возрасте до 60 лет к общему количеству мужчин учреждения
нужно написать прогу вот задание: В автоматизированной инф. системе...

Определить и вывести на экран номер квадрата, в котором расположена точка
Задача 2. Определить и вывести на экран номер квадрата, в котором расположена...

Вывести номер слагаемого, при котором сумма ряда превысит 1000
Помощь срочно Дано вещественное число t(0&lt;t&lt;1). Вывести номер слагаемого, при...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
2
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru