Список.

program Project1;
 
type
 
  (*Типы для описания списка.*)
 
  (*Тип данных, которые будет содержать каждый элемент списка.*)
  TData = record
    Name : String;
    Country : String;
    Price : Single;
  end;
  (*Тип, задающий указатель на элемент списка.*)
  TPElem = ^TElem;
  (*Тип, описывающий элемент списка.*)
  TElem = record
    Data : TData;
    PNext : TPElem;
    PPrev : TPElem;
  end;
  (*Тип, описывающий список.*)
  TList = record
    PFirst : TPElem;
    PLast : TPElem;
  end;
 
(*Процедуры для работы со списком.*)
 
(*Добавление элемента в конец списка.*)
procedure ListAdd(var aList : TList; const aPElem : TPElem);
begin
  if aPElem = nil then Exit;
 
  aPElem^.PNext := nil;
  aPElem^.PPrev := nil;
  if aList.PFirst = nil then begin
    aList.PFirst := aPElem;
    aList.PLast := aPElem;
  end else begin
    aList.PLast^.PNext := aPElem;
    aPElem^.PPrev := aList.PLast;
    aList.PLast := aPElem;
  end;
end;
 
(*Удаление всего списка из памяти и инициализация.
Это очень важная процедура. Если список не удалить, то память, которую
занимали его элементы, окажется недоступной для дальнейшего использования.
Т. е. произойдёт "утечка памяти".*)
procedure ListFree(var aList : TList);
var
  PNext, PDel : TPElem;
begin
  if aList.PFirst = nil then Exit;
 
  PNext := aList.PFirst;
  while PNext <> nil do begin
    PDel := PNext;
    PNext := PNext^.PNext;
    Dispose(PDel);
  end;
 
  aList.PFirst := nil;
  aList.PLast := nil;
end;
 
var
  S : String;
  List : TList;
  PElem : TPElem;
begin
  (*Инициализация списка.*)
  ListFree(List);
 
  (*Добавляем в список несколько элементов.*)
 
  (*1.*)
  New(PElem);
  PElem^.Data.Name := 'Name1';
  PElem^.Data.Country := 'Country1';
  PElem^.Data.Price := 10;
  ListAdd(List, PElem);
  (*2.*)
  New(PElem);
  PElem^.Data.Name := 'Name2!';
  PElem^.Data.Country := 'Country2';
  PElem^.Data.Price := 20;
  ListAdd(List, PElem);
  (*3.*)
  New(PElem);
  PElem^.Data.Name := 'Name2!';
  PElem^.Data.Country := 'Country3';
  PElem^.Data.Price := 30;
  ListAdd(List, PElem);
  (*4.*)
  New(PElem);
  PElem^.Data.Name := 'Name4';
  PElem^.Data.Country := 'Country4';
  PElem^.Data.Price := 40;
  ListAdd(List, PElem);
 
  (*Вывод элементов списка на экран.*)
  PElem := List.PFirst;
  if PElem = nil then Writeln('Список пуст.');
  while PElem <> nil do begin
    Writeln(
      'Name = ', PElem^.Data.Name,
      'Country = ', PElem^.Data.Country,
      'Price = ', PElem^.Data.Price:0:2
    );
    PElem := PElem^.PNext;
  end;
 
  (*Вывод стоимости товаров с заданным названием.*)
  Writeln('Задайте название товара:');
  Readln(S);
  Writeln('Список товаров с заданным названием:');
  PElem := List.PFirst;
  if PElem = nil then Writeln('Список пуст.');
  while PElem <> nil do begin
    if PElem^.Data.Name = S then
      Writeln(
        'Name = ', PElem^.Data.Name,
        'Country = ', PElem^.Data.Country,
        'Price = ', PElem^.Data.Price:0:2
      );
    PElem := PElem^.PNext;
  end;
 
  (*Удаление элементов списка из памяти.
  Этот шаг необходим. Если список не удалить из памяти, то память, которую
  он занимает, окажется потеряной (утечка памяти).*)
  ListFree(List);
 
  Readln;
end.

      Writeln(
        'Name = ', PElem^.Data.Name,
        'Country = ', PElem^.Data.Country,
        'Price = ', PElem^.Data.Price:0:2
      );

      Writeln(
        'Name = ', PElem^.Data.Name,
        ', Country = ', PElem^.Data.Country,
        ', Price = ', PElem^.Data.Price:0:2
      );