Форум программистов, компьютерный форум, киберфорум
Наши страницы
Pascal (Паскаль)
Войти
Регистрация
Восстановить пароль
 
Рейтинг 4.80/5: Рейтинг темы: голосов - 5, средняя оценка - 4.80
Solomon_G
0 / 0 / 0
Регистрация: 21.12.2012
Сообщений: 1
1

Задача с использованием модульного программирования

24.12.2012, 20:43. Просмотров 910. Ответов 1
Метки нет (Все метки)

Создать таблицу (имя, пол 'm' или 'f', возраст, адрес). Должны быть функции(реализованы с возвратом полученной таблицы):
поиск всех записей с возрастом больше заданного пользователем,
поиск самой молодой женщины ('f'),
сортировка таблицы по алфавиту адреса,
добавление и удаление одной записи (по имени).
0
Лучшие ответы (1)
Similar
Эксперт
41792 / 34177 / 6122
Регистрация: 12.04.2006
Сообщений: 57,940
24.12.2012, 20:43
Ответы с готовыми решениями:

Задача с использованием функции
Вот, собственно, пример. Очень нужна помощь, спасибо.

Задача с использованием рекурсии
Очень срочно, заранее благодарю:) sqrt{11-2\sqrt{11+2\sqrt{11-2\sqrt{11-2\sqrt{11+...}}}}}

задача с использованием function
помогите пожалуйста сделать задачу)) Найти сумму наибольших элементов строк матрицы А размерности...

Задача с использованием функций
Условие задачи на картинке: 1)

задача с использованием одномерных массивов.
Возникла проблема с решение задачи:-| Дан массив A(m), m=или<16. Найти сумму S элементов,...

1
baquaqa
durila :d
125 / 107 / 98
Регистрация: 21.12.2012
Сообщений: 160
25.12.2012, 09:06 2
Лучший ответ Сообщение было отмечено как решение

Решение

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
Program _table;
 
uses 
 table_func,
 u_interface;
 
var
 mPerson:Tmperson;
 choice,count,iresult:integer;
 del_name:string;
 
Begin
 
{ menu }
 repeat  
  ShowMainMenu(choice);
  case choice  of 
    
    { print table }
    1:begin
       PrintTable(mPerson,count);
       Readln;
      end;
       
    { add record }
    2:begin
       AddRecord(mPerson,count);
      end;
        
    { delete record }
    3:begin
       write('delete (name): ');
       Readln(del_name);
       if DeleteRecord(mPerson,count,del_name) then write('Successfull')
                                               else write('not found');
       Readln;    
      end;
      
    { process menu }
    4:repeat
       ShowProcessMenu(choice);
       case choice  of 
        
        {find older}
        1:begin
           write('find older: ');
           Readln(iResult);
           FindOlder(mPerson,iResult,count);
           Readln;
          end;
          
        
        {find youngest woman}
        2:begin
           Write('Yongest woman: ',
           FindYstW(mPerson,count));
           Readln;
          end;
        
        { sort }
        3:begin 
           SortByAdress(mPerson,1,count);
           PrintTable(mPerson,count);
           Readln;
          end;
       
       end;
      until choice = -1;      
  end;
 until choice = 0;
 
End.
u_interface
Кликните здесь для просмотра всего текста

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
unit u_interface;
 
interface
 
 uses CRT;
 
 Procedure ShowMainMenu(var res:integer);
 Procedure ShowProcessMenu(var res:integer);
 
implementation
 
Procedure ShowMainMenu;
 var
  choice:Char;
 begin
  repeat
   ClrScr;
   Writeln('1. - print table');
   Writeln('2. - add record');
   Writeln('3. - delete record');
   Writeln('4. - processing table');
   Writeln('0. - exit');
   Writeln();
   Write(':> ');Readln(choice);
  until choice in ['0'..'4'];
  case choice of 
    '0':res:=0;
    '1':res:=1;
    '2':res:=2;
    '3':res:=3;
    '4':res:=4;
  end;
end;
 
Procedure ShowProcessMenu;
 var
  choice:Char;
 begin
  repeat
   ClrScr;
   Writeln('1. - find older..');
   Writeln('2. - find youngest woman');
   Writeln('3. - sort table by adress');
   Writeln('0. - back');
   Writeln();
   Write(':> ');Readln(choice);
  until choice in ['0'..'3'];
  case choice of 
    '0': res:=-1;
    '1': res:=1;
    '2': res:=2;
    '3': res:=3;
  end;
 
end;
 
end.


table_func
Кликните здесь для просмотра всего текста

Pascal
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
unit table_func;
 
interface
  
 type
  TPerson=record
    name:string[10];
    sex:(male,female);
    age:word;
    adress:string[20];  
  end;
  
  TMperson= array [1..100] of TPerson;
  
 
 procedure AddRecord(var aPerson:TMPerson;var count:integer);
 
 procedure PrintTable(const aPerson:TMPerson;count:integer);
 
 procedure FindOlder(var aPerson:TMPerson;aFold,count:integer);
 
 procedure SortByAdress(var aPerson:TMPerson;left,right:integer);
 
 function FindYstW(var aPerson:TMPerson;count:integer):String;
 
 function DeleteRecord(var aPerson :TMPerson;
                       var count   :integer;
                           del_name:string ):boolean;
 
 
 
implementation
 
procedure AddRecord;
  var
   cS:char;
   h:integer;
  begin
   inc(count);
   h:=count;
   With aPerson[h] do begin
                       Write('name: ');Readln(name);
                       repeat 
                        Write('sex (m/f): ');
                         readln(cS)
                       until (cS='m') or (cS='f');
                       if cS='m' then sex:=male
                                 else sex:=female;
                       Write('age: ');readln(age);
                       Write('Adress: ');readln(adress);
                     end; 
end;
 
 
 
procedure PrintTable;
  var
   i:integer;
  begin
   for i:=1 to count do 
   with aPerson[i]   do begin
                        writeln(name:10,
                                sex:7,
                                age:5,
                                adress:21);
                     end;                   
end;
 
procedure FindOlder;
  var
   i:integer;
  begin
   for i:=1 to count do
   with aPerson[i]   do 
   if age > aFold then writeln(name:10,
                               sex:7,
                               age:5,
                               adress:21); 
end;
 
function FindYstW;
  var
   i,min,imin:integer;
   bW:boolean;
   
  begin
   bW:=false;
   for i:=1 to count do 
   with aPerson[i] do   
   if sex=female  then begin 
                       bW:=true;
                       min:=age;
                       imin:=i;
                       break;
                       end;
   if bW then begin
              for i:=1 to count do 
              with aPerson[i]   do
              if (sex=female) and (age<min) then begin
                                                  min:=age;
                                                  imin:=i;
                                                 end;
              FindYstW:=aPerson[imin].name;                                   
              end
              else FindYstW:='no womans in table'
end;
 
procedure SortByAdress;
 procedure sort(left,right:integer);
  var
   l,r,i:integer;
   Persontemp:TPerson;
   mid:string;
  begin
   l:=left;
   r:=right;
   mid:=aPerson[(l+r) div 2].adress;
   i:=1;
   While aPerson[l].adress[i]=mid[i] do
   if i=length(mid) then break
                    else inc(i);
   repeat   
    while aPerson[l].adress[i]<mid[i] do inc(l);
    while aPerson[r].adress[i]>mid[i] do dec(r);
    if l<=r then begin
                  Persontemp:=aPerson[l]; 
                  aPerson[l]:=aPerson[r];
                  aPerson[r]:=persontemp;
                  inc(l);dec(r);
                 end;
   until l>=r;
   if left < r  then  Sort(left,r);  
   if l < right then  Sort(l,right); 
  end;
 
 begin
   sort(left,right)
end;
 
function DeleteRecord;
 var
  i,del_pos:integer;
  name_ex:boolean;
 begin
  { find name in table}
  name_ex:=FALSE;
  for i:=1 to count do 
  with aPerson[i]   do
  if name=del_name then begin
                         name_ex:=TRUE;
                         del_pos:=i;
                        end;
  if name_ex then begin
                  for i:=del_pos to count-1 do
                  aPerson[i]:=aPerson[i+1];
                  dec(count);
                  deleteRecord:=TRUE;
                  end
             else deleteRecord:=FALSE;
end;
 
end.
0
Вложения
Тип файла: zip files.zip (2.2 Кб, 7 просмотров)
MoreAnswers
Эксперт
37091 / 29110 / 5898
Регистрация: 17.06.2006
Сообщений: 43,301
25.12.2012, 09:06

Задача на массив (с использованием функции).
Доброго времени суток! Помогите решить задачу с помощью ПОДПРОГРАММ-ФУНКЦИЙ. Найти большее из...

Задача с использованием структуры «файл»
Дан файл, содержащий различные даты. Каждая дата — это число, месяц и год. (pascal) Найти самую...

Задача на одномерные массивы с использованием процедур
Помогите пожалуйста с решением задачи: Заданы 2 любых одномерных массива V и F. Для каждого...


Искать еще темы с ответами

Или воспользуйтесь поиском по форуму:
2
Ответ Создать тему
Опции темы

КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.
Рейтинг@Mail.ru