Функция, меняющая местами указанные строки в матрице

program mass;
 
type
  mas = array[1..10, 1..10] of integer;
 
var
  n, i, j, x: integer;
  m: mas;
 
function init(a: mas; cnt: integer): mas;
var
  k, h: integer;
begin
  for k := 1 to n do
    for h := 1 to n do
      a[k, h] := 0;
end;
 
function rand(a: mas; cnt: integer): mas;
var
  v, w: integer;
begin
  for v := 1 to n do
    for w := 1 to n do
      a[v, w] := Random(100);
  Rand := a;
end;
 
function vvod(a: mas; cnt: integer): mas;
var
  r, t: integer;
begin
  for r := 1 to n do
    for t := 1 to n do
    begin
      writeln(' m[', r, ',', t, ']=');
      read(a[r, t]);
      vvod:=a;
    end;
end;
 
function print(a: mas; cnt: integer): mas;
var
  k1, k2: integer;
begin
  for k1 := 1 to n do
  begin
    writeln;
    for k2 := 1 to n do
      write(' a[', k1, ',', k2, ']=', a[k1, k2]);
  end;
end;
 
 
function Zamena(a:mas; cnt: integer): mas;
 
 
 
begin
  Writeln('Введите размерность квадратного массива, n');
  Readln(n);
  repeat
    
    writeln;
    writeln('1.)Заполнить массив вручную');
    writeln('2.)Процедура инициализации');
    writeln('3.)Заполнить массив рандомно');
    writeln('4.)Процедура вывода массива');
    writeln('5.)Выход');
    writeln('6.)Замена указанных строк местами');
    writeln('Введите цифру операции');
    
    readln(x);
    case x of
      1: m := vvod(m, n);
      2: m := init(m, n);
      3: m := rand(m, n);
      4: m := print(m, n);
      6:
    end;
  until x = 5;
end.

type
  mas = array [1..100, 1..100] of integer;
 
function masInput(n : Integer) : mas;
var otvet : String;
begin
  for var Row := 1 to n do
    for var Col := 1 to n do
      repeat
        otvet := ReadLnString('[' + Row + ',' + Col + '] =');
      until TryStrToInt(otvet, Result[Row, Col]);
end;
 
function masRandom(n : Integer) : mas;
begin
  Randomize;
  for var Row := 1 to n do
    for var Col := 1 to n do
      Result[Row, Col] := Random(0, 99);
end;
  
procedure masOutput(n : Integer; m : mas; msg : String := '');
begin
  WriteLn;
  if msg.Length > 0 then WriteLn(msg);
  var d := 0;
  for var Row := 1 to n do
    for var Col := 1 to n do
      d := max(d, m[Row, Col].ToString.Length);
  d += 1;
  for var Row := 1 to n do
    begin
      for var Col := 1 to n do
        Write(m[Row, Col]:d);
      WriteLn;
    end;
end;
 
procedure masSwapRows(Row1, Row2, n : Integer; var m : mas);
begin
  for var Col := 1 to n do
    Swap(m[Row1, Col], m[Row2, Col]);
end;
 
var
  n : Integer; // Размер массива
  otvet : String; // Вводимый ответ
  m : mas; // Массив
  Row1, Row2 : Integer; // Номера строк для обмена
  
begin
  repeat
    otvet := ReadLnString('Введите размерность квадратного массива до 100: n =').Trim(#32);
    tryStrToInt(otvet, n);
    if (n < 1) or (n > 100) then WriteLn(NewLine, 'Ошибка ввода числа! Повторите.');
  until (n > 0) and (n < 101);
    
  WriteLn;
  repeat
    WriteLn('Выберите способ заполнения:');
    WriteLn('1 - Заполнить массив вручную');
    WriteLn('2 - Заполнить массив случайными числами');
    otvet := ReadLnString('Ваш выбор:').Trim(#32);
    case otvet of
      String('1') : m := masInput(n);
      String('2') : m := masRandom(n);
    else
      WriteLn(NewLine, 'Ошибочный ввод! Повторите.');
    end;
  until (otvet = '1') or (otvet = '2');
 
  masOutput(n, m, 'Получен следующий массив:');
  
  WriteLn;
  repeat
    otvet := ReadLnString('Введите через пробел номера строк для замены или „0“ для завершения работы:').Trim(#32);
    var w := otvet.ToWords(#32);
    if (w.Count = 1) and (w[0] = '0') then
      otvet := 'the end' // если введен один „0“
    else
      if w.Count <> 2 then
        WriteLn(NewLine, 'Неверное число параметров! Повторите ввод.') // если введено не два значения
    else
      if not( tryStrToInt(w[0], Row1) and tryStrToInt(w[1], Row2) ) then
        WriteLn(NewLine, 'Неверные номера строк! Повторите ввод.') // введены не числовые данные
    else
      if (Row1 < 1) or (Row1 > n) or (Row2 < 1) or (Row2 > n) then
        WriteLn(NewLine, 'Неверные номера строк! Повторите ввод.') // номера несуществующих строк
    else
      if Row1 = Row2 then
        WriteLn(NewLine, 'Менять одну и ту-же строку не имеет смысла! Повторите ввод.')
    else 
      begin // Можно поменять строки
        masSwapRows(Row1, Row2, n, m);
        masOutput(n, m, 'Результаты обмена строк ' + Row1 + ' и ' + Row2 + ':');
      end;
  until otvet = 'the end';
  
  WriteLn(NewLine, 'Программа завершила свою работу.');
end.