Глобальные переменные и процедуры

@Kujivunia · Регистрация: 12.01.2017

Author24 — интернет-сервис помощи студентам

Итак, я решил, что начать изучение этого языка лучше начать с написания чего-то интересного и простого. Крестики-нолики показались мне идеальным выбором. А теперь к проблеме: (коротко: я делаю в процедуре так: глобалка winl:=true, а winl посылает меня и не становится true в глобальном смысле)
Суть кода примерно такая: (ход мой, ход компа)*4+мой ход+проверка ничьей.
При этом в каждой процедуре хода есть процедура проверки победы. Если размотать этот клубок до конца и выйти к моей проблеме, то получится следующие: есть глобальная переменная winl, при победе (не важно чьей) я присваиваю ей значение истины. Но, судя по всему, это не работает. Ей не присваивается нужное значение. Ничья, возникающая при значении "победа=ложь" после последнего хода работает, а присваивание истины при победе - нет. Выяснил я это, решив сделав игру бесконечной - чтобы после победы/поражения/ничьей она начиналась сначала.
Я убрал из побед halt и добавил в процедуры ходов первой строчкой строку if winl=true then exit;
Как итог - программа просто упрямо выполнялась до конца, не обращая ни малейшего внимания на ту строку. Вывод один - присваивание не работает. Хотелось бы спросить, что здесь не так и почему оно не работает? Заранее спасибо
Под спойлером сама программа.

Кликните здесь для просмотра всего текста

Pascal

program xoxoxoxox;
 
uses crt;
    //Переменная победа/поражения, для определения ничьей
var winl:boolean;
    //Выйти?
    quit:char;
    //Создаю массив символов
    field:array[0..2,0..2] of char;
    //Запись поля тильдами
procedure recording_empty_in_memory;
var i,n:byte;
begin
    i:=0;
    n:=0;
            for a:byte:=1 to 3 do
            begin
                for b:byte:=1 to 3 do
                    begin
                    field[n,i]:='~';
                    i:=i+1;
                    end;
            n:=n+1;
            i:=0;
            end;
end;
    //Отрисовка поля в текущем его состоянии
procedure draw;
var i,n:byte;
begin
    i:=0;
    n:=0;
            for a:byte:=1 to 3 do
            begin
            write(' ');
                for b:byte:=1 to 3 do
                    begin
                    write(field[n,i]);
                    i:=i+1;
                    end;
            n:=n+1;
            i:=0;
            writeln;
            end;
end;    
    //Ввод
procedure read_user_key;
var key:char;
    i:byte;
begin
    repeat
        i:=0;
        key:=readkey;
        if ((key<='9') and (key>='1')) then
            case key of
'7':if ((field[0,0]<>'X')and(field[0,0]<>'O')) then field[0,0]:='X' else i:=1;
'8':if ((field[0,1]<>'X')and(field[0,1]<>'O')) then field[0,1]:='X' else i:=1;
'9':if ((field[0,2]<>'X')and(field[0,2]<>'O')) then field[0,2]:='X' else i:=1;
'4':if ((field[1,0]<>'X')and(field[1,0]<>'O')) then field[1,0]:='X' else i:=1;
'5':if ((field[1,1]<>'X')and(field[1,1]<>'O')) then field[1,1]:='X' else i:=1;
'6':if ((field[1,2]<>'X')and(field[1,2]<>'O')) then field[1,2]:='X' else i:=1;
'1':if ((field[2,0]<>'X')and(field[2,0]<>'O')) then field[2,0]:='X' else i:=1;
'2':if ((field[2,1]<>'X')and(field[2,1]<>'O')) then field[2,1]:='X' else i:=1;
'3':if ((field[2,2]<>'X')and(field[2,2]<>'O')) then field[2,2]:='X' else i:=1;
            end
                    else
                        i:=1;
    until i=0;       
end;
    //ИИ
procedure AI;
var i,k,n:byte;
begin
n:=0;
    repeat
    i:=random(0,2);
    k:=random(0,2);
        if ((field[i,k]<>'X')and(field[i,k]<>'O')) then 
            begin 
                field[i,k]:='O';
                n:=9;
            end 
        else 
            n:=n+1;
    until n=9;
 
end; 
    //Действия при победе игрока
procedure winp(winl:boolean);
begin
winl:=true;
writeln(#10,' Вы победили!'); 
readkey; 
halt;
end;
    //Действия при победе компьютера
procedure winc(winl:boolean);
begin
winl:=true;
writeln(#10,' Вы проиграли!'); 
readkey; 
halt;
end;
    //Проверка на победу кого-либо. Выводит, кто победил
function winvec:char;
var x,y,i,n:byte;
begin
    begin
    y:=0;
    x:=0;
    i:=0;
    n:=0;
            for b:byte:=1 to 3 do
                                    begin
        for a:byte:=1 to 3 do
            begin
            if field[x,y]='X' then i:=i+1;
            if field[x,y]='O' then n:=n+1;
            if n=3 then winvec:='O';
            if i=3 then winvec:='X';
            y:=y+1;
            end;
                                        x:=x+1;
                                        y:=0;
                                        n:=0;
                                        i:=0;
                                    end;
    y:=0;
    x:=0;
    i:=0;
    n:=0;
            for b:byte:=1 to 3 do
                                    begin
        for a:byte:=1 to 3 do
            begin
            if field[x,y]='X' then i:=i+1;
            if field[x,y]='O' then n:=n+1;
            if n=3 then winvec:='O';
            if i=3 then winvec:='X';
            x:=x+1;
            end;
                x:=0;
                n:=0;
                i:=0;
                y:=y+1;
                                    end;
    y:=0;
    x:=0;
    i:=0;
    n:=0;
 
        for a:byte:=1 to 3 do
            begin
            if field[x,y]='X' then i:=i+1;
            if field[x,y]='O' then n:=n+1;
            if n=3 then winvec:='O';
            if i=3 then winvec:='X';
            x:=x+1;
            y:=y+1;
            end;
    y:=2;
    x:=0;
    i:=0;
    n:=0;
 
        for a:byte:=1 to 3 do
            begin
            if field[x,y]='X' then i:=i+1;
            if field[x,y]='O' then n:=n+1;
            if n=3 then winvec:='O';
            if i=3 then winvec:='X';
            x:=x+1;
            y:=y-1;
            end;
    end;
end;
    //Действия в зависимости от чьей-либо победы
procedure win(winvec:char);
begin
if winvec='X' then winp(winl);
if winvec='O' then winc(winl);
end;
    //Ход игрока
procedure user;
begin
clrscr;
    draw;
        writeln(#10,' Ваш ход: ');
    read_user_key;
clrscr;
    draw;
        win(winvec);
    writeln(#10,' Нажмите любую клавишу для совершения компьютером своего хода');
readkey;
end;
    //Ход компьютера
procedure com;
begin
AI;
clrscr;
draw;
win(winvec);
end;
    //Вся игра собрана в одну процеру
procedure game(winl:boolean);
begin
    recording_empty_in_memory;
    randomize;
    winl:=false;
        draw;        
 
    user;
        com;
    user;
        com;
    user;
        com;
    user;
        com;
        
clrscr;
draw;
writeln(#10,' Ваш ход: ');
read_user_key;
clrscr;
draw;
 
win(winvec);
 
if winl=false then 
begin 
writeln(#10,' Ничья');
readkey; 
halt;
end;
end;
 
begin
repeat
game(winl);
writeln(#10,' Для выхода нажмите q');
quit:=readkey
until quit='q';
end.

@Krutoy 4el · 19.07.2019, 20:53

ваш код, начинающийся со строки 88:

Pascal

//Действия при победе игрока
procedure winp(winl:boolean);
begin
winl:=true;
writeln(#10,' Вы победили!'); 
readkey; 
halt;
end;
* * //Действия при победе компьютера
procedure winc(winl:boolean);
begin
winl:=true;
writeln(#10,' Вы проиграли!'); 
readkey; 
halt;
end;

Не разбирался с вашим кодом полностью, но здесь видно, что у вас конфликт имён.
в начале программы (

Pascal

1 2	//Переменная победа/поражения, для определения ничьей var winl:boolean;

)
вы объявляете переменную winl.
В наведенных мной процедурах вы используете переменную winl как аргумент, то есть во время выполнения процедуры существует ДВЕ переменные с именем winl, при этом переменная, которая объявлена в заголовке процедуры имеет больший приоритет, чем глобальная, то есть если в процедуре вы присваиваете переменной winl значение true, оно присваивается ЛОКАЛЬНОЙ переменной winl (которая, кстати, удаляется при завершении процедуры).
Тут надо бы менять название переменной в заголовке процедур, но конкретно в вашем случае, процедуре ВООБЩЕ не нужны какие-либо входные данные. То есть, код, начинающийся на строке 88 должен выглядеть как-то так:

Pascal

//Действия при победе игрока
procedure winp;
begin
winl:=true;
writeln(#10,' Вы победили!'); 
readkey; 
halt;
end;
//Действия при победе компьютера
procedure winc;
begin
winl:=true;
writeln(#10,' Вы проиграли!'); 
readkey; 
halt;
end;

так же вам надо "починить" обращение к этим процедурам и пересмотреть остальной код (может там еще какая-то ошибка такого рода =)
надеюсь, понятно объяснил)

@JuriiMW · 21.07.2019, 14:36

Во-первых, ваше форматирование… Совершенно не понятно где какие операторные скобки! А форматирование текста программы именно и приводит к лёгкости чтения кода.

Во-вторых, Kujivunia, очень странный код после такого вопроса: Как считать файл с текстом в одну переменную типа string максимально быстро?

Добавлено через 9 минут
Вы объявляете массив [0..2, 0..2], но зачем-то используете какие-то „костыли“, чтобы обратиться к конкретной ячейке этого массива.
К примеру, для заполнения массива в процедуре recording_empty_in_memory можно было же просто:

Pascal

1
2
3

  for var row := 0 to 2 do
    for var col := 0 to 2 do
      field[row, col] := '~';

Или процедура draw:

Pascal

  for a: byte := 0 to 2 do
  begin
    write(' ');
    for b: byte := 0 to 2 do
      write(field[a, b]);
    writeln;
  end;

Добавлено через 50 минут
Процедура read_user_key: зачем делать двойные проверки на <>X и <>O, когда достаточно одной =~:

Pascal

      case key of
        '7': if field[0, 0] = '~' then field[0, 0] := 'X' else i := 1;
        '8': if field[0, 1] = '~' then field[0, 1] := 'X' else i := 1;
        '9': if field[0, 2] = '~' then field[0, 2] := 'X' else i := 1;
        '4': if field[1, 0] = '~' then field[1, 0] := 'X' else i := 1;
        '5': if field[1, 1] = '~' then field[1, 1] := 'X' else i := 1;
        '6': if field[1, 2] = '~' then field[1, 2] := 'X' else i := 1;
        '1': if field[2, 0] = '~' then field[2, 0] := 'X' else i := 1;
        '2': if field[2, 1] = '~' then field[2, 1] := 'X' else i := 1;
        '3': if field[2, 2] = '~' then field[2, 2] := 'X' else i := 1;
      end

Да и, в принципе, case здесь лишнее:

Pascal

procedure read_user_key;
begin
  var theEnd := False;
  repeat
    var key := readkey;
    if key.InRange('1','9') then
      begin
        var n := StrToInt(key) - 1;
        var(row, col) := (2 - n div 3, n mod 3);
        if field[row, col] = '~' then
          (field[row, col], theEnd) := ('X', True);
      end;
  until theEnd;       
end;

Добавлено через 2 часа 29 минут
AI — просто верх совершенства! Ни какой логики! Тупой рандом…

С проверкой на выигрыш сильно… Масштабировать до 4-х в ряд вы не собираетесь, поэтому можно проще:

Pascal

function winvec: char;
begin
  if (field[0,0] <> '~') and (field[0,0] = field[0,1]) and (field[0,1] = field[0,2]) then // 1 ряд
    begin winvec := field[0,0]; Exit; end;
  if (field[1,0] <> '~') and (field[1,0] = field[1,1]) and (field[1,1] = field[1,2]) then // 2 ряд
    begin winvec := field[1,0]; Exit; end;
  if (field[2,0] <> '~') and (field[2,0] = field[2,1]) and (field[2,1] = field[2,2]) then // 3 ряд
    begin winvec := field[2,0]; Exit; end;
    
  if (field[0,0] <> '~') and (field[0,0] = field[1,0]) and (field[1,0] = field[2,0]) then // 1 колонка
    begin winvec := field[0,0]; Exit; end;
  if (field[0,1] <> '~') and (field[0,1] = field[1,1]) and (field[1,1] = field[2,1]) then // 1 колонка
    begin winvec := field[0,1]; Exit; end;
  if (field[0,2] <> '~') and (field[0,2] = field[1,2]) and (field[1,2] = field[2,2]) then // 1 колонка
    begin winvec := field[0,2]; Exit; end;
    
  if (field[0,0] <> '~') and (field[0,0] = field[1,1]) and (field[1,1] = field[2,2]) then // главная диагональ
    begin winvec := field[0,0]; Exit; end;
  if (field[0,2] <> '~') and (field[0,2] = field[1,1]) and (field[1,1] = field[2,0]) then // побочная диагональ
    begin winvec := field[0,2]; Exit; end;
end;

	21.07.2019, 14:36

Глобальные переменные и процедуры

Решение