Составить программу, вычисляющую сумму

@axbor · Регистрация: 06.01.2019

Дано натуральное число н(<100).Составить программу, вычисляющую сумму

C:=sqr(н)/(1*2) + sqr(н)/(2*3*4)+ sqr(н)/(3*4*5*6)+… +sqr(н)/(н*(н+1)*…*2*н)

@Cyborg Drone · 18.01.2019, 23:58

В формуле ошибка.

@axbor · 19.01.2019, 14:14 **[ТС]**

незнаю задание вроде таким был

@Cyborg Drone · 20.01.2019, 01:17

А, кажется, догадался. Имеется ввиду

$http://www.cyberforum.ru/cgi-bin/latex.cgi? C=\frac{\sqrt{1}}{1\cdot 2}+\frac{\sqrt{2}}{2\cdot 3\cdot 4}+\frac{\sqrt{3}}{3\cdot 4\cdot 5\cdot 6}+...+\frac{\sqrt{n}}{n\cdot (n+1)\cdot ...\cdot 2\cdot n} $

Если так, то пустяковая задачка.

Только вот не ясно. Верно ли я понял, что "sqr" - это корень квадратный?

Не по теме:

Что значит - "не знаю"? Вам же решение нужно, значит, Вы и должны знать задание.

@axbor · 20.01.2019, 15:54 **[ТС]**

sqr: Это квадрат

@Cyborg Drone · 21.01.2019, 05:53

Ага, то есть, вот так:

$http://www.cyberforum.ru/cgi-bin/latex.cgi? C=\frac{1^2}{1\cdot 2}+\frac{2^2}{2\cdot 3\cdot 4}+\frac{3^2}{3\cdot 4\cdot 5\cdot 6}+...+\frac{n^2}{n\cdot (n+1)\cdot ...\cdot 2\cdot n}=\sum_{k=1}^{n}\frac{k^2}{\left( \prod_{t=k}^{2k}t\right)}=\sum_{k=1}^{n}a_k $

Это уже интереснее. Получается, что каждое слагаемое можно сократить на k².

Найдём рекуррентное соотношение для членов ряда:

$http://www.cyberforum.ru/cgi-bin/latex.cgi? a_1=\frac{1}{2};\ \ a_k=\frac{k^2}{\left( \prod_{t=k}^{2k}t\right)}=\frac{1}{\left( 2\prod_{t=k+1}^{2k-1}t\right)};\ \ a_{k-1}=\frac{1}{\left( 2\prod_{t=k}^{2k-3}t\right)}; $

$http://www.cyberforum.ru/cgi-bin/latex.cgi? \frac{a_k}{a_{k-1}}=\frac{2\prod_{t=k}^{2k-3}t}{2\prod_{t=k+1}^{2k-1}t}=\frac{k}{(2k-1)(2k-2)}=\frac{k}{4(k-0.5)(k-1)};\ \ \Rightarrow \ \ a_k=\frac{ka_{k-1}}{4(k-0.5)(k-1)} $

Первый член известен, последующий член выражен через предыдущий, рекуррентное соотношение найдено.

Пишем программу.

Pascal

var
  k, n: integer;
  a, c: real;
 
begin
  repeat {ввод n с проверкой}
    write('n > 0;  n = ');
    readln(n)
  until n > 0;
  a := 0.5; {первый член ряда}
  c := a; {складываем первый член ряда с суммой}
  for k := 2 to n do {находим и добавляем к сумме остальные члены ряда}
    begin
      a := k * a / 4 / (k - 0.5) / (k - 1); {находим очередной член ряда}
      c := c + a {Добавляем его к сумме}
    end;
  write('c = ', c:0:15) {печатаем результат}
end.

На всякий случай, не оптимальное решение (без рекуррентного соотношения), это если Вы не сможете объяснить, как мною было получено рекуррентное соотношение:

Pascal

var
  k, t, n: integer;
  a, c: real;
 
begin
  repeat {ввод n с проверкой}
    write('n > 0;  n = ');
    readln(n)
  until n > 0;
  c := 0; {сумма пока равна 0}
  for k := 1 to n do {находим и добавляем к сумме члены ряда}
    begin
      a := k * k; {k^2}
      for t := k to 2 * k do a := a / t; {k^2/(k*(k+1)*...*2k)}
      c := c + a
    end;
  write('c = ', c:0:15) {печатаем результат}
end.

Для сравнения:
При n=100000 первая программа выдаёт результат мгновенно, а эта - думает секунд 20.
Если n=1000000, то первая программа выдаёт результат почти мгновенно, а эта... Я покурил, кофейку попил, а результата так и не дождался.

Короче, если поймёте, как мне удалось ускорить вычисления, наивысший балл Вам будет обеспечен.

@axbor 0 / 0 / 0 Регистрация: 06.01.2019 Сообщений: 15
		1
	Составить программу, вычисляющую сумму 13.01.2019, 10:45. Просмотров 924. Ответов 5 Метки нет (Все метки) Дано натуральное число н(<100).Составить программу, вычисляющую сумму C:=sqr(н)/(12) + sqr(н)/(234)+ sqr(н)/(3456)+… +sqr(н)/(н(н+1)…2н) 0

@Cyborg Drone Модератор 5742 / 3356 / 2507 Регистрация: 17.08.2012 Сообщений: 10,779
	18.01.2019, 23:58	2
	В формуле ошибка. 0

@axbor 0 / 0 / 0 Регистрация: 06.01.2019 Сообщений: 15
	19.01.2019, 14:14 [ТС]	3
	незнаю задание вроде таким был 0

@Cyborg Drone Модератор 5742 / 3356 / 2507 Регистрация: 17.08.2012 Сообщений: 10,779
	20.01.2019, 01:17	4
	А, кажется, догадался. Имеется ввиду $http://www.cyberforum.ru/cgi-bin/latex.cgi?<br /> C=\frac{\sqrt{1}}{1\cdot 2}+\frac{\sqrt{2}}{2\cdot 3\cdot 4}+\frac{\sqrt{3}}{3\cdot 4\cdot 5\cdot 6}+...+\frac{\sqrt{n}}{n\cdot (n+1)\cdot ...\cdot 2\cdot n}<br />$ Если так, то пустяковая задачка. Только вот не ясно. Верно ли я понял, что "sqr" - это корень квадратный? Не по теме: Что значит - "не знаю"? Вам же решение нужно, значит, Вы и должны знать задание. 0

@axbor 0 / 0 / 0 Регистрация: 06.01.2019 Сообщений: 15
	20.01.2019, 15:54 [ТС]	5
	sqr: Это квадрат 0

	21.01.2019, 05:53

Опции темы

Составить программу, вычисляющую сумму

Решение