Получение курсов валют из интернета - PascalABC.NET - Ответ 13253006

{$reference System.Xml.dll}
 
uses System.Xml;
 
function ПолучитьКурсВалют(var ВремяПоследнегоОбновления: DateTime): Dictionary<string, decimal>;
begin
  Result := new Dictionary<string, decimal>;
  
  var xmlr := XmlReader.Create('http://www.ecb.europa.eu/stats/eurofxref/eurofxref-daily.xml');
  xmlr.ReadToFollowing('Cube');
  while xmlr.Read do
  begin
    if xmlr.NodeType <> XmlNodeType.Element then continue;
    
    if xmlr.GetAttribute('time') <> nil then
      
      //я сделал чтоб сразу парсило, зачем в отдельной переменной сохранять
      ВремяПоследнегоОбновления := DateTime.Parse(xmlr.GetAttribute('time')) else
      
      Result.Add(
        xmlr.GetAttribute('currency'),
        decimal.Parse(
          xmlr.GetAttribute('rate'),
          System.Globalization.CultureInfo.InvariantCulture
        )
      );
    
  end;
  
  xmlr.Dispose;//Это то что вызывает using после выхода из него
  Result.Add('EUR', 1);
end;
 
begin
  var dt: DateTime;
  var kv := ПолучитьКурсВалют(dt);
  writeln($'Последнее обновление было {dt}');
  writeln($'Курс:');
  kv.PrintLines;
  
  writeln;
  var r := decimal(ReadlnReal('Введите рубли:'));
  writeln($'{r} рублей это {r/kv[''RUB'']*kv[''USD'']} долларов');
end.