В каталоге и его подкаталогах найти и скопировать в отдельный подкаталог все файлы, созданные после 14:00 - CMD/BAT - Ответ 3475110

@echo off
SetLocal EnableDelayedExpansion
 
::Задаем исходный каталог, где будем искать файлы рекурсивно
set $DirSource=e:\2 2
::Задаем целевой каталог, куда будем складывать 
set $DirDest=e:\1 1
::Полное имя архива
set $PathArch=e:\1 1\myArchive.zip
::Степень сжатия файлов (3 - минимальная, 5 - нормальная, 7 - максимальная)
set Level=5
 
::Задайте дату и время, после которой следует выполнять операции с файлами
set date0=21.09.2012
set time0=14:00:00
Echo Установлены граничные параметры: Дата - %date0% Время - %time0%
Echo.
 
::::Работаем с граничным временем
::Разбиваем время на часы, минуты, секунды
Call :parse_time hh0 min0 ss0 %time0%
::Переводим время в секунды
Call :toSec %hh0% %min0% %ss0% Msec
::Переводим время в число
Call :date_into_long %date0% Mdat
 
::Определяем расположение архиватора 7Zip через реестр
For /F "UseBackQ Tokens=2*" %%A In (`Reg Query "HKCU\Software\7-Zip"^|Find /I "Path"`) Do Set $7Zip=%%B
if not defined $7Zip (echo Архиватор 7Zip не установлен & pause>nul & goto :eof)
::Добавляем бекслэш \ если его нет (установщики msi и exe по-разному прописывают путь в реестре)
if %$7Zip:~-1% NEQ \ Set $7zip=%$7Zip%\
 
Set $AtLeastOneFile=False
::обходим рекурсивно все файлы
for /r "%$DirSource%" %%i in (*) do (
  set $Flag=False
  rem Получаем дату и время модификации файла
  Call :getFileTime "%%i" Fdate Ftime
  rem Преобразуем данные модификации файла
  Call :parse_time hh0 min0 ss0 !Ftime!
  Call :toSec !hh0! !min0! !ss0! Fsec
  Call :date_into_long !Fdate! FdateLong
  rem Определяем, если дата файла > установленной, либо дата = уст., а время > уст.
  rem FdateLong - числовой эквивалент даты файла (в формате yyyymmdd)
  rem Mdat - установленная граничная дата
  rem Fsec - время модификации файла в секундах
  rem Msec - установленное граничное время в секундах
  echo Проверяем файл %%i. !Fdate! !Ftime!
  if !FdateLong! GTR %Mdat% (
      set $Flag=True
    ) else (
      if !FdateLong! EQU %Mdat% if !Fsec! GTR %Msec% Set $Flag=True
  )
  if !$Flag!==True (
      >Nul copy "%%i" "%$DirDest%" && Set $AtLeastOneFile=True && (
        Echo                                                                 Успех
        Echo %%i готов к архивации.
      )
    ) else (
      Echo Не удовлетворяет условиям.
  )
  echo. 2>nul
)
Echo Проверка завершена.
::Хотя бы один файл был скопирован?
if %$AtLeastOneFile%==True (
    Echo Начинаю процесс архивации следующих файлов:
    Dir /b "%$DirDest%\*.*"
    Echo.
    >Nul "%$7zip%7z.exe" a -tzip -mx%Level% "%$PathArch%" "%$DirDest%\*.*"
    Echo Создание архива "%$PathArch%" завершено.  
  ) else (
    Echo Нет файлов, подходящих под условия для архивации.
)
Echo.
Pause
goto :eof
 
:toSec
::%1 - hh; %2 -  min; %3 - ss; %4 - to var
set /a %4=%1*60*60+%2*60+%3
exit /b
 
:parse_time
::%1 - hh; %2 -  min; %3 - ss; %4 - from var
set t=%4
if %t:~1,1%==: (set t=0%4)
::Обход ошибки представления числа в 8-ричной СС
set %1=1%t:~0,2%
set /a %1-=100
set %2=1%t:~3,2%
set /a %2-=100
set %3=1%t:~6,2%
set /a %3-=100
exit /b
 
:getFileTime
:: %1=file %2=var (FileDate) %3 - var (FileTime)
::Обход ошибки пробелов в пути к файлу
chdir /d "%~dp1"
set $FName=%~nx1
::Обход ошибки пробелов в имени файла
set $FName=%$FName: =?%
for /f "delims=" %%a in ('where /T %$FName%') do (
  for /f "tokens=1,2,3" %%i in ("%%a") do (
    set %2=%%j
    set %3=%%k
  )
)
exit /b
 
:date_into_long
::%1 - date; %2 - to var
::making long number like yyyymmdd
for /f "tokens=1-3 delims=." %%i in ("%1") do (
  set dd=%%i
  set mm=%%j
  set yyyy=%%k
)
::Если день - однозначное число, тогда дописываем 0
if "%dd:~1,1%"=="" set dd=0%dd%
::Если месяц - однозначное число, тогда дописываем 0
if "%mm:~1,1%"=="" set mm=0%mm%
::Если год - двухзначное число, тогда дописываем 19 или 20
if "%yyyy:~3,1%"=="" (
  set /a Nyyyy=1%yyyy%
  set /a Nyyyy-=100
  if !Nyyyy! GEQ 50 (set yyyy=19%yyyy%) else (set yyyy=20%yyyy%)
)
set /a %2=%yyyy%%mm%%dd%
exit /b