Парсинг тегов <title> расположенных в разных формах - Delphi - Ответ 3849086

//Поиск элементов с заданными параметрами.
procedure TForm1.Button1Click(Sender: TObject);
var
  Doc, Elems, Elem, Attrs, Attr : Variant;
  TagName, ClassName, AttrName, AttrVal : String;
  i, j, Cnt : Integer;
begin
  //Ссылка на документ.
  Doc := WebBrowser1.OleObject.document;
  if TVarData(Doc).VDispatch = nil then begin
    ShowMessage('Документ не задан. Действие отменено.');
    Exit;
  end;
  //TagName = 'div'.
  TagName := Edit1.Text;
  if TagName = '' then begin
    ShowMessage('Тег не задан. Действие отменено.');
    Exit;
  end;
  //ClassName = 'tradeheader'.
  ClassName := Edit2.Text;
  if ClassName = '' then begin
    ShowMessage('Имя класса не задано. Действие отменено.');
    Exit;
  end;
  //AttrName = 'title'.
  AttrName := Edit3.Text;
  if AttrName = '' then begin
    ShowMessage('Имя атрибута не задано. Действие отменено.');
    Exit;
  end;
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Tag: "' + TagName + '", ClassName: "' + ClassName
     + '", AttrName: "' + AttrName + '".');
 
  //Получаем коллекцию всех элементов с заданным тегом.
  Elems := Doc.getElementsByTagName(TagName);
  //Перебор всех элементов колекции.
  Cnt := 0;
  for i := 0 to Elems.length - 1 do begin
    //Ссылка на очередной элемент.
    Elem := Elems.item(i);
    //Проверяем имя класса.
    if Elem.className = ClassName then begin
      //Поиск атрибута.
      //Почему-то в интерфейсе нет методов Elem.hasAttribute()
      //и Elem.getAttribute(). Поэтому пришлось сделать перебор атрибутов.
      Attrs := Elem.Attributes;
      for j := 0 to Attrs.length - 1 do begin
        Attr := Attrs.item(j);
        if Attr.name = AttrName then begin
          AttrVal := Attr.value;
          //Например, атрибут title есть у всех элементов DOM, поэтому, даже если
          //этот атрибут не задан в явном виде в HTML коде, то он всё равно
          //присутствует. И его значение в этом случае равно пустой строке.
          if AttrVal <> '' then begin
            Inc(Cnt);
            Memo1.Lines.Add(IntToStr(Cnt) + ': ' + AttrName + ' = "' + AttrVal + '".');
          end;
        end;
      end;
    end;
  end;
  Memo1.Lines.Add('Всего найдено элементов: ' + IntToStr(Cnt) + '.');
end;