Гистограммы C++ - C++ - Ответ 713195

program WordGG;
type
  TPointer=^TNode;{указатель на узел}
  TNode=record{описание узла}
    strWord:string;{слово}
    count:integer;{частота встречи в файле}
    next:TPointer;{указатель на следующий элемент}
  end;
procedure InitList(var List:TPointer);
{процедура инициализации списка}
begin
  List:=nil;
end;
procedure AddToList(var List:TPointer;strWord:string);
{процедура добавления элемента в список на нужное место}
var
  NewNode,TempList:TPointer;{NewNode - новый узел, TempNode - вспомогательный указатель}
begin
  TempList:=List;{указатель на начало списка}
  while(TempList<>nil) and (TempList^.strWord<>strWord) do{пока не конец списка и не нашли повторений}
    TempList:=TempList^.next;{переход к следующему элементу списка}
  if TempList<>nil then{если не дошли до конца, то значит есть повторение}
    inc(TempList^.count){увеличиваем счетчик}
  else
  begin
    {создаем новый элемент}
    NewNode:=new(TPointer);{выделяем память в куче}
    NewNode^.strWord:=strWord;{записываем слово}
    NewNode^.count:=1;{инициализируем счетчик}
    {поиск нужного места}
    TempList:=List;{указатель на начало списка}
    if TempList<>nil then{если список не пуст}
    begin
      if NewNode^.strWord<List^.strWord then{если строка нового элемента должна стоять раньше первого в списке}
      begin
        NewNode^.next:=List;{следующий после нового первый в списке}
        List:=NewNode;{меняем указатель на первый элемент списка}
      end
      else
      begin
        while(TempList^.next<>nil) and (TempList^.next^.strWord<strWord) do{находим место вставки}
          TempList:=TempList^.next;
        {вставляем элемент}
        NewNode^.next:=TempList^.next;
        TempList^.next:=NewNode;
      end;
    end
    else{список пуст}
    begin
      NewNode^.next:=nil;{больше элементов нет}
      List:=NewNode;{первый элемент - только что созданный}
    end;
  end;
end;
procedure DeleteList(var List:TPointer);
{процедура удаления списка}
var
  TempList:TPointer;{вспомогательный указатель}
begin
  while(List<>nil) do{пока список не пуст}
  begin
    TempList:=List;{вспомогательный указатель на первый в списке}
    List:=List^.next;{двигаем указатель в списке}
    dispose(TempList);{освобождаем память для запомненного элемента}
  end;
end;
procedure CreateWordGGFile(strInputFileName,strOutputFileName:string);
{процедура создания гистограммы слов}
const
  SSymbols=['a'..'z','A'..'Z'];{мн-во символов}
var
  List,TempList:TPointer;{указатели на список и вспомогательный элемент соот-но}
  f:text;{текстовый файл}
  strWord:string;{для хранения прочитанного из файла слова}
  ch:char;{для чтения символа из файла}
  iMaxCount,iMaxLength,strLen,iLength:integer;
begin
  iMaxLength:=0;{инициализация максимальной длины строки}
  iMaxCount:=0;{инициализация максимального счетчика для слова}
  InitList(List);{инициализация списка}
  assign(f,strInputFileName);{связывание файловой переменной с файлом}
  reset(f);{открытие для чтения}
  while not eof(f) do{пока не конец файла}
  begin
    strWord:='';{инициализация слова}
    read(f,ch);{читаем символ}
    while not(eof(f) or (ch in SSymbols))do{пока прочитанный символ не буква}
      read(f,ch);{читаем символ}
    while not eof(f) and (ch in SSymbols) do{пока прочитанный символ буква}
    begin
      strWord:=strWord+ch;{добавляем букву к слову}
      read(f,ch);{читаем символ}
    end;
    if strWord<>'' then{если прочитанное слово не пусто}
    begin
      strLen:=Length(strWord);{узнаем длину слова}
      if strLen>iMaxLength then{если длина слова больше максимальной}
        iMaxLength:=strLen;{запоминаем максимальную длину слова}
      AddToList(List,strWord);{добавляем слово в список}
    end;
  end;
  close(f);{закрываем файл}
  assign(f,strOutputFileName);{связывание файловой переменной с фвйлом}
  rewrite(f);{открываем для перезаписи}
  TempList:=List;{указатель на начало списка}
  {ищем частоту слова, которое встречается чаще всего}
  while(TempList<>nil) do{пока не конец списка}
  begin
    if TempList^.count>iMaxCount then{если частота текущего слова больше}
      iMaxCount:=TempList^.count;{запоминаем максимальную частоту}
    TempList:=TempList^.next;{переход к следующему элементу}
  end;
  while(iMaxCount<>0) do{пока максимальная частота не равна 0}
  begin
    TempList:=List;{указатель на начало списка}
    while(TempList<>nil) do{пока не конец списка}
    begin
      if TempList^.count>=iMaxCount then{если частота текущего слова >= максимальной}
        write(f,'#'){печатаем символ #}
      else
        write(f,' ');{печатаем пробел}
      TempList:=TempList^.next;{переход к следующему элементу}
    end;
    writeln(f);{переход на следующую строку файла}
    dec(iMaxCount);{уменьшаем максимальную частотность}
  end;
  iLength:=1;{инициализация вспомогательной переменной}
  while(iLength<=iMaxLength) do{пока длина <= максимальной длине слова}
  begin
    TempList:=List;{указатель на начало списка}
    while(TempList<>nil) do{пока не конец списка}
    begin
      strLen:=Length(TempList^.strWord);{узнаем длину слова}
      if strLen>=iLength then{если длина текущего слова >= текущей длине}
        write(f,TempList^.strWord[iLength]){печатаем iLength'ую букву слова}
      else
        write(f,' ');{печатаем пробел}
      TempList:=TempList^.next;{переход к следующему элементу}
    end;
    writeln(f);{переходим к следующей строке файла}
    inc(iLength);{увеличиваем текущую длину}
  end;
  close(f);{закрываем файл}
  DeleteList(List);{удаляем список}
end;
var
  strInputFileName,strOutputFileName:string;
begin
  writeln('Please enter an input file name:');
  readln(strInputFileName);{вводим имя исходного файла}
  writeln('Please enter an output file name:');
  readln(strOutputFileName);{вводим имя выходного файла}
  CreateWordGGFile(strInputFileName,strOutputFileName);
  writeln('ok');
  readln;{ждем ввода}
end.