Вычислить выражение {(x y)*7} - Assembler - Ответ 7909133

_StrToUChar macro arg1, arg2, arg3
    lea bx, arg1
    call StrToUChar
    jc short arg3
    ifnb <arg2>
        mov arg2, al
    endif
endm
 
scan macro _addr
    mov ah, 0Ah
    lea dx, _addr
    int 21h
endm
 
print macro _addr
    mov ah, 09h
    lea dx, _addr
    int 21h
endm
 
codesg segment 'code'
    assume cs:codesg, ds:codesg, ss:codesg
    org 100h
    main: jmp short begin
        x db ?
        y db ?
        z dw ?
        mes1 db 13, 10, 'Enter number x: $'
        mes2 db 13, 10, 'Enter number y: $'
        _Error db 13, 10, 'Invalid number!!! $'
        mes3 db 13, 10, 'Error!!! Overflow!!! $'
        mes4 db 13, 10, 'Rezult: $'
        buffer db 4, ?, 6 dup('$')
    begin: print mes1
        scan buffer
        _StrToUChar buffer+2, x, begin
    _repeat:print mes2
        scan buffer
        _StrToUChar buffer+2, y, _repeat
        
        xor ah, ah
        xor bh, bh
        xor dx, dx
        mov bl, x
        cmp bl, 159
        ja short func1
        jb short func3
            add bl, 35
            add ax, bx
            jmp _end
        func1: add ax, bx
            mov bx, 7
            mul bx
            jmp _end
        func3: mov cx, 5
            mul cx
            jo Overflow
            add ax, bx
        _end: jo Overflow
            mov z, ax
            lea di, buffer+2
            call OutInt
            mov byte ptr buffer+1, al
            print mes4
            print buffer+2
            jmp __end 
        Overflow: print mes3
        __end: int 20h
    
    ;вход в bx адрес строки в которой число - размер байт, строка заканчивается $ символом
    ;выход число в al
    StrToUChar proc
        push dx
        push di
        xor di, di
        xor al, al
        mov dl, 10
        _while: mov dh, [bx]
            cmp dh, 0Dh
            je Exit
            inc di
            mul dl
            jo _Err
            cmp dh, '0'
            jb _Err
            cmp dh, '9'
            ja _Err
            and dh, 0Fh
            add al, dh
            jc _Err
            inc bx
        jmp _while
        _Err: print _Error 
            stc 
            jmp short _exit
        Exit: or di, 0
            jz _Err
        _exit:pop di
        pop dx
        ret
    StrToUChar endp
    
    OutInt proc
    oi1:  
        xor     cx, cx
        mov     bx, 10
    oi2:
        xor     dx,dx
        div     bx
        push    dx
        inc     cx
        test    ax, ax
        jnz     oi2
        mov al, cl
    oi3:
        pop     dx
        add     dl, '0'
        mov byte ptr[di], dl
        inc di
        loop    oi3
        ret
    OutInt endp 
 
codesg ends
    end main