Форум программистов, компьютерный форум, киберфорум
Наши страницы

Полезные VBS скрипты и программы по работе с ними - VBScript/JScript

Войти
Регистрация
Восстановить пароль
Другие темы раздела
VBScript/JScript Кто нибудь работал с библиотекой ChilkatFTP? http://www.cyberforum.ru/vbscript-wsh/thread668991.html
Использую данную библиотеку для получения файлов из файл-сервера FTP. Подключаюсь 1 раз, но когда работаю с директориями (меняю каталог, возвращаюсь в корневой каталог) создаются все новые и новые...
VBScript/JScript Как в VBS скрипте создать задание в планировщике задач Как в VBS скрипте создать задание в планировщике задач, которое бы запускало файл каждые несколько минут? http://www.cyberforum.ru/vbscript-wsh/thread665572.html
VBScript/JScript Запуск скрипта из контекстного меню
В общем ситуация такая: решил написать скрипт, чтобы который выполнялся из контекстного меню. Пусть будет: msgBox "Hello World" Cоздал разделыы: "HKEY_CLASSES_ROOT\Folder\shell\myscr", ...
VBScript/JScript Проверить наличие папки с условием
ззззздарова! пытаюсь слепить код который проверяет наличие папки , вот че я нагородил, при проверке то вообще молчит то закидывает ошибками. код достаточно мудреный: 1: сначала он должен определить...
VBScript/JScript VBS и интернет http://www.cyberforum.ru/vbscript-wsh/thread659937.html
зззззздарова. нужен vbs код который запустит указанный в коде файл при коннекте с инетом.
VBScript/JScript Работа с реестром ззззздарова! буду благодарен тому кто подкинет vbs код, который создаст раздел в реестре по адресу HKLM\SOFTWARE. с возможностью создания ветки разделов, пр(HKLM\SOFTWARE\Новый раздел #1\Новый раздел... подробнее

Показать сообщение отдельно
greg zakharov
Покинул форум
1436 / 699 / 174
Регистрация: 07.05.2015
Сообщений: 1,347
Записей в блоге: 40
30.11.2015, 13:22
Crc32 файла
Суть идеи - запихать файл в zip и уже оттуда получить Crc32 файла (смещение 14 байт от начала архива, само поле crc32 - 4 байта). Концепт расчитан прежде не на шибко большие файлы.
Visual Basic
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
On Error Resume Next
 
If WScript.Arguments.Count <> 1 Then
  WScript.Echo "Usage: " & WScript.ScriptName & " <file>"
  WScript.Echo ".e.g.: " & WScript.ScriptName & " E:\sandbox\app.exe"
  WScript.Quit(1)
End If
 
Dim strFile
Dim strTemp
Dim objFile
Dim objDump
Dim strDump
 
strFile = WScript.Arguments.Unnamed(0)
 
With CreateObject("Scripting.FileSystemObject")
  If Not .FileExists(strFile) Then
    WScript.Echo "Could not locate specified file."
    WScript.Quit(1)
  End If
  
  strFile = .GetAbsolutePathName(strFile)
  strTemp = .BuildPath(.GetSpecialFolder(2), "~crc32.zip")
  
  Set objFile = .CreateTextFile(strTemp)
  objFile.Write "PK" & Chr(5) & Chr(6) & String(18, 0)
  objFile.Close
  
  With CreateObject("Shell.Application")
    .NameSpace(strTemp).CopyHere strFile
    WScript.Sleep 500
  End With
  
  With CreateObject("SAPI.SpFileStream")
    .Open strTemp, 0
    .Seek 14, 1
    .Read objDump, 4
    .Close
  End With
  
  With CreateObject("Microsoft.XMLDOM")
    Set strDump = .createElement("Binary")
    strDump.dataType = "bin.hex"
    strDump.nodeTypedValue = objDump
  End With
  
  strDump = strDump.text
  WScript.StdOut.Write "0x"
  For i = Len(strDump) - 1 To 0 Step -2
    WScript.StdOut.Write UCase(Mid(strDump, i, 2))
  Next
  WScript.Echo
  .GetFile(strTemp).Delete
End With
1
 
КиберФорум - форум программистов, компьютерный форум, программирование
Powered by vBulletin® Version 3.8.9
Copyright ©2000 - 2018, vBulletin Solutions, Inc.